/[cvs]/wolfpack/wolfpack.tcl
ViewVC logotype

Contents of /wolfpack/wolfpack.tcl

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.27 - (show annotations) (download) (as text)
Wed Jan 15 01:32:28 2003 UTC (16 years, 9 months ago) by tothwolf
Branch: MAIN
Changes since 1.26: +2 -1 lines
File MIME type: application/x-tcl
*** empty log message ***

1 #! /bin/sh
2 # \
3 # Nice little hack to find latest version of tclsh in PATH \
4 # \
5 # NOTE: backslash and semicolon placements are important! \
6 # \
7 # Search for tclsh[0-9].[0-9] in each valid dir in PATH \
8 for dir in $(echo $PATH | sed 's/:/ /g'); \
9 do \
10 if test -d $dir; \
11 then \
12 files=$(/bin/ls $dir | egrep '^tclsh[0-9]\.[0-9]$'); \
13 if test "$files" != ""; \
14 then \
15 versions="${versions:+$versions }$(echo $files | sed 's/tclsh//g')"; \
16 fi; \
17 fi; \
18 done; \
19 # Loop over each version to find the latest version of tclsh \
20 for ver in $versions; \
21 do \
22 tmpver=$(echo $ver | sed 's/\.//g'); \
23 if test "$lasttmpver" != ""; \
24 then \
25 if test "$tmpver" -gt "$lasttmpver"; \
26 then \
27 lastver=$ver; \
28 lasttmpver=$tmpver; \
29 fi; \
30 else \
31 lastver=$ver; \
32 lasttmpver=$tmpver; \
33 fi; \
34 done; \
35 # Use the latest tclsh version found, otherwise fall back to 'tclsh' \
36 exec tclsh$lastver "$0" "$@"
37 ###############################################################################
38 ##
39 ## Wolfpack - A modular Tcl system for Eggdrop 1.3.0+ with Tcl 8.0+
40 ## Copyright (C) 1998-2003 Tothwolf <tothwolf@concentric.net>
41 ##
42 ## This program is free software; you can redistribute it and/or modify
43 ## it under the terms of the GNU General Public License as published by
44 ## the Free Software Foundation; either version 2 of the License, or
45 ## (at your option) any later version.
46 ##
47 ## This program is distributed in the hope that it will be useful,
48 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
49 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
50 ## GNU General Public License for more details.
51 ##
52 ## You should have received a copy of the GNU General Public License
53 ## along with this program; if not, write to the Free Software
54 ## Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
55 ##
56 ###############################################################################
57 ##
58 ## You should not need to edit anything in any of these files.
59 ##
60 ## './wolfpack.tcl -c' may be used to configure initial settings.
61 ## './wolfpack.tcl --help' will list all avaliable options.
62 ##
63 ## Use '.wpconf' in dcc chat with the bot to configure everything else.
64 ##
65 ###############################################################################
66 ##
67 ## $Id: wolfpack.tcl,v 1.26 2003/01/14 11:18:05 tothwolf Exp $
68 ##
69
70 # make sure Tcl version is compatible with this code (we use namespaces)
71 if {[catch {package require Tcl 8.0}]} then {
72 if {[info exists argv0]} then {
73 puts "Wolfpack: Error: wolfpack requires Tcl 8.0 or later to load."
74 } else {
75 putloglev o * "Wolfpack: Error: wolfpack requires Tcl 8.0 or later to load."
76 }
77 return 0
78 }
79
80 namespace eval :: {
81
82 # Eggdrop doesn't currently set argv0, so we use that to detect load type.
83 global argv0
84
85 if {![info exists argv0]} then {
86 # HACK: quick fix for buggy tcl variables in older bots
87 catch {set version}
88 catch {set numversion}
89 # require eggdrop 1.3.0 or later
90 if {(![info exists version]) || (![info exists numversion]) || \
91 ($numversion < 1030000)} then {
92 putloglev o * "Wolfpack: Error: wolfpack requires Eggdrop 1.3.0 or later to load."
93 return 0
94 }
95 } else {
96 # emulate eggdrop's putloglev when loading with tclsh
97 if {![string compare "" [info commands putloglev]]} then {
98 proc putloglev {level channel text} {
99 puts $text
100 }
101 }
102 }
103
104 ##
105 ## Log tcl messages where they can be seen
106 ##
107 ## Args: text
108 ## Returns: nothing
109 ##
110 proc tclLog {text} {
111 # Tcl's tclLog embeds newlines in it's output
112 if {[string first \n $text] == -1} then {
113 putloglev o * "Wolfpack: \[Tcl\]: $text"
114 } else {
115 foreach line [split $text \n] {
116 putloglev o * "Wolfpack: \[Tcl\]: $line"
117 }
118 }
119 return
120 }
121
122 } ;# namespace ::
123
124 namespace eval ::wp {
125
126 # manage package information
127 package forget ::wp
128 package provide ::wp 1.9.9.0
129
130 # set namespace variable
131 set NamespaceCurrent [namespace current]
132
133 ##
134 ## WARNING: If you change these, you may render your module database useless!
135 ##
136
137 # Max number of lines to scan in a module file
138 set moduleDatabaseConfig(scanlines) 30
139
140 # Max depth to list directories in module path
141 set moduleDatabaseConfig(maxdepth) 4
142
143 # Module database version
144 set moduleDatabaseConfig(version) 2.0
145
146 # Module database header
147 set moduleDatabaseConfig(header) "Wolfpack module database "
148
149 # Module database defaults
150 set moduleDatabaseConfig(defaults) "{version 0.1} {description {(no description)}} {load 0}"
151
152 # Versioned module database formats
153 array set moduleDatabaseFormat {
154 2.0 "{version config help description provides requires} {load file md5sum}"
155 }
156
157 # md5 style, command name and result string index
158 array set md5Format {
159 bsd "md5 3"
160 gnu "md5sum 0"
161 }
162
163 # Configuration file
164 set IconfigDefaults(cfgfile) wolfpack.conf
165
166 # Interactive configuration prompt
167 set IconfigDefaults(prompt) "wolfpack> "
168
169 # Configuration defaults, values and descriptions
170 array set configDefaults {
171 modulepath {word modules/ {} {Module path}}
172 configpath {word wpconf/ {} {Config path}}
173 datapath {word wpdata/ {} {Data path}}
174 helppath {word wphelp/ {} {Help path}}
175 moddbfile {word wolfpack.db {} {Module database file}}
176 rebuild {{range {0 1}} 1 {} {Automatically rebuild database}}
177 verbose {{range {0 1}} 0 {} {Verbose operation}}
178 time {{range {0 1}} 0 {} {Time database compare and rebuild}}
179 commandchar {word - {} {Character to prefix public commands with}}
180 }
181
182 # Command line option defaults
183 array set optionData {
184 config 0
185 rebuild 0
186 norebuild 0
187 time 0
188 verbose 0
189 quiet 0
190 debug 0
191 }
192
193 # Exported commands
194 set ExportList {
195 md5Sum
196 md5Init
197 replaceExpr
198 listFiles
199 listSubdirs
200 findFiles
201 createFile
202 createDir
203 backupFile
204 listSave
205 listLoad
206 arraySave
207 arrayLoad
208 arraySetAll
209 arrayFindElementName
210 arrayMaxElementDataLength
211 listMaxElementLength
212 splitList
213 arraySearch
214 commandChar
215 dataFormatDefault
216 dataFormatValue
217 dataFormatReplace
218 dataFormatBuild
219 dataFormatConvert
220 scanModule
221 getModuleDatabaseData
222 setModuleDatabaseData
223 saveModuleDatabase
224 loadModuleDatabase
225 compareModuleDatabase
226 rebuildModuleDatabase
227 listModules
228 moduleExists
229 moduleLoaded
230 moduleBindUnbind
231 moduleLoad
232 moduleUnload
233 moduleConfigSave
234 moduleConfigLoad
235 moduleConfigCheckdefs
236 moduleConfig
237 moduleDataSave
238 moduleDataLoad
239 moduleDataBackup
240 moduleData
241 buildCommandTable
242 whichCommand
243 whichModule
244 whichModuleCommand
245 compareVersion
246 wpLog
247 }
248
249 ##
250 ## Create md5 checksum for a file
251 ##
252 ## Args: filename
253 ## Returns: md5 checksum if successful
254 ## Errors: permission denied,
255 ## no such file,
256 ## not a file,
257 ## can't exec md5 command
258 ##
259 proc md5Sum {file} {
260 variable md5Config
261
262 if {![file exists $file]} then {
263 error "$file: no such file"
264 } else {
265 if {![file isfile $file]} then {
266 error "$file: not a file"
267 } else {
268 if {![file readable $file]} then {
269 error "$file: permission denied"
270 } else {
271 if {[catch {set sum [lindex [exec $md5Config(command) $file] $md5Config(index)]} result]} then {
272 error "$file: $result"
273 } else {
274 return $sum
275 }
276 }
277 }
278 }
279 }
280
281 ##
282 ## Init md5 command
283 ##
284 ## Args: none
285 ## Returns: 1 if a useable md5 command found
286 ## 0 otherwise
287 ##
288 proc md5Init {} {
289 variable md5Config
290 variable md5Format
291
292 foreach type [array names md5Format] {
293 foreach {command index} $md5Format($type) {break}
294 if {([catch {exec $command ""} result]) && \
295 (![regexp -- "^couldn't execute" $result])} then {
296 set md5Config(command) $command
297 set md5Config(index) $index
298 return 1
299 }
300 }
301 return 0
302 }
303
304 ##
305 ## Replace all occurances of an expression in a string with the given text
306 ##
307 ## Args: string, expr, replacement text
308 ## Returns: string
309 ##
310 proc replaceExpr {string expr {replace ""}} {
311 while {[regexp -nocase -- $expr $string]} {
312 regsub -all -- $expr $string $replace string
313 }
314 return $string
315 }
316
317 ##
318 ## List files in a path
319 ##
320 ## Args: path
321 ## Returns: list of files in the given path,
322 ## nothing if no files in the given path
323 ## Errors: permission denied,
324 ## no such directory,
325 ## not a directory
326 ##
327 proc listFiles {path} {
328 if {![file exists $path]} then {
329 error "$path: no such directory"
330 } else {
331 if {![file isdirectory $path]} then {
332 error "$path: not a directory"
333 } else {
334 if {![file readable $path]} then {
335 error "$path: permission denied"
336 } else {
337 set ret ""
338 foreach name [lsort [glob -nocomplain -- [file join $path *]]] {
339 if {[file isfile $name]} then {
340 lappend ret $name
341 }
342 }
343 return $ret
344 }
345 }
346 }
347 }
348
349 ##
350 ## List subdirs in a path
351 ##
352 ## Args: path
353 ## Returns: list of subdirs in the given path,
354 ## nothing if no subdirs in the given path
355 ## Errors: permission denied,
356 ## no such directory,
357 ## not a directory
358 ##
359 proc listSubdirs {path} {
360 if {![file exists $path]} then {
361 error "$path: no such directory"
362 } else {
363 if {![file isdirectory $path]} then {
364 error "$path: not a directory"
365 } else {
366 if {![file readable $path]} then {
367 error "$path: permission denied"
368 } else {
369 set ret ""
370 foreach name [lsort [glob -nocomplain -- [file join $path *]]] {
371 if {[file isdirectory $name]} then {
372 lappend ret $name
373 }
374 }
375 return $ret
376 }
377 }
378 }
379 }
380
381 ##
382 ## List files with a set ext in a path and its subdirs up to a set depth
383 ##
384 ## Args: path, max search depth, file extension
385 ## Returns: list of files with a set ext in the given path and its subdirs,
386 ## nothing if no matching files are found
387 ##
388 proc findFiles {path depth {ext ""}} {
389 set ret ""
390 set foundDirs "$path "
391 set searchDirs $path
392 for {
393 set currentDepth 0
394 } {($currentDepth <= $depth) || (!$depth)} {
395 incr currentDepth
396 } {
397 set subDirs ""
398 foreach dir $searchDirs {
399 if {[catch {set dirList [listSubdirs $dir]} result]} then {
400 wpLog o * "Error: unable to get file listing: $result"
401 } elseif {[string compare "" $dirList]} then {
402 append subDirs $dirList " "
403 }
404 }
405 if {![string compare "" $subDirs]} then {
406 break
407 }
408 append foundDirs $subDirs " "
409 set searchDirs $subDirs
410 }
411 foreach dir $foundDirs {
412 if {[catch {set files [listFiles $dir]} result]} then {
413 wpLog o * "Error: unable to get file listing: $result"
414 } else {
415 if {[string compare "" $ext]} then {
416 foreach file $files {
417 if {![string compare $ext \
418 [string tolower [file extension $file]]]} then {
419 lappend ret $file
420 }
421 }
422 } else {
423 set ret $files
424 }
425 }
426 }
427 return $ret
428 }
429
430 ##
431 ## Check if a file exists, and create it if not
432 ##
433 ## Args: filename, verbose {-1,0,1}, description, force new file
434 ## Returns: 1 if the file was created successfully
435 ## 0 if the operation failed
436 ## -1 if the file already exists
437 ##
438 proc createFile {file {verbose 0} {desc "file "} {force 0}} {
439 if {($force) || (![file exists $file])} then {
440 if {[catch {set fd [open $file w]} result]} then {
441 if {$verbose >= 0} then {
442 wpLog o * "Error: unable to create ${desc}`[file tail $file]': $result"
443 }
444 } else {
445 if {(!$force) && ($verbose >= 1)} then {
446 wpLog o * "Warning: ${desc}`[file tail $file]' does not exist -- creating"
447 }
448 close $fd
449 return 1
450 }
451 } elseif {[file isfile $file]} then {
452 return -1
453 } elseif {$verbose >= 0} then {
454 wpLog o * "Error: not a file: $file"
455 }
456 return 0
457 }
458
459 ##
460 ## Check if a directory exists, and create it if not
461 ##
462 ## Args: directory, verbose {-1,0,1}, description
463 ## Returns: 1 if the directory was created successfully
464 ## 0 if the operation failed
465 ## -1 if the directory already exists
466 ##
467 proc createDir {dir {verbose 0} {desc "directory "}} {
468 if {![file exists $dir]} then {
469 if {[catch {file mkdir $dir} result]} then {
470 if {$verbose >= 0} then {
471 wpLog o * "Error: unable to create ${desc}`[file tail $dir]': $result"
472 }
473 } else {
474 if {$verbose >= 1} then {
475 wpLog o * "Warning: ${desc}`[file tail $dir]' does not exist -- creating"
476 }
477 return 1
478 }
479 } elseif {[file isdirectory $dir]} then {
480 return -1
481 } elseif {$verbose >= 0} then {
482 wpLog o * "Error: not a directory: $dir"
483 }
484 return 0
485 }
486
487 ##
488 ## Create a backup of the given file with an optional suffix
489 ##
490 ## Args: filename, suffix, verbose {-1,0,1}
491 ## Returns: 1 if successful
492 ## -1 if file is 0 in size
493 ## 0 otherwise
494 ##
495 proc backupFile {file {verbose 0} {suffix ~bak}} {
496 variable NamespaceCurrent
497
498 if {[string compare "" $suffix]} then {
499 if {[file size $file]} then {
500 if {[catch {
501 file copy -force $file $file${suffix}
502 } result]} then {
503 if {$verbose >= 0} then {
504 wpLog o * $NamespaceCurrent "Error: unable to create backup file for `[file tail $file]': $result"
505 }
506 } else {
507 return 1
508 }
509 } else {
510 return -1
511 }
512 }
513 return 0
514 }
515
516 ##
517 ## Save data from a list into a file
518 ##
519 ## Args: list, filename, verbose {-1,0,1}, description, access flag
520 ## Returns: 1 is successful,
521 ## 0 otherwise
522 ##
523 proc listSave {listName file {verbose 0} {desc "file "} {access w}} {
524 upvar 1 $listName list
525
526 if {[createFile $file $verbose $desc]} then {
527 if {[catch {set fd [open $file $access]} result]} then {
528 if {$verbose >= 0} then {
529 wpLog o * "Error: unable to open ${desc}`$file' for writing: $result"
530 }
531 } else {
532 if {[info exists list]} then {
533 foreach data $list {
534 puts $fd [list $data]
535 }
536 }
537 close $fd
538 return 1
539 }
540 }
541 return 0
542 }
543
544 ##
545 ## Load data into a list from a file
546 ##
547 ## Args: list, filename, verbose {-1,0,1}, description, ignore regsub
548 ## Returns: 1 if successful,
549 ## 0 otherwise
550 ##
551 proc listLoad {listName file {verbose 0} {desc "file "} {ignore "^#"}} {
552 upvar 1 $listName list
553
554 if {[createFile $file $verbose $desc]} then {
555 if {[catch {set fd [open $file r]} result]} then {
556 if {$verbose >= 0} then {
557 wpLog o * "Error: unable to open ${desc}`$file' for reading: $result"
558 }
559 } else {
560 if {[info exists list]} then {
561 unset list
562 }
563 while {![eof $fd]} {
564 set line [replaceExpr [gets $fd] "^ "]
565 if {([string compare "" $line]) && \
566 (![regexp -- $ignore $line])} then {
567 append list $line " "
568 }
569 }
570 close $fd
571 return 1
572 }
573 }
574 return 0
575 }
576
577 ##
578 ## Save data from an array info a file
579 ##
580 ## Args: array, filename, verbose {-1,0,1}, description, access flag
581 ## Returns: 1 is successful,
582 ## 0 otherwise
583 ##
584 proc arraySave {arrayName file {verbose 0} {desc "file "} {access w}} {
585 upvar 1 $arrayName array
586
587 if {[createFile $file $verbose $desc]} then {
588 if {[catch {set fd [open $file $access]} result]} then {
589 if {$verbose >= 0} then {
590 wpLog o * "Error: unable to open ${desc}`$file' for writing: $result"
591 }
592 } else {
593 if {[array exists array]} then {
594 foreach name [lsort [array names array]] {
595 puts $fd "[list $name] [list $array($name)]"
596 }
597 close $fd
598 return 1
599 } else {
600 close $fd
601 }
602 }
603 }
604 return 0
605 }
606
607 ##
608 ## Load data into an array from a file
609 ##
610 ## Args: array, filename, verbose {-1,0,1}, description, ignore regsub
611 ## Returns: 1 if successful,
612 ## 0 otherwise
613 ##
614 proc arrayLoad {arrayName file {verbose 0} {desc "file "} {ignore "^#"}} {
615 upvar 1 $arrayName array
616
617 if {[createFile $file $verbose $desc]} then {
618 if {[catch {set fd [open $file r]} result]} then {
619 if {$verbose >= 0} then {
620 wpLog o * "Error: unable to open ${desc}`$file' for reading: $result"
621 }
622 } else {
623 if {[info exists array]} then {
624 unset array
625 }
626 while {![eof $fd]} {
627 set line [replaceExpr [gets $fd] "^ "]
628 if {([string compare "" $line]) && \
629 (![regexp -- $ignore $line])} then {
630 set array([lindex $line 0]) [lindex $line 1]
631 }
632 }
633 close $fd
634 return 1
635 }
636 }
637 return 0
638 }
639
640 ##
641 ## Set all elements in the given array the the given value
642 ##
643 ## Args: array name, value
644 ## Returns: 1 if the array exists
645 ## 0 otherwise
646 ##
647 proc arraySetAll {arrayName {value ""}} {
648 upvar 1 $arrayName array
649
650 if {[array exists array]} then {
651 foreach name [array names array] {
652 set array($name) $value
653 }
654 return 1
655 }
656 return 0
657 }
658
659 ##
660 ## Find the given element in an array
661 ##
662 ## Args: array name, element name
663 ## Returns: case sensitive element name if found,
664 ## nothing otherwise
665 ##
666 proc arrayFindElementName {array element} {
667 set list [lsort [array names $array]]
668 set index [lsearch -exact [string tolower $list] [string tolower $name]]
669 if {$index != -1} then {
670 return [lindex $list $index]
671 }
672 return
673 }
674
675 ##
676 ## Return length of longest data in an array at index
677 ##
678 ## Args: array name
679 ## Returns: length of longest name in an array
680 ##
681 proc arrayMaxElementDataLength {arrayName index} {
682 upvar 1 $arrayName array
683
684 set maxlength 0
685 foreach {name data} [array get array] {
686 set length [string length [lindex $data $index]]
687 if {$length > $maxlength} then {
688 set maxlength $length
689 }
690 }
691 return $maxlength
692 }
693
694 ##
695 ## Return length of the longest element in a list
696 ##
697 ## Args: list
698 ## Returns: length of longest element in the given list
699 ##
700 proc listMaxElementLength {list} {
701 set maxlength 0
702 foreach data $list {
703 set length [string length $data]
704 if {$length > $maxlength} then {
705 set maxlength $length
706 }
707 }
708 return $maxlength
709 }
710
711 ##
712 ## Split up a list into multiple elements
713 ##
714 ## Args: text, max list length, split char, trim chars
715 ## Returns: split list
716 ##
717 # FIXME: improve this
718 proc splitList {text {splitLength 75} {splitChar " "} {trimChars " "}} {
719 # Sanity check splitLength and splitChar
720 if {($splitLength >= 1) && ([string compare "" $splitChar])} then {
721 set elementSplitLength [expr $splitLength - 1]
722 set stringLength [string length $text] ;# Total length of string
723 set subStringLength 0 ;# Text left over
724 set elementLength 0 ;# Element length counter
725 set elementStartIndex 0 ;# Start of split element
726 set elementEndIndex 0 ;# End of split element
727 for {
728 set stringIndex 0
729 } {$stringIndex < $stringLength} {
730 incr stringIndex
731 } {
732 # If element length greater than/equal to split length,
733 # Or element length equal to split length - 1,
734 # And character at current string index is splitChar
735 if {(($elementLength >= $splitLength) ||
736 ($elementLength == $elementSplitLength)) &&
737 (![string compare $splitChar \
738 [string index $text $stringIndex]])} then {
739 # Split substring element from text
740 set string [string range $text $elementStartIndex $elementEndIndex]
741 # Append substring element list to list
742 lappend list [string trim $string $trimChars]
743 # Reset element length counter
744 set elementLength 0
745 # Start split of next element at the end + 1 of the current one
746 set elementStartIndex [expr $elementEndIndex + 1]
747 # Reset end of next element to the start of the next element
748 set elementEndIndex $elementStartIndex
749 # Track remaining text length
750 set subStringLength [expr $subStringLength + [string length $string]]
751 } else {
752 # Increment element length
753 incr elementLength
754 # Increment end of next element
755 incr elementEndIndex
756 }
757 }
758 # Append any left over text as a new element
759 if {$stringLength > $subStringLength} then {
760 lappend list [string trim [string range $text $subStringLength end] $trimChars]
761 }
762 # Whew...that was alot of work!
763 if {[info exists list]} then {
764 return $list
765 }
766 }
767 return
768 }
769
770 ##
771 ## Search an array for a given word or regexp
772 ##
773 ## Args: array name, word/regexp
774 ## Returns: list of indexes that match the given word/regexp
775 ##
776 proc arraySearch {array word} {
777 set word [string tolower $word]
778 set ret ""
779 foreach {name data} [array get $array] {
780 set string [string tolower $data]
781 if {[lsearch -regexp $string $word] != -1} then {
782 for {
783 set index 0
784 set indexes ""
785 } {
786 if {[regexp -- .*$word $string]} then {
787 lappend indexes $index
788 }
789 } {
790 incr index
791 }
792 lappend ret [list [concat $name $indexes]]
793 }
794 }
795 return $ret
796 }
797
798 ##
799 ## Return current command character
800 ##
801 ## Args: type {pub,msg,dcc,fil}
802 ## Returns: command character for the type given
803 ##
804 proc commandChar {type} {
805 global botnick
806 variable configData
807
808 switch -exact -- $type {
809 pub {
810 return $configData(commandchar)
811 }
812 msg {
813 return "/msg $botnick "
814 }
815 dcc {
816 return
817 }
818 fil {
819 return
820 }
821 default {
822 error "Unknown command character type: $type"
823 }
824 }
825 return
826 }
827
828 ##
829 ## Find option default for the given option name in a data list
830 ##
831 ## Args: data list, option name
832 ## Returns: option default if found,
833 ## nothing otherwise
834 ##
835 proc dataFormatDefault {list option} {
836 foreach i $list {
837 if {![string compare $option [lindex $i 0]]} then {
838 return [lindex $i 1]
839 }
840 }
841 return
842 }
843
844 ##
845 ## Find option value for the given option name in a data list
846 ##
847 ## Args: data format, data list, option name
848 ## Returns: option value if found,
849 ## nothing otherwise
850 ##
851 proc dataFormatValue {format data option} {
852 if {[set index [lsearch -exact $format $option]] != -1} then {
853 return [lindex $data $index]
854 }
855 return
856 }
857
858 ##
859 ## Replace option data in the given data list with a new value
860 ##
861 ## Args: data format, data list, option name, new value
862 ## Returns: data list
863 ##
864 proc dataFormatReplace {format data option value} {
865 if {[set index [lsearch -exact $format $option]] != -1} then {
866 return [lreplace $data $index $index $value]
867 }
868 return $data
869 }
870
871 ##
872 ## Create a data format list for a given data format and options
873 ##
874 ## Args: data format list, defaults, options {{option1 value} ...}
875 ## Returns: data format list with options and values in proper order
876 ##
877 proc dataFormatBuild {format defaults args} {
878 set ret ""
879 foreach arg $args {
880 set [lindex $arg 0] [lindex $arg 1]
881 }
882 foreach opt $format {
883 if {[info exists $opt]} then {
884 lappend ret [set $opt]
885 } else {
886 lappend ret [dataFormatDefault $defaults $opt]
887 }
888 }
889 return $ret
890 }
891
892 ##
893 ## Convert a data list from one format to another
894 ##
895 ## Args: from format, to format, data list
896 ## Returns: data list
897 ##
898 proc dataFormatConvert {fromFormat toFormat data} {
899 set ret ""
900 set index 0
901 foreach opt $fromFormat {
902 set $opt [lindex $data $index]
903 incr index
904 }
905 foreach opt $toFormat {
906 if {[info exists $opt]} then {
907 lappend ret [set $opt]
908 } else {
909 lappend ret [dataFormatDefault $defaults $opt]
910 }
911 }
912 return $ret
913 }
914
915 ##
916 ## Scan the given file for module options
917 ##
918 ## Args: file, args {only scan for these options}
919 ## Returns: list of module options if the given file is a module,
920 ## nothing otherwise
921 ## Errors: unable to open file for reading
922 ##
923 proc scanModule {file args} {
924 variable moduleDatabaseConfig
925 variable moduleDatabaseFormat
926
927 if {[catch {set fd [open $file r]} result]} then {
928 error $result
929 } else {
930 set ret ""
931 if {![string compare "" $args]} then {
932 set baseOptions [lindex $moduleDatabaseFormat([set moduleDatabaseConfig(version)]) 0]
933 set extraOptions [lindex $moduleDatabaseFormat([set moduleDatabaseConfig(version)]) 1]
934 set scanOptions "name $baseOptions"
935 set formatOptions "name $baseOptions $extraOptions"
936 } else {
937 set scanOptions $args
938 set formatOptions $args
939 }
940 for {
941 set lineCount 0
942 set optionCount 0
943 set continuedLine 0
944 } {(![eof $fd]) && ($lineCount <= $moduleDatabaseConfig(scanlines))} {
945 incr lineCount
946 } {
947 gets $fd line
948 if {[regexp -- "^# .*:.*" $line]} then {
949 set opt [string trimright [lindex $line 1] :]
950 if {[lsearch -glob $scanOptions $opt] != -1} then {
951 set data [string trimright [string trimleft [string range $line [string first : $line] end] " \t:"] " \t\\"]
952 if {![info exists $opt]} then {
953 set $opt $data
954 } else {
955 append $opt " $data"
956 }
957 }
958 if {[regexp -- \\\\$ $line]} then {
959 set continuedLine 1
960 } else {
961 set continuedLine 0
962 }
963 } elseif {($continuedLine) && ([info exists opt])} then {
964 append $opt " [string trimright [string trimleft $line " \t#"] " \t\\"]"
965 if {![regexp -- \\\\$ $line]} then {
966 set continuedLine 0
967 }
968 }
969 }
970 close $fd
971 if {(![string compare "" $args]) && \
972 ((![info exists name]) || \
973 ([catch {set md5sum [md5Sum $file]}]))} then {
974 return
975 }
976 foreach option $formatOptions {
977 if {(![info exists $option]) || \
978 (![string compare "" [set $option]])} then {
979 set $option [dataFormatDefault $moduleDatabaseConfig(defaults) $option]
980 }
981 lappend ret [set $option]
982 }
983 return $ret
984 }
985 }
986
987 ##
988 ## Get data from module db data array
989 ##
990 ## Args: module name, data type
991 ## Returns: data for the given module's data type if it exists,
992 ## nothing otherwise
993 ##
994 proc getModuleDatabaseData {module type} {
995 variable moduleDatabaseConfig
996 variable moduleDatabaseFormat
997 variable moduleDatabaseData
998
999 if {[moduleExists $module]} then {
1000 set index [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] $type]
1001 if {$index != -1} then {
1002 return [lindex $moduleDatabaseData($module) $index]
1003 }
1004 }
1005 return
1006 }
1007
1008 ##
1009 ## Set data in module db data array
1010 ##
1011 ## Args: module name, data type, data
1012 ## Returns: 1 if valid module and data type,
1013 ## 0 otherwise
1014 ##
1015 proc setModuleDatabaseData {module type data} {
1016 variable moduleDatabaseConfig
1017 variable moduleDatabaseFormat
1018 variable moduleDatabaseData
1019 variable moduleDatabaseDataChanged
1020
1021 if {[moduleExists $module]} then {
1022 set index [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] $type]
1023 if {$index != -1} then {
1024 set moduleDatabaseData($module) [lreplace $moduleDatabaseData($module) $index $index [list $data]]
1025 set moduleDatabaseDataChanged 1
1026 return 1
1027 }
1028 }
1029 return 0
1030 }
1031
1032 ##
1033 ## Save module database
1034 ##
1035 ## Args: verbose {-1,0,1}
1036 ## Returns: 1 if successful,
1037 ## 0 otherwise
1038 ##
1039 proc saveModuleDatabase {{verbose 0}} {
1040 variable configData
1041 variable moduleDatabaseConfig
1042 variable moduleDatabaseData
1043 variable moduleDatabaseDataChanged
1044
1045 if {[createFile $configData(moddbfile) $verbose "module database file "]} then {
1046 if {[catch {set fd [open $configData(moddbfile) w]} result]} then {
1047 if {$verbose >= 0} then {
1048 wpLog o * "Error: unable to open module database file `$configData(moddbfile)' for writing: $result"
1049 }
1050 } else {
1051 puts $fd "# $moduleDatabaseConfig(header)$moduleDatabaseConfig(version)"
1052 close $fd
1053 set ret [arraySave moduleDatabaseData $configData(moddbfile) $verbose "module database file " a]
1054 if {$ret} then {
1055 set moduleDatabaseDataChanged 0
1056 }
1057 return $ret
1058 }
1059 }
1060 return 0
1061 }
1062
1063 ##
1064 ## Load module database
1065 ##
1066 ## Args: verbose {-1,0,1}
1067 ## Returns: 1 if successful,
1068 ## 0 otherwise
1069 ##
1070 proc loadModuleDatabase {{verbose 0}} {
1071 variable configData
1072 variable moduleDatabaseConfig
1073 variable moduleDatabaseFormat
1074 variable moduleDatabaseData
1075 variable moduleDatabaseDataChanged
1076
1077 if {![file exists $configData(moddbfile)]} then {
1078 return -1
1079 } else {
1080 if {[catch {set fd [open $configData(moddbfile) r]} result]} then {
1081 if {$verbose >= 0} then {
1082 wpLog o * "Error: unable to open module database file `$configData(moddbfile)' for reading: $result"
1083 }
1084 } else {
1085 set firstline [replaceExpr [gets $fd] "^ "]
1086 if {[regexp -- "^# $moduleDatabaseConfig(header)" $firstline]} then {
1087 regsub -all -- "^# $moduleDatabaseConfig(header)" $firstline "" version
1088 if {![string compare [set version [string trim $version]] $moduleDatabaseConfig(version)]} then {
1089 close $fd
1090 return [arrayLoad moduleDatabaseData $configData(moddbfile) $verbose "module database file "]
1091 } elseif {[info exists moduleDatabaseFormat($version)]} then {
1092 if {[info exists moduleDatabaseData]} then {
1093 unset moduleDatabaseData
1094 }
1095 while {![eof $fd]} {
1096 set line [replaceExpr [gets $fd] "^ "]
1097 if {([string compare "" $line]) && \
1098 (![regexp -- "^#" $line])} then {
1099 set moduleDatabaseData([lindex $line 0]) [dataFormatConvert [join $moduleDatabaseFormat($version)] [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] [lindex $line 1]]
1100 }
1101 }
1102 close $fd
1103 set moduleDatabaseDataChanged 0
1104 return 1
1105 } else {
1106 wpLog o * "Error: unknown module database version: $version"
1107 }
1108 } else {
1109 wpLog o * "Error: unknown module database format: [string trimleft $firstline " \t#"]"
1110 }
1111 }
1112 close $fd
1113 }
1114 return 0
1115 }
1116
1117 ##
1118 ## Compare loaded module database data to module files
1119 ##
1120 ## Args: verbose {-1,0,1}
1121 ## Returns: 1 if data matches,
1122 ## 0 otherwise
1123 ##
1124 proc compareModuleDatabase {{verbose 0}} {
1125 variable configData
1126 variable moduleDatabaseConfig
1127
1128 foreach path $configData(modulepath) {
1129 set files [findFiles $path $moduleDatabaseConfig(maxdepth) .tcl]
1130 if {[string compare "" $files]} then {
1131 set comparedModules ""
1132 set moduleList [listModules]
1133 # Return early if we don't have any modules listed in the db
1134 if {![string compare "" $moduleList]} then {
1135 return 0
1136 }
1137 foreach file $files {
1138 set shortfile [string trimleft [string range $file [string length $path] end] /]
1139 if {$verbose >= 1} then {
1140 wpLog o * "Comparing file `$shortfile'"
1141 }
1142 if {[catch {set name [lindex [scanModule $file name] 0]} result]} then {
1143 if {$verbose >= 0} then {
1144 wpLog o * "Error: unable to open file `$shortfile' for reading: $result"
1145 }
1146 }
1147 # Process this file if it's a module
1148 if {[string compare "" $name]} then {
1149 # Get module filename from db
1150 set filename [getModuleDatabaseData $name file]
1151 # Compare module filename and make sure it wasn't renamed or moved
1152 if {[string compare $file $filename]} then {
1153 return 0
1154 }
1155 # Compare md5 from module db and sure the module hasn't changed
1156 if {([catch {set md5sum [md5Sum $filename]}]) || \
1157 ([string compare [getModuleDatabaseData $name md5sum] $md5sum])} then {
1158 return 0
1159 }
1160 # Append module name to list of compared modules
1161 lappend comparedModules $name
1162 }
1163 }
1164 # Compare list of compared modules with list of modules from the db
1165 if {[string compare [lsort $comparedModules] $moduleList]} then {
1166 return 0
1167 }
1168 }
1169 }
1170 return 1
1171 }
1172
1173 ##
1174 ## Rebuild module database
1175 ##
1176 ## Args: verbose {-1,0,1}
1177 ## Returns: nothing
1178 ##
1179 proc rebuildModuleDatabase {{verbose 0}} {
1180 variable configData
1181 variable moduleDatabaseConfig
1182 variable moduleDatabaseFormat
1183 variable moduleDatabaseData
1184
1185 foreach path $configData(modulepath) {
1186 set files [findFiles $path $moduleDatabaseConfig(maxdepth) .tcl]
1187 set loadIndex [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] load]
1188 foreach file $files {
1189 set shortfile [string trimleft [string range $file [string length $path] end] /]
1190 if {$verbose >= 1} then {
1191 wpLog o * "Scanning file `$shortfile'"
1192 }
1193 if {[catch {set data [scanModule $file]} result]} then {
1194 if {$verbose >= 0} then {
1195 wpLog o * "Warning: unable to open file `$shortfile' for reading: $result"
1196 }
1197 } else {
1198 set name [lindex $data 0]
1199 if {[string compare "" $name]} then {
1200 if {[moduleExists $name]} then {
1201 set tmp($name) [lreplace [lrange $data 1 end] $loadIndex $loadIndex [lindex $moduleDatabaseData($name) $loadIndex]]
1202 } else {
1203 set tmp($name) [lrange $data 1 end]
1204 }
1205 }
1206 }
1207 }
1208 }
1209 if {[info exists moduleDatabaseData]} then {
1210 unset moduleDatabaseData
1211 }
1212 if {[info exists tmp]} then {
1213 array set moduleDatabaseData [array get tmp]
1214 }
1215 return
1216 }
1217
1218 ##
1219 ## List all modules in the database
1220 ##
1221 ## Args: none
1222 ## Returns: list of modules in module database
1223 ##
1224 proc listModules {{loaded 0}} {
1225 variable moduleDatabaseData
1226 variable moduleLoadedList
1227
1228 if {$loaded} then {
1229 return [lsort $moduleLoadedList]
1230 }
1231 return [lsort [array names moduleDatabaseData]]
1232 }
1233
1234 ##
1235 ## Check if the given module exists
1236 ##
1237 ## Args: module name
1238 ## Returns: 1 if the given module exists
1239 ## 0 otherwise
1240 ##
1241 proc moduleExists {module} {
1242 variable moduleDatabaseData
1243
1244 if {[info exists moduleDatabaseData($module)]} then {
1245 return 1
1246 }
1247 return 0
1248 }
1249
1250 ##
1251 ## Check if a module is loaded
1252 ##
1253 ## Args: module name
1254 ## Returns: 1 if the given module is loaded
1255 ## 0 otherwise
1256 ##
1257 proc moduleLoaded {module} {
1258 variable moduleLoadedList
1259
1260 if {[lsearch -exact $moduleLoadedList $module] != -1} then {
1261 return 1
1262 }
1263 return 0
1264 }
1265
1266 ##
1267 ## Add/remove bindings for a given module
1268 ##
1269 ## Args: mode {bind|unbind}, module,
1270 ## args {{type ...} {option ...} {regsub ... ...}}
1271 ## Returns: nothing
1272 ##
1273 # FIXME: optimize
1274 proc moduleBindUnbind {mode module args} {
1275 variable NamespaceCurrent
1276
1277 if {[info exists ${NamespaceCurrent}::${module}::bindDefaults]} then {
1278 set bindtypes ""
1279 set bindoptions ""
1280 foreach option $args {
1281 switch -exact -- [lindex $option 0] {
1282 type {
1283 # dcc msg pub ...
1284 foreach opt [lrange $option 1 end] {
1285 lappend bindtypes $opt
1286 }
1287 }
1288 option {
1289 # commandchar noauto ...
1290 foreach opt [lrange $option 1 end] {
1291 lappend bindoptions $opt
1292 }
1293 }
1294 regsub {
1295 # replace regexp 'replacewhat' with 'replacewith'
1296 foreach opt [lrange $option 1 end] {
1297 foreach {rwhat rwith} $opt {break}
1298 # FIXME: better fix for leading '+/$'
1299 regsub -- "\[\\+|\\$\]" $rwhat "\\\\&" rwhat
1300 set replace($rwhat) $rwith
1301 }
1302 }
1303 }
1304 }
1305 foreach {proc data} [array get ${NamespaceCurrent}::${module}::bindDefaults] {
1306 foreach bind $data {
1307 foreach {type flags mask options help} $bind {break}
1308 if {([lsearch -exact $options noauto] != -1) && \
1309 ((![string compare "" $bindoptions]) || \
1310 ([lsearch -exact $bindoptions noauto] == -1))} then {
1311 continue
1312 }
1313 if {([string compare "" $bindtypes]) && \
1314 ([lsearch -exact $bindtypes $type] == -1)} then {
1315 continue
1316 }
1317 if {[string compare "" $bindoptions]} then {
1318 set found 0
1319 foreach opt $options {
1320 if {[lsearch -exact $bindoptions $opt] != -1} then {
1321 set found 1
1322 break
1323 }
1324 }
1325 if {!$found} then {
1326 continue
1327 }
1328 }
1329 if {[lsearch -exact $options commandchar] != -1} then {
1330 set mask "[commandChar pub]$mask"
1331 }
1332 if {[array exists replace]} then {
1333 foreach {replacewhat replacewith} [array get replace] {
1334 regsub -all -- $replacewhat $mask $replacewith mask
1335 }
1336 }
1337 # bind/unbind
1338 $mode $type $flags $mask ${NamespaceCurrent}::${module}::$proc
1339 }
1340 }
1341 }
1342 return
1343 }
1344
1345 ##
1346 ## Load a module
1347 ##
1348 ## Args: module name, verbose {-1,0,1}, args {loop detection}
1349 ## Returns: nothing
1350 ## Errors: if unable to load module
1351 ##
1352 proc moduleLoad {module {verbose 0} args} {
1353 variable NamespaceCurrent
1354 variable moduleLoadedList
1355
1356 if {[lsearch -exact [set loop [lindex $args 0]] $module] == -1} then {
1357 if {[moduleExists $module]} then {
1358 set preload ""
1359 set requires [getModuleDatabaseData $module requires]
1360 foreach required $requires {
1361 set preloadModule [whichModuleCommand $required]
1362 if {[string compare "" $preloadModule]} then {
1363 if {([lsearch -exact $preload $preloadModule] == -1) && \
1364 ([string compare wp $preloadModule]) && \
1365 (![moduleLoaded $preloadModule])} then {
1366 lappend preload $preloadModule
1367 }
1368 } else {
1369 error "required command `$required' not found."
1370 }
1371 }
1372 if {[string compare "" $preload]} then {
1373 foreach premod $preload {
1374 if {[catch {moduleLoad $premod $verbose [concat $loop $module]} result]} then {
1375 error $result
1376 }
1377 }
1378 }
1379 if {[catch {source [getModuleDatabaseData $module file]} result]} then {
1380 error $result
1381 } else {
1382 package forget $module
1383 package provide ${NamespaceCurrent}::${module} [getModuleDatabaseData $module version]
1384 moduleConfigLoad $module 1
1385 moduleConfigCheckdefs $module 1
1386 moduleDataLoad $module 1
1387 # Imported commands '# requires: ...'
1388 if {[string compare "" $requires]} then {
1389 set Eval "namespace eval ${NamespaceCurrent}::${module} \{\n namespace forget *\n namespace import"
1390 foreach required $requires {
1391 if {[string compare "" [set command [whichCommand $required]]]} then {
1392 append Eval " $command"
1393 }
1394 }
1395 append Eval "\n\}"
1396 eval $Eval
1397 }
1398 # Exported commands '# provides: ...'
1399 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
1400 set Eval "namespace eval ${NamespaceCurrent}::${module} \{\n namespace export"
1401 foreach provided $provides {
1402 append Eval " $provided"
1403 }
1404 append Eval "\n\}"
1405 eval $Eval
1406 }
1407 if {[string compare "" [info commands ${NamespaceCurrent}::${module}::ModuleInit]]} then {
1408 ${NamespaceCurrent}::${module}::ModuleInit
1409 }
1410 # FIXME: check for bindings? duplicates?
1411 moduleBindUnbind bind $module
1412 if {![getModuleDatabaseData $module load]} then {
1413 setModuleDatabaseData $module load 1
1414 }
1415 if {[lsearch -exact $moduleLoadedList $module] == -1} then {
1416 lappend moduleLoadedList $module
1417 if {$verbose >= 1} then {
1418 wpLog o * "Module loaded: $module"
1419 }
1420 }
1421 }
1422 } else {
1423 error "No such module: $module"
1424 }
1425 } else {
1426 regsub -all -- " " $loop " -> " loop
1427 error "Preload endless loop: $loop -> $module"
1428 }
1429 return
1430 }
1431
1432 ##
1433 ## Unload a module
1434 ##
1435 ## Args: module name, verbose {-1,0,1}
1436 ## Returns: nothing
1437 ## Errors: if unable to completely unload module
1438 ##
1439 proc moduleUnload {module {verbose 0}} {
1440 variable NamespaceCurrent
1441 variable moduleLoadedList
1442
1443 # FIXME: handle dependant modules and modules that can't be unloaded
1444 if {[moduleExists $module]} then {
1445 if {[string compare "" [info commands ${NamespaceCurrent}::${module}::ModuleDestroy]]} then {
1446 ${NamespaceCurrent}::${module}::ModuleDestroy
1447 }
1448 # FIXME: check for bindings?
1449 moduleBindUnbind unbind $module
1450 moduleConfigSave $module 1
1451 moduleDataSave $module 1
1452 if {[catch {namespace delete ${NamespaceCurrent}::${module}} result]} then {
1453 error $result
1454 } else {
1455 package forget ${NamespaceCurrent}::${module}
1456 if {[getModuleDatabaseData $module load] == 1} then {
1457 setModuleDatabaseData $module load 0
1458 }
1459 set index [lsearch -exact $moduleLoadedList $module]
1460 if {$index != -1} then {
1461 set moduleLoadedList [lreplace $moduleLoadedList $index $index]
1462 if {$verbose >= 1} then {
1463 wpLog o * "Module unloaded: $module"
1464 }
1465 }
1466 }
1467 } else {
1468 error "No such module: $module"
1469 }
1470 return
1471 }
1472
1473 ##
1474 ## Save configuration settings for the given module
1475 ##
1476 ## Args: module, force {0,1}, verbose {-1,0,1}
1477 ## Returns: 1 if settings saved
1478 ## 0 otherwise
1479 ##
1480 proc moduleConfigSave {module {force 0} {verbose 0}} {
1481 variable NamespaceCurrent
1482 variable configData
1483
1484 if {([string compare "" \
1485 [set file [getModuleDatabaseData $module config]]]) && \
1486 ([createDir $configData(configpath)])} then {
1487 set cfgfile [file join $configData(configpath) $file]
1488 if {([getModuleDatabaseData $module load]) && \
1489 (($force) || \
1490 (![info exists ${NamespaceCurrent}::${module}::configDataChanged]) || \
1491 ([set ${NamespaceCurrent}::${module}::configDataChanged]))} then {
1492 if {[arraySave ${NamespaceCurrent}::${module}::configData $cfgfile 0 "$module configuration file "]} then {
1493 if {$verbose >= 1} then {
1494 wpLog o * "Writing $module config file..."
1495 }
1496 set ${NamespaceCurrent}::${module}::configDataChanged 0
1497 return 1
1498 } elseif {$verbose >= 0} then {
1499 wpLog o * "Error writing $module config file."
1500 }
1501 }
1502 }
1503 return 0
1504 }
1505
1506 ##
1507 ## Load configuration settings for the given module
1508 ##
1509 ## Args: module, force {0,1}, verbose {-1,0,1}
1510 ## Returns: 1 if settings loaded
1511 ## 0 otherwise
1512 ##
1513 proc moduleConfigLoad {module {force 0} {verbose 0}} {
1514 variable NamespaceCurrent
1515 variable configData
1516
1517 if {([string compare "" \
1518 [set file [getModuleDatabaseData $module config]]]) && \
1519 ([createDir $configData(configpath)])} then {
1520 set cfgfile [file join $configData(configpath) $file]
1521 if {($force) || \
1522 (![info exists ${NamespaceCurrent}::${module}::configDataChanged]) || \
1523 (![set ${NamespaceCurrent}::${module}::configDataChanged])} then {
1524 if {[arrayLoad ${NamespaceCurrent}::${module}::configData $cfgfile 0 "$module configuration file "]} then {
1525 if {$verbose >= 1} then {
1526 wpLog o * "Loading $module config file..."
1527 }
1528 set ${NamespaceCurrent}::${module}::configDataChanged 0
1529 return 1
1530 } elseif {$verbose >= 0} then {
1531 wpLog o * "Error loading $module config file."
1532 }
1533 }
1534 }
1535 return 0
1536 }
1537
1538 ##
1539 ## Check and set default configuration settings for the given module
1540 ##
1541 ## Args: module, force {0,1}, verbose {-1,0,1}
1542 ## Returns: nothing
1543 ##
1544 proc moduleConfigCheckdefs {module {force 0} {verbose 0}} {
1545 variable NamespaceCurrent
1546
1547 if {([array exists ${NamespaceCurrent}::${module}::configDefaults]) && \
1548 ([string compare "" [getModuleDatabaseData $module config]])} then {
1549 set Changed 0
1550 # Unset unknown variables
1551 foreach name [array names ${NamespaceCurrent}::${module}::configData] {
1552 if {![info exists ${NamespaceCurrent}::${module}::configDefaults($name)]} then {
1553 unset ${NamespaceCurrent}::${module}::configData($name)
1554 set Changed 1
1555 }
1556 }
1557 # Set missing variables to defaults
1558 foreach {name data} [array get ${NamespaceCurrent}::${module}::configDefaults] {
1559 if {![info exists ${NamespaceCurrent}::${module}::configData($name)]} then {
1560 set ${NamespaceCurrent}::${module}::configData($name) [lindex $data 1]
1561 set Changed 1
1562 }
1563 }
1564 # FIXME: do this with a trace?
1565 if {$Changed} then {
1566 set ${NamespaceCurrent}::${module}::configDataChanged 1
1567 }
1568 }
1569 return
1570 }
1571
1572 ##
1573 ## Handle config data for a list of modules
1574 ##
1575 ## Args: action {load|save|checkdefs}, module list, force {0,1},
1576 ## verbose {-1,0,1}
1577 ## Returns: nothing
1578 ##
1579 proc moduleConfig {action modules {force 0} {verbose 0}} {
1580 if {![string compare * $modules]} then {
1581 set modules [listModules 1]
1582 }
1583 switch -exact -- $action {
1584 save {
1585 foreach module $modules {
1586 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1587 moduleConfigSave $module $force $verbose
1588 }
1589 }
1590 }
1591 load {
1592 foreach module $modules {
1593 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1594 moduleConfigLoad $module $force $verbose
1595 }
1596 }
1597 }
1598 checkdefs {
1599 foreach module $modules {
1600 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1601 moduleConfigCheckdefs $module $force $verbose
1602 }
1603 }
1604 }
1605 }
1606 return
1607 }
1608
1609 ##
1610 ## Save data for the given module
1611 ##
1612 ## Args: module, force {0,1}, verbose {-1,0,1}
1613 ## Returns: nothing
1614 ##
1615 proc moduleDataSave {module {force 0} {verbose 0}} {
1616 variable NamespaceCurrent
1617 variable configData
1618
1619 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1620 ([createDir $configData(datapath)])} then {
1621 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1622 foreach {type file desc} $data {break}
1623 if {([info exists type]) && ([info exists file]) && \
1624 ([info exists desc])} then {
1625 set Changed ${NamespaceCurrent}::${module}::${name}Changed
1626 if {($force) || ((![info exists $Changed]) || ([set $Changed]))} then {
1627 if {[${type}Save ${NamespaceCurrent}::${module}::$name [file join $configData(datapath) $file]]} then {
1628 if {$verbose >= 1} then {
1629 wpLog o * $NamespaceCurrent "Writing $desc data file..."
1630 }
1631 set $Changed 0
1632 } elseif {$verbose >= 0} then {
1633 wpLog o * $NamespaceCurrent "Error writing $desc data file!"
1634 }
1635 }
1636 }
1637 }
1638 }
1639 return
1640 }
1641
1642 ##
1643 ## Load data for the given module
1644 ##
1645 ## Args: module, force {0,1}, verbose {-1,0,1}
1646 ## Returns: nothing
1647 ##
1648 proc moduleDataLoad {module {force 0} {verbose 0}} {
1649 variable NamespaceCurrent
1650 variable configData
1651
1652 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1653 ([createDir $configData(datapath)])} then {
1654 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1655 foreach {type file desc} $data {break}
1656 if {([info exists type]) && ([info exists file]) && \
1657 ([info exists desc])} then {
1658 set Changed ${NamespaceCurrent}::${module}::${name}Changed
1659 if {($force) || ((![info exists $Changed]) || ([set $Changed]))} then {
1660 if {[${type}Load ${NamespaceCurrent}::${module}::$name [file join $configData(datapath) $file]]} then {
1661 if {$verbose >= 1} then {
1662 wpLog o * $NamespaceCurrent "Reloading $desc data file..."
1663 }
1664 set $Changed 0
1665 } elseif {$verbose >= 0} then {
1666 wpLog o * $NamespaceCurrent "Error reloading $desc data file!"
1667 }
1668 }
1669 }
1670 }
1671 }
1672 return
1673 }
1674
1675 ##
1676 ## Backup data for the given module
1677 ##
1678 ## Args: module, force {0,1}, verbose {-1,0,1}
1679 ## Returns: nothing
1680 ##
1681 proc moduleDataBackup {module {force 0} {verbose 0}} {
1682 variable NamespaceCurrent
1683 variable configData
1684
1685 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1686 ([createDir $configData(datapath)])} then {
1687 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1688 foreach {type file desc} $data {break}
1689 if {([info exists type]) && ([info exists file]) && \
1690 ([info exists desc])} then {
1691 if {[set result [backupFile [file join $configData(datapath) $file] $verbose]]} then {
1692 if {($result >= 1) && ($verbose >= 1)} then {
1693 wpLog o * $NamespaceCurrent "Backing up $desc data file..."
1694 }
1695 } elseif {$verbose >= 0} then {
1696 wpLog o * $NamespaceCurrent "Error backing up $desc data file!"
1697 }
1698 }
1699 }
1700 }
1701 return
1702 }
1703
1704 ##
1705 ## Handle data for a list of modules
1706 ##
1707 ## Args: action {load|save|backup}, module list, force {0,1},
1708 ## verbose {-1,0,1}
1709 ## Returns: nothing
1710 ##
1711 proc moduleData {action modules {force 0} {verbose 0}} {
1712 if {![string compare * $modules]} then {
1713 set modules [listModules 1]
1714 }
1715 switch -exact -- $action {
1716 save {
1717 foreach module $modules {
1718 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1719 moduleDataSave $module $force $verbose
1720 }
1721 }
1722 }
1723 load {
1724 foreach module $modules {
1725 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1726 moduleDataLoad $module $force $verbose
1727 }
1728 }
1729 }
1730 backup {
1731 foreach module $modules {
1732 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1733 moduleDataBackup $module $force $verbose
1734 }
1735 }
1736 }
1737 }
1738 return
1739 }
1740
1741 ##
1742 ## Builds command matching table from module database
1743 ##
1744 ## Args: none
1745 ## Returns: nothing
1746 ##
1747 proc buildCommandTable {{verbose 0}} {
1748 variable NamespaceCurrent
1749 variable ExportList
1750 variable commandTable
1751
1752 foreach command $ExportList {
1753 if {![info exists tmp($command)]} then {
1754 if {$verbose >= 2} then {
1755 wpLog o * "Adding command: `$command' as `${NamespaceCurrent}::$command'"
1756 }
1757 set tmp($command) ${NamespaceCurrent}::$command
1758 } elseif {$verbose >= 0} then {
1759 wpLog o * "Warning: ignoring duplicate command `$command', conflicts with `$tmp($command)'"
1760 }
1761 }
1762 foreach module [listModules] {
1763 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
1764 foreach command $provides {
1765 if {![info exists tmp($command)]} then {
1766 if {$verbose >= 2} then {
1767 wpLog o * "Adding command: `$command' as `${NamespaceCurrent}::${module}::$command'"
1768 }
1769 set tmp($command) ${NamespaceCurrent}::${module}::$command
1770 } elseif {$verbose >= 0} then {
1771 wpLog o * "Warning: ignoring duplicate command `$command', conflicts with `$tmp($command)'"
1772 }
1773 }
1774 }
1775 }
1776 if {[info exists commandTable]} then {
1777 unset commandTable
1778 }
1779 array set commandTable [array get tmp]
1780 return
1781 }
1782
1783 ##
1784 ## Return full namespace path for the given command
1785 ##
1786 ## Args: command
1787 ## Returns: full namespace path for the given command if it exists
1788 ## nothing otherwise
1789 ##
1790 proc whichCommand {command} {
1791 variable commandTable
1792
1793 if {[info exists commandTable($command)]} then {
1794 return $commandTable($command)
1795 }
1796 return
1797 }
1798
1799 ##
1800 ## Return full namespace path for the given module
1801 ##
1802 ## Args: module
1803 ## Returns: full namespace path for the given module if it's loaded
1804 ## nothing otherwise
1805 ##
1806 proc whichModule {module} {
1807 variable NamespaceCurrent
1808
1809 if {![string compare $module [namespace tail $NamespaceCurrent] $module]} then {
1810 return $NamespaceCurrent
1811 } elseif {[moduleLoaded $module]} then {
1812 return ${NamespaceCurrent}::$module
1813 }
1814 return
1815 }
1816
1817 ##
1818 ## Return module name that provides the given command
1819 ##
1820 ## Args: command
1821 ## Returns: name of module that provides the given command
1822 ## nothing otherwise
1823 ##
1824 proc whichModuleCommand {command} {
1825 variable NamespaceCurrent
1826 variable commandTable
1827
1828 if {[info exists commandTable($command)]} then {
1829 if {![string compare ${NamespaceCurrent}::$command \
1830 $commandTable($command)]} then {
1831 return [namespace tail $NamespaceCurrent]
1832 }
1833 return [namespace tail [namespace qualifiers $commandTable($command)]]
1834 }
1835 return
1836 }
1837
1838 ##
1839 ## Compare the given version to eggdrop's version
1840 ##
1841 ## Args: version
1842 ## Returns: 0 if eggdrop's version is older then the given version
1843 ## 1 if eggdrop's version matches the given version
1844 ## 2 if eggdrop's version is newer then the given version
1845 ##
1846 proc compareVersion {version} {
1847 global numversion
1848
1849 if {[string compare "" $version]} then {
1850 if {([info exists numversion]) || \
1851 (![catch {set numversion}]) || \
1852 ([info exists numversion])} then {
1853 if {[regexp -- \\. $version]} then {
1854 regsub -all -- \\. $version 0 version
1855 set version ${version}00
1856 }
1857 if {![regexp -- \[^0-9\] $version]} then {
1858 if {$numversion > $version} then {
1859 return 2
1860 } elseif {$numversion == $version} then {
1861 return 1
1862 }
1863 }
1864 }
1865 }
1866 return 0
1867 }
1868
1869 ##
1870 ## Log module information
1871 ##
1872 ## Args: level, channel, args ({<namespace>} {<text>} | {<text>})
1873 ## Returns: nothing
1874 ##
1875 proc wpLog {level channel args} {
1876 if {[llength $args] == 2} then {
1877 if {[string compare wp [set namespace [namespace tail [lindex $args 0]]]]} then {
1878 putloglev $level $channel "Wolfpack: \[$namespace\] [lindex $args 1]"
1879 } else {
1880 putloglev $level $channel "Wolfpack: [lindex $args 1]"
1881 }
1882 } else {
1883 putloglev $level $channel "Wolfpack: [join $args]"
1884 }
1885 return
1886 }
1887
1888 ##
1889 ## Trace configuration changes
1890 ##
1891 ## Args: name1, name2, operation
1892 ## Returns: nothing
1893 ##
1894 proc TraceConfigData {name1 name2 op} {
1895 variable configData
1896 variable oldConfigData
1897
1898 if {[string compare $oldConfigData($name2) $configData($name2)]} then {
1899 switch -exact -- $name2 {
1900 commandchar {
1901 foreach module [listModules 1] {
1902 moduleBindUnbind unbind $module "type pub" "option commandchar" [list regsub "^[commandChar pub] $oldConfigData(commandchar)"]
1903 moduleBindUnbind bind $module "type pub" "option commandchar"
1904 }
1905 }
1906 }
1907 set oldConfigData($name2) $configData($name2)
1908 }
1909 return
1910 }
1911
1912 ##
1913 ## Evaluate command line arguments
1914 ##
1915 ## Args: none
1916 ## Returns: nothing
1917 ##
1918 proc EvalArgs {argc argv argv0} {
1919 variable NamespaceCurrent
1920 variable optionData
1921
1922 # Make sure defaults are sane
1923 arraySetAll optionData 0
1924 for {set index 0} {$index < $argc} {incr index} {
1925 set option [lindex $argv $index]
1926 switch -regexp -- $option {
1927 (^--config$) {
1928 set optionData(config) 1
1929 }
1930 (^--rebuild$) {
1931 set optionData(rebuild) 1
1932 }
1933 (^--norebuild$) {
1934 set optionData(norebuild) 1
1935 }
1936 (^--time$) {
1937 set optionData(time) 1
1938 }
1939 (^--verbose$) {
1940 incr optionData(verbose)
1941 }
1942 (^--quiet$) {
1943 incr optionData(quiet) -1
1944 }
1945 (^--debug$) {
1946 set optionData(debug) 1
1947 }
1948 (^--help$) {
1949 ShowUsage $argv0
1950 exit
1951 }
1952 (^--version$) {
1953 puts "[file tail $argv0] version [package require ${NamespaceCurrent}]"
1954 exit
1955 }
1956 (^-\[^-\]*$) {
1957 set suboptions [split $option ""]
1958 set sublength [llength [split $suboptions]]
1959 for {set subindex 0} {$subindex < $sublength} {incr subindex} {
1960 set suboption [lindex $suboptions $subindex]
1961 switch -exact -- $suboption {
1962 - {
1963 continue
1964 }
1965 c {
1966 set optionData(config) 1
1967 }
1968 r {
1969 set optionData(rebuild) 1
1970 }
1971 n {
1972 set optionData(norebuild) 1
1973 }
1974 t {
1975 set optionData(time) 1
1976 }
1977 v {
1978 incr optionData(verbose)
1979 }
1980 q {
1981 incr optionData(quiet) -1
1982 }
1983 d {
1984 set optionData(debug) 1
1985 }
1986 default {
1987 if {(![info exists invalidopt]) || \
1988 ($subindex == 1) || \
1989 ([lsearch -exact $invalidopt $option] == -1)} then {
1990 lappend invalidopt $option
1991 }
1992 }
1993 }
1994 }
1995 }
1996 default {
1997 lappend invalidopt $option
1998 }
1999 }
2000 }
2001
2002 # complain about invalid command line arguments
2003 if {[info exists invalidopt]} then {
2004 foreach option $invalidopt {
2005 puts stderr "[file tail $argv0]: unrecognized option `$option'"
2006 }
2007 exit 1
2008 }
2009 }
2010
2011 ##
2012 ## Show usage information
2013 ##
2014 ## Args: none
2015 ## Returns: nothing
2016 ##
2017 proc ShowUsage {argv0} {
2018 # FIXME: code missing options
2019 puts "Usage: [file tail $argv0] <options>"
2020 puts " Valid options:"
2021 puts " -c, --config start interactive configuration"
2022 #puts " -u, --update update module database"
2023 puts " -r, --rebuild force rebuild of module database"
2024 puts " -n, --norebuild don't rebuild module database even if it's outdated"
2025 puts " -t, --time time compare and rebuild of module database"
2026 #puts " -i, --include <mod> include `module' when building database"
2027 #puts " -e, --exclude <mod> exclude `module' when building database"
2028 #puts " -m, --module <mod> only update database for `module'"
2029 puts " -v, --verbose use more than once for more verbose operation"
2030 puts " -q, --quiet use more than once for quieter operation"
2031 puts " -d, --debug start in debug mode with tclsh"
2032 puts " --help show this help"
2033 puts " --version show version information"
2034 }
2035
2036 ##
2037 ## Enter interactive configuration
2038 ##
2039 ## Args: none
2040 ## Returns: nothing
2041 ##
2042 proc Iconfig {} {
2043 variable NamespaceCurrent
2044 variable IconfigDefaults
2045
2046 fileevent stdin readable ${NamespaceCurrent}::IconfigReadStdin
2047 puts "Entering wolfpack configuration system..."
2048 puts "Type 'help' for help."
2049 puts -nonewline $IconfigDefaults(prompt)
2050 flush stdout
2051 vwait forever
2052 }
2053
2054 ##
2055 ## Read stdin and process commands
2056 ##
2057 ## Args: none
2058 ## Returns: nothing
2059 ##
2060 # FIXME: readline-like support?
2061 proc IconfigReadStdin {} {
2062 variable IconfigDefaults
2063 variable configData
2064
2065 set exit 0
2066 if {[eof stdin]} {
2067 set exit 1
2068 }
2069 set stdin [string trimright [gets stdin]]
2070 set data [join [lrange [split $stdin] 1 end]]
2071 if {[string compare "" $stdin]} then {
2072 switch -exact -- [lindex [split $stdin] 0] {
2073 set {
2074 IconfigSet $data
2075 }
2076 enable {
2077 IconfigEnable $data
2078 }
2079 disable {
2080 IconfigDisable $data
2081 }
2082 modules {
2083 IconfigModules $data
2084 }
2085 info {
2086 IconfigInfo $data
2087 }
2088 help {
2089 IconfigHelp $data
2090 }
2091 quit {
2092 set exit 1
2093 }
2094 default {
2095 puts "What? You need 'help'"
2096 }
2097 }
2098 }
2099 if {(!$exit) && (![eof stdin])} then {
2100 puts -nonewline $IconfigDefaults(prompt)
2101 flush stdout
2102 } else {
2103 # Save configuration data
2104 arraySave configData $IconfigDefaults(cfgfile) 0 "configuration file "
2105 # Save module database
2106 saveModuleDatabase
2107 puts ""
2108 flush stdout
2109 exit
2110 }
2111 return
2112 }
2113
2114 ##
2115 ## Set configuration settings
2116 ##
2117 ## Args: data
2118 ## Returns: nothing
2119 ##
2120 proc IconfigSet {data} {
2121 variable configData
2122 variable configDefaults
2123
2124 if {![string compare "" $data]} then {
2125 set fmtlen1 [arrayMaxElementDataLength configDefaults 3]
2126 if {$fmtlen1 < 13} then {
2127 set fmtlen1 13 ;# 'Description: '
2128 }
2129 set names [array names configData]
2130 set fmtlen2 [listMaxElementLength $names]
2131 if {$fmtlen2 < 8} then {
2132 set fmtlen2 8 ;# 'Option: '
2133 }
2134 puts ""
2135 puts "Current settings:"
2136 puts ""
2137 # FIXME: this needs improvement
2138 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" Description: Option: Value:]
2139 foreach option [lsort $names] {
2140 if {[info exists configDefaults($option)]} then {
2141 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" [lindex $configDefaults($option) 3] $option $configData($option)]
2142 } else {
2143 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" "" $option $configData($option)]
2144 }
2145 }
2146 puts ""
2147 } else {
2148 set option [lindex [split $data] 0]
2149 if {![info exists configData($option)]} then {
2150 puts "Invalid option: $option"
2151 } else {
2152 set value [join [lrange [split $data] 1 end]]
2153 if {![string compare "" $value]} then {
2154 puts "Currently: $configData($option)"
2155 } else {
2156 set configData($option) $value
2157 puts "Set $option to: $value"
2158 }
2159 }
2160 }
2161 return
2162 }
2163
2164 ##
2165 ## Enable a module
2166 ##
2167 ## Args: data
2168 ## Returns: nothing
2169 ##
2170 proc IconfigEnable {data} {
2171 set module [lindex [split $data] 0]
2172 if {![string compare "" $module]} then {
2173 puts "Usage: enable <module>"
2174 } elseif {[moduleExists $module]} then {
2175 if {![getModuleDatabaseData $module load]} then {
2176 setModuleDatabaseData $module load 1
2177 puts "Enabled module: $module"
2178 } else {
2179 puts "Module `$module' is already enabled."
2180 }
2181 } else {
2182 puts "Invalid module: $module"
2183 }
2184 return
2185 }
2186
2187 ##
2188 ## Disable a module
2189 ##
2190 ## Args: data
2191 ## Returns: nothing
2192 ##
2193 proc IconfigDisable {data} {
2194 set module [lindex [split $data] 0]
2195 if {![string compare "" $module]} then {
2196 puts "Usage: disable <module>"
2197 } elseif {[moduleExists $module]} then {
2198 if {[getModuleDatabaseData $module load] == 1} then {
2199 setModuleDatabaseData $module load 0
2200 puts "Disabled module: $module"
2201 } else {
2202 puts "Module `$module' is already disabled."
2203 }
2204 } else {
2205 puts "Invalid module: $module"
2206 }
2207 return
2208 }
2209
2210 ##
2211 ## List modules
2212 ##
2213 ## Args: data
2214 ## returns: nothing
2215 ##
2216 # FIXME: format the list of modules better (proc from texttools?)
2217 proc IconfigModules {data} {
2218 if {[llength [set modules [listModules]]]} then {
2219 set what [lindex [split $data] 0]
2220 if {![string compare "" $what]} then {
2221 set what "all"
2222 }
2223 switch -exact -- $what {
2224 * -
2225 all {
2226 puts "Available modules:"
2227 foreach line [splitList $modules 65 " " " "] {
2228 puts " $line"
2229 }
2230 }
2231 enabled {
2232 set list ""
2233 foreach module $modules {
2234 if {[getModuleDatabaseData $module load]} {
2235 lappend list $module
2236 }
2237 }
2238 if {[llength $list]} then {
2239 puts "Enabled modules:"
2240 foreach line [splitList $list 65 " " " "] {
2241 puts " $line"
2242 }
2243 } else {
2244 puts "No modules enabled"
2245 }
2246 }
2247 disabled {
2248 set list ""
2249 foreach module $modules {
2250 if {![getModuleDatabaseData $module load]} {
2251 lappend list $module
2252 }
2253 }
2254 if {[llength $list]} then {
2255 puts "Disabled modules:"
2256 foreach line [splitList $list 65 " " " "] {
2257 puts " $line"
2258 }
2259 } else {
2260 puts "No modules disabled"
2261 }
2262 }
2263 default {
2264 puts "Error: 'option' must be one of: all, enabled, disabled"
2265 }
2266 }
2267 } else {
2268 puts "Error: No modules available."
2269 }
2270 return
2271 }
2272
2273 ##
2274 ## Show info for the given module
2275 ##
2276 ## Args: data {*|all|enabled|disabled}
2277 ## returns: nothing
2278 ##
2279 # FIXME: add multiple module support as in config.tcl and or integrate?
2280 proc IconfigInfo {data} {
2281 set module [lindex [split $data] 0]
2282 if {![string compare "" $module]} then {
2283 puts "Usage: info <module>"
2284 } elseif {[moduleExists $module]} then {
2285 puts "Info for module: $module"
2286 puts ""
2287 puts "Filename: [getModuleDatabaseData $module file]"
2288 puts "MD5: [getModuleDatabaseData $module md5sum]"
2289 puts "Version: [getModuleDatabaseData $module version]"
2290 if {[getModuleDatabaseData $module load]} then {
2291 puts "Enabled: yes"
2292 } else {
2293 puts "Enabled: no"
2294 }
2295 if {[string compare "" [set config [getModuleDatabaseData $module config]]]} then {
2296 puts "Config file: $config"
2297 }
2298 if {[string compare "" [set help [getModuleDatabaseData $module help]]]} then {
2299 puts "Help file: $help"
2300 }
2301 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
2302 puts "Provided commands:"
2303 foreach line [splitList $provides 65 " " " "] {
2304 puts " $line"
2305 }
2306 }
2307 if {[string compare "" [set requires [getModuleDatabaseData $module requires]]]} then {
2308 puts "Required commands:"
2309 foreach line [splitList $requires 65 " " " "] {
2310 puts " $line"
2311 }
2312 }
2313 puts "Description:"
2314 foreach line [splitList [getModuleDatabaseData $module description] 65 " " " "] {
2315 puts " $line"
2316 }
2317 } else {
2318 puts "Invalid module: $module"
2319 }
2320 return
2321 }
2322
2323 ##
2324 ## Show configuration help
2325 ##
2326 ## Args: data
2327 ## Returns: nothing
2328 ##
2329 proc IconfigHelp {data} {
2330 if {![string compare "" $data]} then {
2331 set data help
2332 }
2333 switch -exact -- $data {
2334 set {
2335 puts "### set \[option\] \[value\]"
2336 puts " Sets an option to what you specify."
2337 puts " Shows current setting for an option if no new value is given."
2338 puts " Shows current settings for all options if no option is given."
2339 }
2340 enable {
2341 puts "### enable <module>"
2342 puts " Enables the given module."
2343 }
2344 disable {
2345 puts "### disable <module>"
2346 puts " Disables the given module."
2347 }
2348 info {
2349 puts "### info <module>"
2350 puts " Show info for the given module."
2351 }
2352 modules {
2353 puts "### modules \[what\]"
2354 puts " Available options: all, enabled, disabled"
2355 puts " all: Shows all available modules"
2356 puts " enabled: Shows enabled modules"
2357 puts " disabled: Shows disabled modules"
2358 }
2359 help {
2360 puts "### Avaliable commands:"
2361 puts " set \[option\] \[value\]"
2362 puts " enable <module>"
2363 puts " disable <module>"
2364 puts " info <module>"
2365 puts " modules \[what\]"
2366 puts " help \[command\]"
2367 puts " quit"
2368 puts "You can get help on individual commands: 'help <command>'"
2369 }
2370 quit {
2371 puts "### quit"
2372 puts " Quits interactive configuration."
2373 }
2374 default {
2375 puts "No help available on that."
2376 }
2377 }
2378 return
2379 }
2380
2381 ##
2382 ## Inline startup and init code
2383 ##
2384
2385 wpLog o * "wolfpack.tcl v[package require $NamespaceCurrent] loading..."
2386
2387 # Init md5Sum command
2388 if {![md5Init]} then {
2389 wpLog o * "Error: can't find a usable md5 command!"
2390 # FIXME: would it be sane to delete the $NamespaceCurrent in this case?
2391 return 0
2392 }
2393
2394 # Export commands
2395 eval namespace export [join $ExportList]
2396
2397 # Set missing variables to default values
2398 if {![info exists configDataChanged]} then {
2399 set configDataChanged 0
2400 }
2401 if {![info exists moduleDatabaseDataChanged]} then {
2402 set moduleDatabaseDataChanged 0
2403 }
2404 if {![info exists moduleLoadedList]} then {
2405 set moduleLoadedList ""
2406 }
2407
2408 # Load configuration data
2409 arrayLoad configData $IconfigDefaults(cfgfile) 0 "configuration file "
2410
2411 # Unset unknown configuration variables
2412 foreach name [array names configData] {
2413 if {![info exists configDefaults($name)]} then {
2414 unset configData($name)
2415 set configDataChanged 1
2416 }
2417 }
2418
2419 # Set missing configuration variables to defaults
2420 foreach {name data} [array get configDefaults] {
2421 if {![info exists configData($name)]} then {
2422 set configData($name) [lindex $data 1]
2423 set configDataChanged 1
2424 }
2425 }
2426
2427 # Set oldConfigData configuration variables to match
2428 foreach {name data} [array get configData] {
2429 if {![info exists oldConfigData($name)]} then {
2430 set oldConfigData($name) $data
2431 }
2432 }
2433
2434 # Trace configData changes
2435 trace variable configData w ${NamespaceCurrent}::TraceConfigData
2436
2437 # Save configuration data if changed
2438 if {$configDataChanged} then {
2439 arraySave configData $IconfigDefaults(cfgfile) 0 "configuration file "
2440 }
2441
2442 # Eval command line arguments if loading with tclsh
2443 if {[info exists argv0]} then {
2444 EvalArgs $argc $argv $argv0
2445 }
2446
2447 # Check verbose/quiet options
2448 if {$optionData(quiet)} then {
2449 set Verbose $optionData(quiet)
2450 } elseif {$configData(verbose)} then {
2451 set Verbose $configData(verbose)
2452 } else {
2453 set Verbose $optionData(verbose)
2454 }
2455
2456 # Check rebuild/norebuild options
2457 if {(!$optionData(norebuild)) && ($optionData(rebuild))} then {
2458 set RebuildDatabase 1
2459 } else {
2460 set RebuildDatabase 0
2461 }
2462
2463 # Sanity check: old eggdrop versions used [time] for a timestamp command
2464 if {(($optionData(time)) || ($configData(time))) && \
2465 ([catch {time}])} then {
2466 set TimeOk 1
2467 } else {
2468 set TimeOk 0
2469 }
2470
2471 # Load module database
2472 if {$Verbose >= 0} then {
2473 wpLog o * "Loading module database..."
2474 }
2475
2476 if {$TimeOk} then {
2477 set LoadTime [time {set LoadResult [loadModuleDatabase $Verbose]}]
2478 } else {
2479 set LoadResult [loadModuleDatabase $Verbose]
2480 }
2481
2482 if {$LoadResult != -1} then {
2483 if {$Verbose >= 0} then {
2484 if {[info exists LoadTime]} then {
2485 wpLog o * "Done. ([format "%.3f" [expr [lindex $LoadTime 0] / 1000000.0]] seconds elapsed)"
2486 } else {
2487 wpLog o * "Done."
2488 }
2489 }
2490 set CreateDatabase 0
2491 } else {
2492 if {$Verbose >= 0} then {
2493 wpLog o * "Warning: module database does not exist."
2494 }
2495 set CreateDatabase 1
2496 }
2497
2498 set NeedsRebuild 0
2499
2500 # Compare module database if we are not going to rebuild or create it
2501 if {(!$RebuildDatabase) && (!$CreateDatabase)} then {
2502 if {$Verbose >= 0} then {
2503 wpLog o * "Comparing module database..."
2504 }
2505 if {![file exists $configData(moddbfile)]} then {
2506 set NeedsRebuild 1
2507 } else {
2508 if {$TimeOk} then {
2509 set CompareTime [time {set CompareResult [compareModuleDatabase $Verbose]}]
2510 } else {
2511 set CompareResult [compareModuleDatabase $Verbose]
2512 }
2513 if {!$CompareResult} then {
2514 set NeedsRebuild 1
2515 }
2516 }
2517
2518 if {$Verbose >= 0} then {
2519 if {[info exists CompareTime]} then {
2520 wpLog o * "Done. ([format "%.3f" [expr [lindex $CompareTime 0] / 1000000.0]] seconds elapsed)"
2521 } else {
2522 wpLog o * "Done."
2523 }
2524 if {$NeedsRebuild} then {
2525 wpLog o * "Database is outdated."
2526 } else {
2527 wpLog o * "Database is current."
2528 }
2529 }
2530 }
2531
2532 # Create database if does not exist
2533 # Rebuild database if requested
2534 # Rebuild database if it's outdated and config permits
2535 if {($CreateDatabase) || ($RebuildDatabase) || \
2536 (($NeedsRebuild) && ($configData(rebuild)))} then {
2537
2538 if {$Verbose >= 0} then {
2539 if {$CreateDatabase} then {
2540 wpLog o * "Creating module database..."
2541 } else {
2542 wpLog o * "Rebuilding module database..."
2543 }
2544 }
2545
2546 # Rebuild module database
2547 if {$TimeOk} then {
2548 set RebuildTime [time {rebuildModuleDatabase $Verbose}]
2549 } else {
2550 rebuildModuleDatabase $Verbose
2551 }
2552
2553 if {$Verbose >= 0} then {
2554 if {[info exists RebuildTime]} then {
2555 wpLog o * "Done. ([format "%.3f" [expr [lindex $RebuildTime 0] / 1000000.0]] seconds elapsed)"
2556 } else {
2557 wpLog o * "Done."
2558 }
2559 }
2560
2561 # Save module database
2562 if {$Verbose >= 0} then {
2563 wpLog o * "Saving module database..."
2564 }
2565
2566 if {$TimeOk} then {
2567 set SaveTime [time {set SaveResult [saveModuleDatabase $Verbose]}]
2568 } else {
2569 set SaveResult [saveModuleDatabase $Verbose]
2570 }
2571
2572 if {$Verbose >= 0} then {
2573 if {$SaveResult} then {
2574 if {[info exists SaveTime]} then {
2575 wpLog o * "Done. ([format "%.3f" [expr [lindex $SaveTime 0] / 1000000.0]] seconds elapsed)"
2576 } else {
2577 wpLog o * "Done."
2578 }
2579 } else {
2580 wpLog o * "Error"
2581 }
2582 }
2583
2584 } elseif {($NeedsRebuild) && ($Verbose >= 0)} then {
2585 wpLog o * "Warning: not rebuilding outdated module database..."
2586 }
2587
2588 # Enter interactive configuration if loading with tclsh
2589 if {[info exists argv0]} then {
2590 if {$optionData(config)} then {
2591 Iconfig
2592 }
2593 }
2594
2595 # Build command table
2596 if {(![info exists argv0]) || ($optionData(debug))} then {
2597 if {$Verbose >= 0} then {
2598 wpLog o * "Building command table..."
2599 }
2600 if {$TimeOk} then {
2601 set CommandTime [time {buildCommandTable $Verbose}]
2602 } else {
2603 buildCommandTable $Verbose
2604 }
2605 if {$Verbose >= 0} then {
2606 if {[info exists CommandTime]} then {
2607 wpLog o * "Done. ([format "%.3f" [expr [lindex $CommandTime 0] / 1000000.0]] seconds elapsed)"
2608 } else {
2609 wpLog o * "Done."
2610 }
2611 }
2612
2613 set loadList ""
2614
2615 # Load debug module first if not in eggdrop mode
2616 if {([info exists argv0]) && ([moduleExists debug])} then {
2617 lappend loadList debug
2618 }
2619
2620 # Load other modules next, moduleLoad will preload additional modules
2621 foreach name [lsort [array names moduleDatabaseData]] {
2622 if {[getModuleDatabaseData $name load] == 1} then {
2623 lappend loadList $name
2624 }
2625 }
2626
2627 wpLog o * "Loading modules..."
2628
2629 # Load modules
2630 if {$TimeOk} then {
2631 set LoadTime [time {
2632 foreach module $loadList {
2633 if {[catch {moduleLoad $module $Verbose} result]} then {
2634 wpLog o * "Error: unable to load module `$module': $result"
2635 }
2636 }
2637 }]
2638 } else {
2639 foreach module $loadList {
2640 if {[catch {moduleLoad $module $Verbose} result]} then {
2641 wpLog o * "Error: unable to load module `$module': $result"
2642 }
2643 }
2644 }
2645
2646 if {[info exists LoadTime]} then {
2647 wpLog o * "Done. ([format "%.3f" [expr [lindex $LoadTime 0] / 1000000.0]] seconds elapsed)"
2648 } else {
2649 wpLog o * "Done."
2650 }
2651
2652 set ModuleLoadCount [llength [split $moduleLoadedList]]
2653 if {$ModuleLoadCount} then {
2654 set ModuleTotalCount [llength [array names moduleDatabaseData]]
2655 wpLog o * "Modules loaded ($ModuleLoadCount/$ModuleTotalCount): $moduleLoadedList"
2656 } else {
2657 wpLog o * "No modules loaded."
2658 }
2659
2660 # Unload modules if started in debug mode
2661 if {$optionData(debug)} then {
2662
2663 # FIXME: code module dependency stuff first
2664 # wpLog o * "Unloading modules..."
2665
2666 # Unload all modules except debug
2667 # foreach module $moduleLoadedList {
2668 # if {[string compare $module debug]} then {
2669 # if {[catch {moduleUnload $module $Verbose} result]} then {
2670 # wpLog o * "Error: unable to unload module `$module': $result"
2671 # }
2672 # }
2673 # }
2674
2675 # Unload debug module last to make it display stats
2676 if {[moduleLoaded debug]} then {
2677 if {[catch {moduleUnload debug} result]} then {
2678 wpLog o * "Error: unable to unload module `debug': $result"
2679 }
2680 }
2681 # wpLog o * "Done."
2682 }
2683 }
2684
2685 } ;# namespace ::wp
2686
2687 return

webmaster@eggheads.org
ViewVC Help
Powered by ViewVC 1.1.23