/[cvs]/wolfpack/wolfpack.tcl
ViewVC logotype

Contents of /wolfpack/wolfpack.tcl

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.25 - (show annotations) (download) (as text)
Tue Jan 14 10:42:54 2003 UTC (16 years, 9 months ago) by tothwolf
Branch: MAIN
Changes since 1.24: +3 -5 lines
File MIME type: application/x-tcl
*** empty log message ***

1 #! /bin/sh
2 # \
3 # Nice little hack to find latest version of tclsh in PATH \
4 # \
5 # NOTE: backslash and semicolon placements are important! \
6 # \
7 # Search for tclsh[0-9].[0-9] in each valid dir in PATH \
8 for dir in $(echo $PATH | sed 's/:/ /g'); \
9 do \
10 if test -d $dir; \
11 then \
12 files=$(/bin/ls $dir | egrep '^tclsh[0-9]\.[0-9]$'); \
13 if test "$files" != ""; \
14 then \
15 versions="${versions:+$versions }$(echo $files | sed 's/tclsh//g')"; \
16 fi; \
17 fi; \
18 done; \
19 # Loop over each version to find the latest version of tclsh \
20 for ver in $versions; \
21 do \
22 tmpver=$(echo $ver | sed 's/\.//g'); \
23 if test "$lasttmpver" != ""; \
24 then \
25 if test "$tmpver" -gt "$lasttmpver"; \
26 then \
27 lastver=$ver; \
28 lasttmpver=$tmpver; \
29 fi; \
30 else \
31 lastver=$ver; \
32 lasttmpver=$tmpver; \
33 fi; \
34 done; \
35 # Use the latest tclsh version found, otherwise fall back to 'tclsh' \
36 exec tclsh$lastver "$0" "$@"
37 ###############################################################################
38 ##
39 ## Wolfpack - A modular Tcl system for Eggdrop 1.3.0+ with Tcl 8.0+
40 ## Copyright (C) 1998-2003 Tothwolf <tothwolf@concentric.net>
41 ##
42 ## This program is free software; you can redistribute it and/or modify
43 ## it under the terms of the GNU General Public License as published by
44 ## the Free Software Foundation; either version 2 of the License, or
45 ## (at your option) any later version.
46 ##
47 ## This program is distributed in the hope that it will be useful,
48 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
49 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
50 ## GNU General Public License for more details.
51 ##
52 ## You should have received a copy of the GNU General Public License
53 ## along with this program; if not, write to the Free Software
54 ## Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
55 ##
56 ###############################################################################
57 ##
58 ## You should not need to edit anything in any of these files.
59 ##
60 ## './wolfpack.tcl -c' may be used to configure initial settings.
61 ## './wolfpack.tcl --help' will list all avaliable options.
62 ##
63 ## Use '.wpconf' in dcc chat with the bot to configure everything else.
64 ##
65 ###############################################################################
66 ##
67 ## $Id: wolfpack.tcl,v 1.24 2003/01/14 10:34:51 tothwolf Exp $
68 ##
69
70 # make sure Tcl version is compatible with this code (we use namespaces)
71 if {[catch {package require Tcl 8.0}]} then {
72 if {[info exists argv0]} then {
73 puts "Wolfpack: Error: wolfpack requires Tcl 8.0 or later to load."
74 } else {
75 putloglev o * "Wolfpack: Error: wolfpack requires Tcl 8.0 or later to load."
76 }
77 return 0
78 }
79
80 namespace eval :: {
81
82 # Eggdrop doesn't currently set argv0, so we use that to detect load type.
83 global argv0
84
85 if {![info exists argv0]} then {
86 # HACK: quick fix for buggy tcl variables in older bots
87 catch {set version}
88 catch {set numversion}
89 # require eggdrop 1.3.0 or later
90 if {(![info exists version]) || (![info exists numversion]) || \
91 ($numversion < 1030000)} then {
92 putloglev o * "Wolfpack: Error: wolfpack requires Eggdrop 1.3.0 or later to load."
93 return 0
94 }
95 } else {
96 # emulate eggdrop's putloglev when loading with tclsh
97 if {![string compare "" [info commands putloglev]]} then {
98 proc putloglev {level channel text} {
99 puts $text
100 }
101 }
102 }
103
104 ##
105 ## Log tcl messages where they can be seen
106 ##
107 ## Args: text
108 ## Returns: nothing
109 ##
110 proc tclLog {text} {
111 # Tcl's tclLog embeds newlines in it's output
112 if {[string first \n $text] == -1} then {
113 putloglev o * "Wolfpack: \[Tcl\]: $text"
114 } else {
115 foreach line [split $text \n] {
116 putloglev o * "Wolfpack: \[Tcl\]: $line"
117 }
118 }
119 return
120 }
121
122 } ;# namespace ::
123
124 namespace eval ::wp {
125
126 # manage package information
127 package forget ::wp
128 package provide ::wp 1.9.9.0
129
130 # set namespace variable
131 set NamespaceCurrent [namespace current]
132
133 ##
134 ## WARNING: If you change these, you may render your module database useless!
135 ##
136
137 # Max number of lines to scan in a module file
138 set moduleDatabaseConfig(scanlines) 30
139
140 # Max depth to list directories in module path
141 set moduleDatabaseConfig(maxdepth) 4
142
143 # Module database version
144 set moduleDatabaseConfig(version) 2.0
145
146 # Module database header
147 set moduleDatabaseConfig(header) "Wolfpack module database "
148
149 # Module database defaults
150 set moduleDatabaseConfig(defaults) "{version 0.1} {description {(no description)}} {load 0}"
151
152 # Versioned module database formats
153 array set moduleDatabaseFormat {
154 2.0 "{version config help description provides requires} {load file md5sum}"
155 }
156
157 # md5 style, command name and result string index
158 array set md5Format {
159 bsd "md5 3"
160 gnu "md5sum 0"
161 }
162
163 # Configuration file
164 set IconfigDefaults(cfgfile) wolfpack.conf
165
166 # Interactive configuration prompt
167 set IconfigDefaults(prompt) "wolfpack> "
168
169 # Configuration defaults, values and descriptions
170 array set configDefaults {
171 modulepath {word modules/ {} {Module path}}
172 configpath {word wpconf/ {} {Config path}}
173 datapath {word wpdata/ {} {Data path}}
174 helppath {word wphelp/ {} {Help path}}
175 moddbfile {word wolfpack.db {} {Module database file}}
176 rebuild {{range {0 1}} 1 {} {Automatically rebuild database}}
177 verbose {{range {0 1}} 0 {} {Verbose operation}}
178 time {{range {0 1}} 0 {} {Time database compare and rebuild}}
179 commandchar {word - {} {Character to prefix public commands with}}
180 }
181
182 # Command line option defaults
183 array set optionData {
184 config 0
185 rebuild 0
186 norebuild 0
187 time 0
188 verbose 0
189 quiet 0
190 debug 0
191 }
192
193 # Exported commands
194 set ExportList {
195 md5Sum
196 md5Init
197 replaceExpr
198 listFiles
199 listSubdirs
200 findFiles
201 createFile
202 createDir
203 backupFile
204 listSave
205 listLoad
206 arraySave
207 arrayLoad
208 arraySetAll
209 arrayFindElementName
210 arrayMaxElementDataLength
211 listMaxElementLength
212 splitList
213 arraySearch
214 commandChar
215 dataFormatDefault
216 dataFormatValue
217 dataFormatReplace
218 dataFormatBuild
219 dataFormatConvert
220 scanModule
221 getModuleDatabaseData
222 setModuleDatabaseData
223 saveModuleDatabase
224 loadModuleDatabase
225 compareModuleDatabase
226 rebuildModuleDatabase
227 listModules
228 moduleExists
229 moduleLoaded
230 moduleBindUnbind
231 moduleLoad
232 moduleUnload
233 moduleConfigSave
234 moduleConfigLoad
235 moduleConfigCheckdefs
236 moduleConfig
237 moduleDataSave
238 moduleDataLoad
239 moduleDataBackup
240 moduleData
241 buildCommandTable
242 whichCommand
243 whichModule
244 whichModuleCommand
245 compareVersion
246 wpLog
247 }
248
249 ##
250 ## Create md5 checksum for a file
251 ##
252 ## Args: filename
253 ## Returns: md5 checksum if successful
254 ## Errors: permission denied,
255 ## no such file,
256 ## not a file,
257 ## can't exec md5 command
258 ##
259 proc md5Sum {file} {
260 variable md5Config
261
262 if {![file exists $file]} then {
263 error "$file: no such file"
264 } else {
265 if {![file isfile $file]} then {
266 error "$file: not a file"
267 } else {
268 if {![file readable $file]} then {
269 error "$file: permission denied"
270 } else {
271 if {[catch {set sum [lindex [exec $md5Config(command) $file] $md5Config(index)]} result]} then {
272 error "$file: $result"
273 } else {
274 return $sum
275 }
276 }
277 }
278 }
279 }
280
281 ##
282 ## Init md5 command
283 ##
284 ## Args: none
285 ## Returns: 1 if a useable md5 command found
286 ## 0 otherwise
287 ##
288 proc md5Init {} {
289 variable md5Config
290 variable md5Format
291
292 foreach type [array names md5Format] {
293 foreach {command index} $md5Format($type) {break}
294 if {([catch {exec $command ""} result]) && \
295 (![regexp -- "^couldn't execute" $result])} then {
296 set md5Config(command) $command
297 set md5Config(index) $index
298 return 1
299 }
300 }
301 return 0
302 }
303
304 ##
305 ## Replace all occurances of an expression in a string with the given text
306 ##
307 ## Args: string, expr, replacement text
308 ## Returns: string
309 ##
310 proc replaceExpr {string expr {replace ""}} {
311 while {[regexp -nocase -- $expr $string]} {
312 regsub -all -- $expr $string $replace string
313 }
314 return $string
315 }
316
317 ##
318 ## List files in a path
319 ##
320 ## Args: path
321 ## Returns: list of files in the given path,
322 ## nothing if no files in the given path
323 ## Errors: permission denied,
324 ## no such directory,
325 ## not a directory
326 ##
327 proc listFiles {path} {
328 if {![file exists $path]} then {
329 error "$path: no such directory"
330 } else {
331 if {![file isdirectory $path]} then {
332 error "$path: not a directory"
333 } else {
334 if {![file readable $path]} then {
335 error "$path: permission denied"
336 } else {
337 set ret ""
338 foreach name [lsort [glob -nocomplain -- [file join $path *]]] {
339 if {[file isfile $name]} then {
340 lappend ret $name
341 }
342 }
343 return $ret
344 }
345 }
346 }
347 }
348
349 ##
350 ## List subdirs in a path
351 ##
352 ## Args: path
353 ## Returns: list of subdirs in the given path,
354 ## nothing if no subdirs in the given path
355 ## Errors: permission denied,
356 ## no such directory,
357 ## not a directory
358 ##
359 proc listSubdirs {path} {
360 if {![file exists $path]} then {
361 error "$path: no such directory"
362 } else {
363 if {![file isdirectory $path]} then {
364 error "$path: not a directory"
365 } else {
366 if {![file readable $path]} then {
367 error "$path: permission denied"
368 } else {
369 set ret ""
370 foreach name [lsort [glob -nocomplain -- [file join $path *]]] {
371 if {[file isdirectory $name]} then {
372 lappend ret $name
373 }
374 }
375 return $ret
376 }
377 }
378 }
379 }
380
381 ##
382 ## List files with a set ext in a path and its subdirs up to a set depth
383 ##
384 ## Args: path, max search depth, file extension
385 ## Returns: list of files with a set ext in the given path and its subdirs,
386 ## nothing if no matching files are found
387 ##
388 proc findFiles {path depth {ext ""}} {
389 set ret ""
390 set foundDirs "$path "
391 set searchDirs $path
392 for {
393 set currentDepth 0
394 } {($currentDepth <= $depth) || (!$depth)} {
395 incr currentDepth
396 } {
397 set subDirs ""
398 foreach dir $searchDirs {
399 if {[catch {set dirList [listSubdirs $dir]} result]} then {
400 wpLog o * "Error: unable to get file listing: $result"
401 } elseif {[string compare "" $dirList]} then {
402 append subDirs $dirList " "
403 }
404 }
405 if {![string compare "" $subDirs]} then {
406 break
407 }
408 append foundDirs $subDirs " "
409 set searchDirs $subDirs
410 }
411 foreach dir $foundDirs {
412 if {[catch {set files [listFiles $dir]} result]} then {
413 wpLog o * "Error: unable to get file listing: $result"
414 } else {
415 if {[string compare "" $ext]} then {
416 foreach file $files {
417 if {![string compare $ext \
418 [string tolower [file extension $file]]]} then {
419 lappend ret $file
420 }
421 }
422 } else {
423 set ret $files
424 }
425 }
426 }
427 return $ret
428 }
429
430 ##
431 ## Check if a file exists, and create it if not
432 ##
433 ## Args: filename, verbose {-1,0,1}, description, force new file
434 ## Returns: 1 if the file was created successfully
435 ## 0 if the operation failed
436 ## -1 if the file already exists
437 ##
438 proc createFile {file {verbose 0} {desc "file "} {force 0}} {
439 if {($force) || (![file exists $file])} then {
440 if {[catch {set fd [open $file w]} result]} then {
441 if {$verbose >= 0} then {
442 wpLog o * "Error: unable to create ${desc}`[file tail $file]': $result"
443 }
444 } else {
445 if {(!$force) && ($verbose >= 1)} then {
446 wpLog o * "Warning: ${desc}`[file tail $file]' does not exist -- creating"
447 }
448 close $fd
449 return 1
450 }
451 } elseif {[file isfile $file]} then {
452 return -1
453 } elseif {$verbose >= 0} then {
454 wpLog o * "Error: not a file: $file"
455 }
456 return 0
457 }
458
459 ##
460 ## Check if a directory exists, and create it if not
461 ##
462 ## Args: directory, verbose {-1,0,1}, description
463 ## Returns: 1 if the directory was created successfully
464 ## 0 if the operation failed
465 ## -1 if the directory already exists
466 ##
467 proc createDir {dir {verbose 0} {desc "directory "}} {
468 if {![file exists $dir]} then {
469 if {[catch {file mkdir $dir} result]} then {
470 if {$verbose >= 0} then {
471 wpLog o * "Error: unable to create ${desc}`[file tail $dir]': $result"
472 }
473 } else {
474 if {$verbose >= 1} then {
475 wpLog o * "Warning: ${desc}`[file tail $dir]' does not exist -- creating"
476 }
477 return 1
478 }
479 } elseif {[file isdirectory $dir]} then {
480 return -1
481 } elseif {$verbose >= 0} then {
482 wpLog o * "Error: not a directory: $dir"
483 }
484 return 0
485 }
486
487 ##
488 ## Create a backup of the given file with an optional suffix
489 ##
490 ## Args: filename, suffix, verbose {-1,0,1}
491 ## Returns: 1 if successful
492 ## -1 if file is 0 in size
493 ## 0 otherwise
494 ##
495 proc backupFile {file {verbose 0} {suffix ~bak}} {
496 variable NamespaceCurrent
497
498 if {[string compare "" $suffix]} then {
499 if {[file size $file]} then {
500 if {[catch {
501 file copy -force $file $file${suffix}
502 } result]} then {
503 if {$verbose >= 0} then {
504 wpLog o * $NamespaceCurrent "Error: unable to create backup file for `[file tail $file]': $result"
505 }
506 } else {
507 return 1
508 }
509 } else {
510 return -1
511 }
512 }
513 return 0
514 }
515
516 ##
517 ## Save data from a list into a file
518 ##
519 ## Args: list, filename, verbose {-1,0,1}, description, access flag
520 ## Returns: 1 is successful,
521 ## 0 otherwise
522 ##
523 proc listSave {listName file {verbose 0} {desc "file "} {access w}} {
524 upvar 1 $listName list
525
526 if {[createFile $file $verbose $desc]} then {
527 if {[catch {set fd [open $file $access]} result]} then {
528 if {$verbose >= 0} then {
529 wpLog o * "Error: unable to open ${desc}`$file' for writing: $result"
530 }
531 } else {
532 if {[info exists list]} then {
533 foreach data $list {
534 puts $fd [list $data]
535 }
536 }
537 close $fd
538 return 1
539 }
540 }
541 return 0
542 }
543
544 ##
545 ## Load data into a list from a file
546 ##
547 ## Args: list, filename, verbose {-1,0,1}, description, ignore regsub
548 ## Returns: 1 if successful,
549 ## 0 otherwise
550 ##
551 proc listLoad {listName file {verbose 0} {desc "file "} {ignore "^#"}} {
552 upvar 1 $listName list
553
554 if {[createFile $file $verbose $desc]} then {
555 if {[catch {set fd [open $file r]} result]} then {
556 if {$verbose >= 0} then {
557 wpLog o * "Error: unable to open ${desc}`$file' for reading: $result"
558 }
559 } else {
560 if {[info exists list]} then {
561 unset list
562 }
563 while {![eof $fd]} {
564 set line [replaceExpr [gets $fd] "^ "]
565 if {([string compare "" $line]) && \
566 (![regexp -- $ignore $line])} then {
567 append list $line " "
568 }
569 }
570 close $fd
571 return 1
572 }
573 }
574 return 0
575 }
576
577 ##
578 ## Save data from an array info a file
579 ##
580 ## Args: array, filename, verbose {-1,0,1}, description, access flag
581 ## Returns: 1 is successful,
582 ## 0 otherwise
583 ##
584 proc arraySave {arrayName file {verbose 0} {desc "file "} {access w}} {
585 upvar 1 $arrayName array
586
587 if {[createFile $file $verbose $desc]} then {
588 if {[catch {set fd [open $file $access]} result]} then {
589 if {$verbose >= 0} then {
590 wpLog o * "Error: unable to open ${desc}`$file' for writing: $result"
591 }
592 } else {
593 if {[array exists array]} then {
594 foreach name [lsort [array names array]] {
595 puts $fd "[list $name] [list $array($name)]"
596 }
597 close $fd
598 return 1
599 } else {
600 close $fd
601 }
602 }
603 }
604 return 0
605 }
606
607 ##
608 ## Load data into an array from a file
609 ##
610 ## Args: array, filename, verbose {-1,0,1}, description, ignore regsub
611 ## Returns: 1 if successful,
612 ## 0 otherwise
613 ##
614 proc arrayLoad {arrayName file {verbose 0} {desc "file "} {ignore "^#"}} {
615 upvar 1 $arrayName array
616
617 if {[createFile $file $verbose $desc]} then {
618 if {[catch {set fd [open $file r]} result]} then {
619 if {$verbose >= 0} then {
620 wpLog o * "Error: unable to open ${desc}`$file' for reading: $result"
621 }
622 } else {
623 if {[info exists array]} then {
624 unset array
625 }
626 while {![eof $fd]} {
627 set line [replaceExpr [gets $fd] "^ "]
628 if {([string compare "" $line]) && \
629 (![regexp -- $ignore $line])} then {
630 set array([lindex $line 0]) [lindex $line 1]
631 }
632 }
633 close $fd
634 return 1
635 }
636 }
637 return 0
638 }
639
640 ##
641 ## Set all elements in the given array the the given value
642 ##
643 ## Args: array name, value
644 ## Returns: 1 if the array exists
645 ## 0 otherwise
646 ##
647 proc arraySetAll {arrayName {value ""}} {
648 upvar 1 $arrayName array
649
650 if {[array exists array]} then {
651 foreach name [array names array] {
652 set array($name) $value
653 }
654 return 1
655 }
656 return 0
657 }
658
659 ##
660 ## Find the given element in an array
661 ##
662 ## Args: array name, element name
663 ## Returns: case sensitive element name if found,
664 ## nothing otherwise
665 ##
666 proc arrayFindElementName {array element} {
667 set list [lsort [array names $array]]
668 set index [lsearch -exact [string tolower $list] [string tolower $name]]
669 if {$index != -1} then {
670 return [lindex $list $index]
671 }
672 return
673 }
674
675 ##
676 ## Return length of longest data in an array at index
677 ##
678 ## Args: array name
679 ## Returns: length of longest name in an array
680 ##
681 proc arrayMaxElementDataLength {arrayName index} {
682 upvar 1 $arrayName array
683
684 set maxlength 0
685 foreach {name data} [array get array] {
686 set length [string length [lindex $data $index]]
687 if {$length > $maxlength} then {
688 set maxlength $length
689 }
690 }
691 return $maxlength
692 }
693
694 ##
695 ## Return length of the longest element in a list
696 ##
697 ## Args: list
698 ## Returns: length of longest element in the given list
699 ##
700 proc listMaxElementLength {list} {
701 set maxlength 0
702 foreach data $list {
703 set length [string length $data]
704 if {$length > $maxlength} then {
705 set maxlength $length
706 }
707 }
708 return $maxlength
709 }
710
711 ##
712 ## Split up a list into multiple elements
713 ##
714 ## Args: text, max list length, split char, trim chars
715 ## Returns: split list
716 ##
717 # FIXME: improve this
718 proc splitList {text {splitLength 75} {splitChar " "} {trimChars " "}} {
719 # Sanity check splitLength and splitChar
720 if {($splitLength >= 1) && ([string compare "" $splitChar])} then {
721 set elementSplitLength [expr $splitLength - 1]
722 set stringLength [string length $text] ;# Total length of string
723 set subStringLength 0 ;# Text left over
724 set elementLength 0 ;# Element length counter
725 set elementStartIndex 0 ;# Start of split element
726 set elementEndIndex 0 ;# End of split element
727 for {
728 set stringIndex 0
729 } {$stringIndex < $stringLength} {
730 incr stringIndex
731 } {
732 # If element length greater than/equal to split length,
733 # Or element length equal to split length - 1,
734 # And character at current string index is splitChar
735 if {(($elementLength >= $splitLength) ||
736 ($elementLength == $elementSplitLength)) &&
737 (![string compare $splitChar \
738 [string index $text $stringIndex]])} then {
739 # Split substring element from text
740 set string [string range $text $elementStartIndex $elementEndIndex]
741 # Append substring element list to list
742 lappend list [string trim $string $trimChars]
743 # Reset element length counter
744 set elementLength 0
745 # Start split of next element at the end + 1 of the current one
746 set elementStartIndex [expr $elementEndIndex + 1]
747 # Reset end of next element to the start of the next element
748 set elementEndIndex $elementStartIndex
749 # Track remaining text length
750 set subStringLength [expr $subStringLength + [string length $string]]
751 } else {
752 # Increment element length
753 incr elementLength
754 # Increment end of next element
755 incr elementEndIndex
756 }
757 }
758 # Append any left over text as a new element
759 if {$stringLength > $subStringLength} then {
760 lappend list [string trim [string range $text $subStringLength end] $trimChars]
761 }
762 # Whew...that was alot of work!
763 if {[info exists list]} then {
764 return $list
765 }
766 }
767 return
768 }
769
770 ##
771 ## Search an array for a given word or regexp
772 ##
773 ## Args: array name, word/regexp
774 ## Returns: list of indexes that match the given word/regexp
775 ##
776 proc arraySearch {array word} {
777 set word [string tolower $word]
778 set ret ""
779 foreach {name data} [array get $array] {
780 set string [string tolower $data]
781 if {[lsearch -regexp $string $word] != -1} then {
782 for {
783 set index 0
784 set indexes ""
785 } {
786 if {[regexp -- .*$word $string]} then {
787 lappend indexes $index
788 }
789 } {
790 incr index
791 }
792 lappend ret [list [concat $name $indexes]]
793 }
794 }
795 return $ret
796 }
797
798 ##
799 ## Return current command character
800 ##
801 ## Args: type {pub,msg,dcc,fil}
802 ## Returns: command character for the type given
803 ##
804 proc commandChar {type} {
805 global botnick
806 variable configData
807
808 switch -exact -- $type {
809 pub {
810 return $configData(commandchar)
811 }
812 msg {
813 return "/msg $botnick "
814 }
815 dcc {
816 return
817 }
818 fil {
819 return
820 }
821 default {
822 error "Unknown command character type: $type"
823 }
824 }
825 return
826 }
827
828 ##
829 ## Find option default for the given option name in a data list
830 ##
831 ## Args: data list, option name
832 ## Returns: option default if found,
833 ## nothing otherwise
834 ##
835 proc dataFormatDefault {list option} {
836 foreach i $list {
837 if {![string compare $option [lindex $i 0]]} then {
838 return [lindex $i 1]
839 }
840 }
841 return
842 }
843
844 ##
845 ## Find option value for the given option name in a data list
846 ##
847 ## Args: data format, data list, option name
848 ## Returns: option value if found,
849 ## nothing otherwise
850 ##
851 proc dataFormatValue {format data option} {
852 if {[set index [lsearch -exact $format $option]] != -1} then {
853 return [lindex $data $index]
854 }
855 return
856 }
857
858 ##
859 ## Replace option data in the given data list with a new value
860 ##
861 ## Args: data format, data list, option name, new value
862 ## Returns: data list
863 ##
864 proc dataFormatReplace {format data option value} {
865 if {[set index [lsearch -exact $format $option]] != -1} then {
866 return [lreplace $data $index $index $value]
867 }
868 return $data
869 }
870
871 ##
872 ## Create a data format list for a given data format and options
873 ##
874 ## Args: data format list, defaults, options {{option1 value} ...}
875 ## Returns: data format list with options and values in proper order
876 ##
877 proc dataFormatBuild {format defaults args} {
878 set ret ""
879 foreach arg $args {
880 set [lindex $arg 0] [lindex $arg 1]
881 }
882 foreach opt $format {
883 if {[info exists $opt]} then {
884 lappend ret [set $opt]
885 } else {
886 lappend ret [dataFormatDefault $defaults $opt]
887 }
888 }
889 return $ret
890 }
891
892 ##
893 ## Convert a data list from one format to another
894 ##
895 ## Args: from format, to format, data list
896 ## Returns: data list
897 ##
898 proc dataFormatConvert {fromFormat toFormat data} {
899 set ret ""
900 set index 0
901 foreach opt $fromFormat {
902 set $opt [lindex $data $index]
903 incr index
904 }
905 foreach opt $toFormat {
906 if {[info exists $opt]} then {
907 lappend ret [set $opt]
908 } else {
909 lappend ret [dataFormatDefault $defaults $opt]
910 }
911 }
912 return $ret
913 }
914
915 ##
916 ## Scan the given file for module options
917 ##
918 ## Args: file, args {only scan for these options}
919 ## Returns: list of module options if the given file is a module,
920 ## nothing otherwise
921 ## Errors: unable to open file for reading
922 ##
923 proc scanModule {file args} {
924 variable moduleDatabaseConfig
925 variable moduleDatabaseFormat
926
927 if {[catch {set fd [open $file r]} result]} then {
928 error $result
929 } else {
930 set ret ""
931 if {![string compare "" $args]} then {
932 set baseOptions [lindex $moduleDatabaseFormat([set moduleDatabaseConfig(version)]) 0]
933 set extraOptions [lindex $moduleDatabaseFormat([set moduleDatabaseConfig(version)]) 1]
934 set scanOptions "name $baseOptions"
935 set formatOptions "name $baseOptions $extraOptions"
936 } else {
937 set scanOptions $args
938 set formatOptions $args
939 }
940 for {
941 set lineCount 0
942 set optionCount 0
943 set continuedLine 0
944 } {(![eof $fd]) && ($lineCount <= $moduleDatabaseConfig(scanlines))} {
945 incr lineCount
946 } {
947 gets $fd line
948 if {[regexp -- "^# .*:.*" $line]} then {
949 set opt [string trimright [lindex $line 1] :]
950 if {[lsearch -glob $scanOptions $opt] != -1} then {
951 set data [string trimright [string trimleft [string range $line [string first : $line] end] " \t:"] " \t\\"]
952 if {![info exists $opt]} then {
953 set $opt $data
954 } else {
955 append $opt " $data"
956 }
957 }
958 if {[regexp -- \\\\$ $line]} then {
959 set continuedLine 1
960 } else {
961 set continuedLine 0
962 }
963 } elseif {($continuedLine) && ([info exists opt])} then {
964 append $opt " [string trimright [string trimleft $line " \t#"] " \t\\"]"
965 if {![regexp -- \\\\$ $line]} then {
966 set continuedLine 0
967 }
968 }
969 }
970 close $fd
971 if {(![string compare "" $args]) && \
972 ((![info exists name]) || \
973 ([catch {set md5sum [md5Sum $file]}]))} then {
974 return
975 }
976 foreach option $formatOptions {
977 if {(![info exists $option]) || \
978 (![string compare "" [set $option]])} then {
979 set $option [dataFormatDefault $moduleDatabaseConfig(defaults) $option]
980 }
981 lappend ret [set $option]
982 }
983 return $ret
984 }
985 }
986
987 ##
988 ## Get data from module db data array
989 ##
990 ## Args: module name, data type
991 ## Returns: data for the given module's data type if it exists,
992 ## nothing otherwise
993 ##
994 proc getModuleDatabaseData {module type} {
995 variable moduleDatabaseConfig
996 variable moduleDatabaseFormat
997 variable moduleDatabaseData
998
999 if {[moduleExists $module]} then {
1000 set index [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] $type]
1001 if {$index != -1} then {
1002 return [lindex $moduleDatabaseData($module) $index]
1003 }
1004 }
1005 return
1006 }
1007
1008 ##
1009 ## Set data in module db data array
1010 ##
1011 ## Args: module name, data type, data
1012 ## Returns: 1 if valid module and data type,
1013 ## 0 otherwise
1014 ##
1015 proc setModuleDatabaseData {module type data} {
1016 variable moduleDatabaseConfig
1017 variable moduleDatabaseFormat
1018 variable moduleDatabaseData
1019 variable moduleDatabaseDataChanged
1020
1021 if {[moduleExists $module]} then {
1022 set index [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] $type]
1023 if {$index != -1} then {
1024 set moduleDatabaseData($module) [lreplace $moduleDatabaseData($module) $index $index [list $data]]
1025 set moduleDatabaseDataChanged 1
1026 return 1
1027 }
1028 }
1029 return 0
1030 }
1031
1032 ##
1033 ## Save module database
1034 ##
1035 ## Args: verbose {-1,0,1}
1036 ## Returns: 1 if successful,
1037 ## 0 otherwise
1038 ##
1039 proc saveModuleDatabase {{verbose 0}} {
1040 variable configData
1041 variable moduleDatabaseConfig
1042 variable moduleDatabaseData
1043 variable moduleDatabaseDataChanged
1044
1045 if {[createFile $configData(moddbfile) $verbose "module database file "]} then {
1046 if {[catch {set fd [open $configData(moddbfile) w]} result]} then {
1047 if {$verbose >= 0} then {
1048 wpLog o * "Error: unable to open module database file `$configData(moddbfile)' for writing: $result"
1049 }
1050 } else {
1051 puts $fd "# $moduleDatabaseConfig(header)$moduleDatabaseConfig(version)"
1052 close $fd
1053 set ret [arraySave moduleDatabaseData $configData(moddbfile) $verbose "module database file " a]
1054 if {$ret} then {
1055 set moduleDatabaseDataChanged 0
1056 }
1057 return $ret
1058 }
1059 }
1060 return 0
1061 }
1062
1063 ##
1064 ## Load module database
1065 ##
1066 ## Args: verbose {-1,0,1}
1067 ## Returns: 1 if successful,
1068 ## 0 otherwise
1069 ##
1070 proc loadModuleDatabase {{verbose 0}} {
1071 variable configData
1072 variable moduleDatabaseConfig
1073 variable moduleDatabaseFormat
1074 variable moduleDatabaseData
1075 variable moduleDatabaseDataChanged
1076
1077 if {![file exists $configData(moddbfile)]} then {
1078 return -1
1079 } else {
1080 if {[catch {set fd [open $configData(moddbfile) r]} result]} then {
1081 if {$verbose >= 0} then {
1082 wpLog o * "Error: unable to open module database file `$configData(moddbfile)' for reading: $result"
1083 }
1084 } else {
1085 set firstline [replaceExpr [gets $fd] "^ "]
1086 if {[regexp -- "^# $moduleDatabaseConfig(header)" $firstline]} then {
1087 regsub -all -- "^# $moduleDatabaseConfig(header)" $firstline "" version
1088 if {![string compare [set version [string trim $version]] $moduleDatabaseConfig(version)]} then {
1089 close $fd
1090 return [arrayLoad moduleDatabaseData $configData(moddbfile) $verbose "module database file "]
1091 } elseif {[info exists moduleDatabaseFormat($version)]} then {
1092 if {[info exists moduleDatabaseData]} then {
1093 unset moduleDatabaseData
1094 }
1095 while {![eof $fd]} {
1096 set line [replaceExpr [gets $fd] "^ "]
1097 if {([string compare "" $line]) && \
1098 (![regexp -- "^#" $line])} then {
1099 set moduleDatabaseData([lindex $line 0]) [dataFormatConvert [join $moduleDatabaseFormat($version)] [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] [lindex $line 1]]
1100 }
1101 }
1102 close $fd
1103 set moduleDatabaseDataChanged 0
1104 return 1
1105 } else {
1106 wpLog o * "Error: unknown module database version: $version"
1107 }
1108 } else {
1109 wpLog o * "Error: unknown module database format: [string trimleft $firstline " \t#"]"
1110 }
1111 }
1112 close $fd
1113 }
1114 return 0
1115 }
1116
1117 ##
1118 ## Compare loaded module database data to module files
1119 ##
1120 ## Args: verbose {-1,0,1}
1121 ## Returns: 1 if data matches,
1122 ## 0 otherwise
1123 ##
1124 proc compareModuleDatabase {{verbose 0}} {
1125 variable configData
1126 variable moduleDatabaseConfig
1127
1128 foreach path $configData(modulepath) {
1129 set files [findFiles $path $moduleDatabaseConfig(maxdepth) .tcl]
1130 if {[string compare "" $files]} then {
1131 set comparedModules ""
1132 set moduleList [listModules]
1133 # Return early if we don't have any modules listed in the db
1134 if {![string compare "" $moduleList]} then {
1135 return 0
1136 }
1137 foreach file $files {
1138 set shortfile [string trimleft [string range $file [string length $path] end] /]
1139 if {$verbose >= 1} then {
1140 wpLog o * "Comparing file `$shortfile'"
1141 }
1142 if {[catch {set name [lindex [scanModule $file name] 0]} result]} then {
1143 if {$verbose >= 0} then {
1144 wpLog o * "Error: unable to open file `$shortfile' for reading: $result"
1145 }
1146 }
1147 # Process this file if it's a module
1148 if {[string compare "" $name]} then {
1149 # Get module filename from db
1150 set filename [getModuleDatabaseData $name file]
1151 # Compare module filename and make sure it wasn't renamed or moved
1152 if {[string compare $file $filename]} then {
1153 return 0
1154 }
1155 # Compare md5 from module db and sure the module hasn't changed
1156 if {([catch {set md5sum [md5Sum $filename]}]) || \
1157 ([string compare [getModuleDatabaseData $name md5sum] $md5sum])} then {
1158 return 0
1159 }
1160 # Append module name to list of compared modules
1161 lappend comparedModules $name
1162 }
1163 }
1164 # Compare list of compared modules with list of modules from the db
1165 if {[string compare [lsort $comparedModules] $moduleList]} then {
1166 return 0
1167 }
1168 }
1169 }
1170 return 1
1171 }
1172
1173 ##
1174 ## Rebuild module database
1175 ##
1176 ## Args: verbose {-1,0,1}
1177 ## Returns: nothing
1178 ##
1179 proc rebuildModuleDatabase {{verbose 0}} {
1180 variable configData
1181 variable moduleDatabaseConfig
1182 variable moduleDatabaseFormat
1183 variable moduleDatabaseData
1184
1185 foreach path $configData(modulepath) {
1186 set files [findFiles $path $moduleDatabaseConfig(maxdepth) .tcl]
1187 set loadIndex [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] load]
1188 foreach file $files {
1189 set shortfile [string trimleft [string range $file [string length $path] end] /]
1190 if {$verbose >= 1} then {
1191 wpLog o * "Scanning file `$shortfile'"
1192 }
1193 if {[catch {set data [scanModule $file]} result]} then {
1194 if {$verbose >= 0} then {
1195 wpLog o * "Warning: unable to open file `$shortfile' for reading: $result"
1196 }
1197 } else {
1198 set name [lindex $data 0]
1199 if {[string compare "" $name]} then {
1200 if {[moduleExists $name]} then {
1201 set tmp($name) [lreplace [lrange $data 1 end] $loadIndex $loadIndex [lindex $moduleDatabaseData($name) $loadIndex]]
1202 } else {
1203 set tmp($name) [lrange $data 1 end]
1204 }
1205 }
1206 }
1207 }
1208 }
1209 if {[info exists moduleDatabaseData]} then {
1210 unset moduleDatabaseData
1211 }
1212 if {[info exists tmp]} then {
1213 array set moduleDatabaseData [array get tmp]
1214 }
1215 return
1216 }
1217
1218 ##
1219 ## List all modules in the database
1220 ##
1221 ## Args: none
1222 ## Returns: list of modules in module database
1223 ##
1224 proc listModules {{loaded 0}} {
1225 variable moduleDatabaseData
1226 variable moduleLoadedList
1227
1228 if {$loaded} then {
1229 return [lsort $moduleLoadedList]
1230 }
1231 return [lsort [array names moduleDatabaseData]]
1232 }
1233
1234 ##
1235 ## Check if the given module exists
1236 ##
1237 ## Args: module name
1238 ## Returns: 1 if the given module exists
1239 ## 0 otherwise
1240 ##
1241 proc moduleExists {module} {
1242 variable moduleDatabaseData
1243
1244 if {[info exists moduleDatabaseData($module)]} then {
1245 return 1
1246 }
1247 return 0
1248 }
1249
1250 ##
1251 ## Check if a module is loaded
1252 ##
1253 ## Args: module name
1254 ## Returns: 1 if the given module is loaded
1255 ## 0 otherwise
1256 ##
1257 proc moduleLoaded {module} {
1258 variable moduleLoadedList
1259
1260 if {[lsearch -exact $moduleLoadedList $module] != -1} then {
1261 return 1
1262 }
1263 return 0
1264 }
1265
1266 ##
1267 ## Add/remove bindings for a given module
1268 ##
1269 ## Args: mode {bind|unbind}, module,
1270 ## args {{type ...} {option ...} {regsub ... ...}}
1271 ## Returns: nothing
1272 ##
1273 proc moduleBindUnbind {mode module args} {
1274 variable NamespaceCurrent
1275
1276 if {[info exists ${NamespaceCurrent}::${module}::bindDefaults]} then {
1277 set bindtypes ""
1278 set bindoptions ""
1279 foreach option $args {
1280 switch -exact -- [lindex $option 0] {
1281 type {
1282 # dcc msg pub ...
1283 foreach opt [lrange $option 1 end] {
1284 lappend bindtypes $opt
1285 }
1286 }
1287 option {
1288 # commandchar noauto ...
1289 foreach opt [lrange $option 1 end] {
1290 lappend bindoptions $opt
1291 }
1292 }
1293 regsub {
1294 # replace regexp 'replacewhat' with 'replacewith'
1295 foreach opt [lrange $option 1 end] {
1296 foreach {rwhat rwith} $opt {break}
1297 # FIXME: better fix for leading '+/$'
1298 regsub -- "\[\\+|\\$\]" $rwhat "\\\\&" rwhat
1299 set replace($rwhat) $rwith
1300 }
1301 }
1302 }
1303 }
1304 foreach {proc data} [array get ${NamespaceCurrent}::${module}::bindDefaults] {
1305 foreach bind $data {
1306 foreach {type flags mask options help} $bind {break}
1307 if {([string compare "" $bindtypes]) && \
1308 ([lsearch -exact $bindtypes $type] == -1)} then {
1309 continue
1310 }
1311 if {[string compare "" $bindoptions]} then {
1312 set found 0
1313 foreach opt $options {
1314 if {[lsearch -exact $bindoptions $opt] != -1} then {
1315 set found 1
1316 break
1317 }
1318 }
1319 if {!$found} then {
1320 continue
1321 }
1322 }
1323 if {[lsearch -exact $options commandchar] != -1} then {
1324 set mask "[commandChar pub]$mask"
1325 }
1326 if {[array exists replace]} then {
1327 foreach {replacewhat replacewith} [array get replace] {
1328 regsub -all -- $replacewhat $mask $replacewith mask
1329 }
1330 }
1331 # bind/unbind
1332 $mode $type $flags $mask ${NamespaceCurrent}::${module}::$proc
1333 }
1334 }
1335 }
1336 return
1337 }
1338
1339 ##
1340 ## Load a module
1341 ##
1342 ## Args: module name, verbose {-1,0,1}, args {loop detection}
1343 ## Returns: nothing
1344 ## Errors: if unable to load module
1345 ##
1346 proc moduleLoad {module {verbose 0} args} {
1347 variable NamespaceCurrent
1348 variable moduleLoadedList
1349
1350 if {[lsearch -exact [set loop [lindex $args 0]] $module] == -1} then {
1351 if {[moduleExists $module]} then {
1352 set preload ""
1353 set requires [getModuleDatabaseData $module requires]
1354 foreach required $requires {
1355 set preloadModule [whichModuleCommand $required]
1356 if {[string compare "" $preloadModule]} then {
1357 if {([lsearch -exact $preload $preloadModule] == -1) && \
1358 ([string compare wp $preloadModule]) && \
1359 (![moduleLoaded $preloadModule])} then {
1360 lappend preload $preloadModule
1361 }
1362 } else {
1363 error "required command `$required' not found."
1364 }
1365 }
1366 if {[string compare "" $preload]} then {
1367 foreach premod $preload {
1368 if {[catch {moduleLoad $premod $verbose [concat $loop $module]} result]} then {
1369 error $result
1370 }
1371 }
1372 }
1373 if {[catch {source [getModuleDatabaseData $module file]} result]} then {
1374 error $result
1375 } else {
1376 package forget $module
1377 package provide ${NamespaceCurrent}::${module} [getModuleDatabaseData $module version]
1378 moduleConfigLoad $module 1
1379 moduleConfigCheckdefs $module 1
1380 moduleDataLoad $module 1
1381 # Imported commands '# requires: ...'
1382 if {[string compare "" $requires]} then {
1383 set Eval "namespace eval ${NamespaceCurrent}::${module} \{\n namespace forget *\n namespace import"
1384 foreach required $requires {
1385 if {[string compare "" [set command [whichCommand $required]]]} then {
1386 append Eval " $command"
1387 }
1388 }
1389 append Eval "\n\}"
1390 eval $Eval
1391 }
1392 # Exported commands '# provides: ...'
1393 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
1394 set Eval "namespace eval ${NamespaceCurrent}::${module} \{\n namespace export"
1395 foreach provided $provides {
1396 append Eval " $provided"
1397 }
1398 append Eval "\n\}"
1399 eval $Eval
1400 }
1401 if {[string compare "" [info commands ${NamespaceCurrent}::${module}::ModuleInit]]} then {
1402 ${NamespaceCurrent}::${module}::ModuleInit
1403 }
1404 # FIXME: check for bindings? duplicates?
1405 moduleBindUnbind bind $module
1406 if {![getModuleDatabaseData $module load]} then {
1407 setModuleDatabaseData $module load 1
1408 }
1409 if {[lsearch -exact $moduleLoadedList $module] == -1} then {
1410 lappend moduleLoadedList $module
1411 if {$verbose >= 1} then {
1412 wpLog o * "Module loaded: $module"
1413 }
1414 }
1415 }
1416 } else {
1417 error "No such module: $module"
1418 }
1419 } else {
1420 regsub -all -- " " $loop " -> " loop
1421 error "Preload endless loop: $loop -> $module"
1422 }
1423 return
1424 }
1425
1426 ##
1427 ## Unload a module
1428 ##
1429 ## Args: module name, verbose {-1,0,1}
1430 ## Returns: nothing
1431 ## Errors: if unable to completely unload module
1432 ##
1433 proc moduleUnload {module {verbose 0}} {
1434 variable NamespaceCurrent
1435 variable moduleLoadedList
1436
1437 # FIXME: handle dependant modules and modules that can't be unloaded
1438 if {[moduleExists $module]} then {
1439 if {[string compare "" [info commands ${NamespaceCurrent}::${module}::ModuleDestroy]]} then {
1440 ${NamespaceCurrent}::${module}::ModuleDestroy
1441 }
1442 # FIXME: check for bindings?
1443 moduleBindUnbind unbind $module
1444 moduleConfigSave $module 1
1445 moduleDataSave $module 1
1446 if {[catch {namespace delete ${NamespaceCurrent}::${module}} result]} then {
1447 error $result
1448 } else {
1449 package forget ${NamespaceCurrent}::${module}
1450 if {[getModuleDatabaseData $module load] == 1} then {
1451 setModuleDatabaseData $module load 0
1452 }
1453 set index [lsearch -exact $moduleLoadedList $module]
1454 if {$index != -1} then {
1455 set moduleLoadedList [lreplace $moduleLoadedList $index $index]
1456 if {$verbose >= 1} then {
1457 wpLog o * "Module unloaded: $module"
1458 }
1459 }
1460 }
1461 } else {
1462 error "No such module: $module"
1463 }
1464 return
1465 }
1466
1467 ##
1468 ## Save configuration settings for the given module
1469 ##
1470 ## Args: module, force {0,1}, verbose {-1,0,1}
1471 ## Returns: 1 if settings saved
1472 ## 0 otherwise
1473 ##
1474 proc moduleConfigSave {module {force 0} {verbose 0}} {
1475 variable NamespaceCurrent
1476 variable configData
1477
1478 if {([string compare "" \
1479 [set file [getModuleDatabaseData $module config]]]) && \
1480 ([createDir $configData(configpath)])} then {
1481 set cfgfile [file join $configData(configpath) $file]
1482 if {([getModuleDatabaseData $module load]) && \
1483 (($force) || \
1484 (![info exists ${NamespaceCurrent}::${module}::configDataChanged]) || \
1485 ([set ${NamespaceCurrent}::${module}::configDataChanged]))} then {
1486 if {[arraySave ${NamespaceCurrent}::${module}::configData $cfgfile 0 "$module configuration file "]} then {
1487 if {$verbose >= 1} then {
1488 wpLog o * "Writing $module config file..."
1489 }
1490 set ${NamespaceCurrent}::${module}::configDataChanged 0
1491 return 1
1492 } elseif {$verbose >= 0} then {
1493 wpLog o * "Error writing $module config file."
1494 }
1495 }
1496 }
1497 return 0
1498 }
1499
1500 ##
1501 ## Load configuration settings for the given module
1502 ##
1503 ## Args: module, force {0,1}, verbose {-1,0,1}
1504 ## Returns: 1 if settings loaded
1505 ## 0 otherwise
1506 ##
1507 proc moduleConfigLoad {module {force 0} {verbose 0}} {
1508 variable NamespaceCurrent
1509 variable configData
1510
1511 if {([string compare "" \
1512 [set file [getModuleDatabaseData $module config]]]) && \
1513 ([createDir $configData(configpath)])} then {
1514 set cfgfile [file join $configData(configpath) $file]
1515 if {($force) || \
1516 (![info exists ${NamespaceCurrent}::${module}::configDataChanged]) || \
1517 (![set ${NamespaceCurrent}::${module}::configDataChanged])} then {
1518 if {[arrayLoad ${NamespaceCurrent}::${module}::configData $cfgfile 0 "$module configuration file "]} then {
1519 if {$verbose >= 1} then {
1520 wpLog o * "Loading $module config file..."
1521 }
1522 set ${NamespaceCurrent}::${module}::configDataChanged 0
1523 return 1
1524 } elseif {$verbose >= 0} then {
1525 wpLog o * "Error loading $module config file."
1526 }
1527 }
1528 }
1529 return 0
1530 }
1531
1532 ##
1533 ## Check and set default configuration settings for the given module
1534 ##
1535 ## Args: module, force {0,1}, verbose {-1,0,1}
1536 ## Returns: nothing
1537 ##
1538 proc moduleConfigCheckdefs {module {force 0} {verbose 0}} {
1539 variable NamespaceCurrent
1540
1541 if {([array exists ${NamespaceCurrent}::${module}::configDefaults]) && \
1542 ([string compare "" [getModuleDatabaseData $module config]])} then {
1543 set Changed 0
1544 # Unset unknown variables
1545 foreach name [array names ${NamespaceCurrent}::${module}::configData] {
1546 if {![info exists ${NamespaceCurrent}::${module}::configDefaults($name)]} then {
1547 unset ${NamespaceCurrent}::${module}::configData($name)
1548 set Changed 1
1549 }
1550 }
1551 # Set missing variables to defaults
1552 foreach {name data} [array get ${NamespaceCurrent}::${module}::configDefaults] {
1553 if {![info exists ${NamespaceCurrent}::${module}::configData($name)]} then {
1554 set ${NamespaceCurrent}::${module}::configData($name) [lindex $data 1]
1555 set Changed 1
1556 }
1557 }
1558 # FIXME: do this with a trace?
1559 if {$Changed} then {
1560 set ${NamespaceCurrent}::${module}::configDataChanged 1
1561 }
1562 }
1563 return
1564 }
1565
1566 ##
1567 ## Handle config data for a list of modules
1568 ##
1569 ## Args: action {load|save|checkdefs}, module list, force {0,1},
1570 ## verbose {-1,0,1}
1571 ## Returns: nothing
1572 ##
1573 proc moduleConfig {action modules {force 0} {verbose 0}} {
1574 if {![string compare * $modules]} then {
1575 set modules [listModules 1]
1576 }
1577 switch -exact -- $action {
1578 save {
1579 foreach module $modules {
1580 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1581 moduleConfigSave $module $force $verbose
1582 }
1583 }
1584 }
1585 load {
1586 foreach module $modules {
1587 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1588 moduleConfigLoad $module $force $verbose
1589 }
1590 }
1591 }
1592 checkdefs {
1593 foreach module $modules {
1594 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1595 moduleConfigCheckdefs $module $force $verbose
1596 }
1597 }
1598 }
1599 }
1600 return
1601 }
1602
1603 ##
1604 ## Save data for the given module
1605 ##
1606 ## Args: module, force {0,1}, verbose {-1,0,1}
1607 ## Returns: nothing
1608 ##
1609 proc moduleDataSave {module {force 0} {verbose 0}} {
1610 variable NamespaceCurrent
1611 variable configData
1612
1613 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1614 ([createDir $configData(datapath)])} then {
1615 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1616 foreach {type file desc} $data {break}
1617 if {([info exists type]) && ([info exists file]) && \
1618 ([info exists desc])} then {
1619 set Changed ${NamespaceCurrent}::${module}::${name}Changed
1620 if {($force) || ((![info exists $Changed]) || ([set $Changed]))} then {
1621 if {[${type}Save ${NamespaceCurrent}::${module}::$name [file join $configData(datapath) $file]]} then {
1622 if {$verbose >= 1} then {
1623 wpLog o * $NamespaceCurrent "Writing $desc data file..."
1624 }
1625 set $Changed 0
1626 } elseif {$verbose >= 0} then {
1627 wpLog o * $NamespaceCurrent "Error writing $desc data file!"
1628 }
1629 }
1630 }
1631 }
1632 }
1633 return
1634 }
1635
1636 ##
1637 ## Load data for the given module
1638 ##
1639 ## Args: module, force {0,1}, verbose {-1,0,1}
1640 ## Returns: nothing
1641 ##
1642 proc moduleDataLoad {module {force 0} {verbose 0}} {
1643 variable NamespaceCurrent
1644 variable configData
1645
1646 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1647 ([createDir $configData(datapath)])} then {
1648 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1649 foreach {type file desc} $data {break}
1650 if {([info exists type]) && ([info exists file]) && \
1651 ([info exists desc])} then {
1652 set Changed ${NamespaceCurrent}::${module}::${name}Changed
1653 if {($force) || ((![info exists $Changed]) || ([set $Changed]))} then {
1654 if {[${type}Load ${NamespaceCurrent}::${module}::$name [file join $configData(datapath) $file]]} then {
1655 if {$verbose >= 1} then {
1656 wpLog o * $NamespaceCurrent "Reloading $desc data file..."
1657 }
1658 set $Changed 0
1659 } elseif {$verbose >= 0} then {
1660 wpLog o * $NamespaceCurrent "Error reloading $desc data file!"
1661 }
1662 }
1663 }
1664 }
1665 }
1666 return
1667 }
1668
1669 ##
1670 ## Backup data for the given module
1671 ##
1672 ## Args: module, force {0,1}, verbose {-1,0,1}
1673 ## Returns: nothing
1674 ##
1675 proc moduleDataBackup {module {force 0} {verbose 0}} {
1676 variable NamespaceCurrent
1677 variable configData
1678
1679 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1680 ([createDir $configData(datapath)])} then {
1681 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1682 foreach {type file desc} $data {break}
1683 if {([info exists type]) && ([info exists file]) && \
1684 ([info exists desc])} then {
1685 if {[set result [backupFile [file join $configData(datapath) $file] $verbose]]} then {
1686 if {($result >= 1) && ($verbose >= 1)} then {
1687 wpLog o * $NamespaceCurrent "Backing up $desc data file..."
1688 }
1689 } elseif {$verbose >= 0} then {
1690 wpLog o * $NamespaceCurrent "Error backing up $desc data file!"
1691 }
1692 }
1693 }
1694 }
1695 return
1696 }
1697
1698 ##
1699 ## Handle data for a list of modules
1700 ##
1701 ## Args: action {load|save|backup}, module list, force {0,1},
1702 ## verbose {-1,0,1}
1703 ## Returns: nothing
1704 ##
1705 proc moduleData {action modules {force 0} {verbose 0}} {
1706 if {![string compare * $modules]} then {
1707 set modules [listModules 1]
1708 }
1709 switch -exact -- $action {
1710 save {
1711 foreach module $modules {
1712 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1713 moduleDataSave $module $force $verbose
1714 }
1715 }
1716 }
1717 load {
1718 foreach module $modules {
1719 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1720 moduleDataLoad $module $force $verbose
1721 }
1722 }
1723 }
1724 backup {
1725 foreach module $modules {
1726 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1727 moduleDataBackup $module $force $verbose
1728 }
1729 }
1730 }
1731 }
1732 return
1733 }
1734
1735 ##
1736 ## Builds command matching table from module database
1737 ##
1738 ## Args: none
1739 ## Returns: nothing
1740 ##
1741 proc buildCommandTable {{verbose 0}} {
1742 variable NamespaceCurrent
1743 variable ExportList
1744 variable commandTable
1745
1746 foreach command $ExportList {
1747 if {![info exists tmp($command)]} then {
1748 if {$verbose >= 2} then {
1749 wpLog o * "Adding command: `$command' as `${NamespaceCurrent}::$command'"
1750 }
1751 set tmp($command) ${NamespaceCurrent}::$command
1752 } elseif {$verbose >= 0} then {
1753 wpLog o * "Warning: ignoring duplicate command `$command', conflicts with `$tmp($command)'"
1754 }
1755 }
1756 foreach module [listModules] {
1757 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
1758 foreach command $provides {
1759 if {![info exists tmp($command)]} then {
1760 if {$verbose >= 2} then {
1761 wpLog o * "Adding command: `$command' as `${NamespaceCurrent}::${module}::$command'"
1762 }
1763 set tmp($command) ${NamespaceCurrent}::${module}::$command
1764 } elseif {$verbose >= 0} then {
1765 wpLog o * "Warning: ignoring duplicate command `$command', conflicts with `$tmp($command)'"
1766 }
1767 }
1768 }
1769 }
1770 if {[info exists commandTable]} then {
1771 unset commandTable
1772 }
1773 array set commandTable [array get tmp]
1774 return
1775 }
1776
1777 ##
1778 ## Return full namespace path for the given command
1779 ##
1780 ## Args: command
1781 ## Returns: full namespace path for the given command if it exists
1782 ## nothing otherwise
1783 ##
1784 proc whichCommand {command} {
1785 variable commandTable
1786
1787 if {[info exists commandTable($command)]} then {
1788 return $commandTable($command)
1789 }
1790 return
1791 }
1792
1793 ##
1794 ## Return full namespace path for the given module
1795 ##
1796 ## Args: module
1797 ## Returns: full namespace path for the given module if it's loaded
1798 ## nothing otherwise
1799 ##
1800 proc whichModule {module} {
1801 variable NamespaceCurrent
1802
1803 if {![string compare $module [namespace tail $NamespaceCurrent] $module]} then {
1804 return $NamespaceCurrent
1805 } elseif {[moduleLoaded $module]} then {
1806 return ${NamespaceCurrent}::$module
1807 }
1808 return
1809 }
1810
1811 ##
1812 ## Return module name that provides the given command
1813 ##
1814 ## Args: command
1815 ## Returns: name of module that provides the given command
1816 ## nothing otherwise
1817 ##
1818 proc whichModuleCommand {command} {
1819 variable NamespaceCurrent
1820 variable commandTable
1821
1822 if {[info exists commandTable($command)]} then {
1823 if {![string compare ${NamespaceCurrent}::$command \
1824 $commandTable($command)]} then {
1825 return [namespace tail $NamespaceCurrent]
1826 }
1827 return [namespace tail [namespace qualifiers $commandTable($command)]]
1828 }
1829 return
1830 }
1831
1832 ##
1833 ## Compare the given version to eggdrop's version
1834 ##
1835 ## Args: version
1836 ## Returns: 0 if eggdrop's version is older then the given version
1837 ## 1 if eggdrop's version matches the given version
1838 ## 2 if eggdrop's version is newer then the given version
1839 ##
1840 proc compareVersion {version} {
1841 global numversion
1842
1843 if {[string compare "" $version]} then {
1844 if {([info exists numversion]) || \
1845 (![catch {set numversion}]) || \
1846 ([info exists numversion])} then {
1847 if {[regexp -- \\. $version]} then {
1848 regsub -all -- \\. $version 0 version
1849 set version ${version}00
1850 }
1851 if {![regexp -- \[^0-9\] $version]} then {
1852 if {$numversion > $version} then {
1853 return 2
1854 } elseif {$numversion == $version} then {
1855 return 1
1856 }
1857 }
1858 }
1859 }
1860 return 0
1861 }
1862
1863 ##
1864 ## Log module information
1865 ##
1866 ## Args: level, channel, args ({<namespace>} {<text>} | {<text>})
1867 ## Returns: nothing
1868 ##
1869 proc wpLog {level channel args} {
1870 if {[llength $args] == 2} then {
1871 if {[string compare wp [set namespace [namespace tail [lindex $args 0]]]]} then {
1872 putloglev $level $channel "Wolfpack: \[$namespace\] [lindex $args 1]"
1873 } else {
1874 putloglev $level $channel "Wolfpack: [lindex $args 1]"
1875 }
1876 } else {
1877 putloglev $level $channel "Wolfpack: [join $args]"
1878 }
1879 return
1880 }
1881
1882 ##
1883 ## Trace configuration changes
1884 ##
1885 ## Args: name1, name2, operation
1886 ## Returns: nothing
1887 ##
1888 proc TraceConfigData {name1 name2 op} {
1889 variable configData
1890 variable oldConfigData
1891
1892 if {[string compare $oldConfigData($name2) $configData($name2)]} then {
1893 switch -exact -- $name2 {
1894 commandchar {
1895 foreach module [listModules 1] {
1896 moduleBindUnbind unbind $module "type pub" "option commandchar" [list regsub "^[commandChar pub] $oldConfigData(commandchar)"]
1897 moduleBindUnbind bind $module "type pub" "option commandchar"
1898 }
1899 }
1900 }
1901 set oldConfigData($name2) $configData($name2)
1902 }
1903 return
1904 }
1905
1906 ##
1907 ## Evaluate command line arguments
1908 ##
1909 ## Args: none
1910 ## Returns: nothing
1911 ##
1912 proc EvalArgs {argc argv argv0} {
1913 variable NamespaceCurrent
1914 variable optionData
1915
1916 # Make sure defaults are sane
1917 arraySetAll optionData 0
1918 for {set index 0} {$index < $argc} {incr index} {
1919 set option [lindex $argv $index]
1920 switch -regexp -- $option {
1921 (^--config$) {
1922 set optionData(config) 1
1923 }
1924 (^--rebuild$) {
1925 set optionData(rebuild) 1
1926 }
1927 (^--norebuild$) {
1928 set optionData(norebuild) 1
1929 }
1930 (^--time$) {
1931 set optionData(time) 1
1932 }
1933 (^--verbose$) {
1934 incr optionData(verbose)
1935 }
1936 (^--quiet$) {
1937 incr optionData(quiet) -1
1938 }
1939 (^--debug$) {
1940 set optionData(debug) 1
1941 }
1942 (^--help$) {
1943 ShowUsage $argv0
1944 exit
1945 }
1946 (^--version$) {
1947 puts "[file tail $argv0] version [package require ${NamespaceCurrent}]"
1948 exit
1949 }
1950 (^-\[^-\]*$) {
1951 set suboptions [split $option ""]
1952 set sublength [llength [split $suboptions]]
1953 for {set subindex 0} {$subindex < $sublength} {incr subindex} {
1954 set suboption [lindex $suboptions $subindex]
1955 switch -exact -- $suboption {
1956 - {
1957 continue
1958 }
1959 c {
1960 set optionData(config) 1
1961 }
1962 r {
1963 set optionData(rebuild) 1
1964 }
1965 n {
1966 set optionData(norebuild) 1
1967 }
1968 t {
1969 set optionData(time) 1
1970 }
1971 v {
1972 incr optionData(verbose)
1973 }
1974 q {
1975 incr optionData(quiet) -1
1976 }
1977 d {
1978 set optionData(debug) 1
1979 }
1980 default {
1981 if {(![info exists invalidopt]) || \
1982 ($subindex == 1) || \
1983 ([lsearch -exact $invalidopt $option] == -1)} then {
1984 lappend invalidopt $option
1985 }
1986 }
1987 }
1988 }
1989 }
1990 default {
1991 lappend invalidopt $option
1992 }
1993 }
1994 }
1995
1996 # complain about invalid command line arguments
1997 if {[info exists invalidopt]} then {
1998 foreach option $invalidopt {
1999 puts stderr "[file tail $argv0]: unrecognized option `$option'"
2000 }
2001 exit 1
2002 }
2003 }
2004
2005 ##
2006 ## Show usage information
2007 ##
2008 ## Args: none
2009 ## Returns: nothing
2010 ##
2011 proc ShowUsage {argv0} {
2012 # FIXME: code missing options
2013 puts "Usage: [file tail $argv0] <options>"
2014 puts " Valid options:"
2015 puts " -c, --config start interactive configuration"
2016 #puts " -u, --update update module database"
2017 puts " -r, --rebuild force rebuild of module database"
2018 puts " -n, --norebuild don't rebuild module database even if it's outdated"
2019 puts " -t, --time time compare and rebuild of module database"
2020 #puts " -i, --include <mod> include `module' when building database"
2021 #puts " -e, --exclude <mod> exclude `module' when building database"
2022 #puts " -m, --module <mod> only update database for `module'"
2023 puts " -v, --verbose use more than once for more verbose operation"
2024 puts " -q, --quiet use more than once for quieter operation"
2025 puts " -d, --debug start in debug mode with tclsh"
2026 puts " --help show this help"
2027 puts " --version show version information"
2028 }
2029
2030 ##
2031 ## Enter interactive configuration
2032 ##
2033 ## Args: none
2034 ## Returns: nothing
2035 ##
2036 proc Iconfig {} {
2037 variable NamespaceCurrent
2038 variable IconfigDefaults
2039
2040 fileevent stdin readable ${NamespaceCurrent}::IconfigReadStdin
2041 puts "Entering wolfpack configuration system..."
2042 puts "Type 'help' for help."
2043 puts -nonewline $IconfigDefaults(prompt)
2044 flush stdout
2045 vwait forever
2046 }
2047
2048 ##
2049 ## Read stdin and process commands
2050 ##
2051 ## Args: none
2052 ## Returns: nothing
2053 ##
2054 # FIXME: readline-like support?
2055 proc IconfigReadStdin {} {
2056 variable IconfigDefaults
2057 variable configData
2058
2059 set exit 0
2060 if {[eof stdin]} {
2061 set exit 1
2062 }
2063 set stdin [string trimright [gets stdin]]
2064 set data [join [lrange [split $stdin] 1 end]]
2065 if {[string compare "" $stdin]} then {
2066 switch -exact -- [lindex [split $stdin] 0] {
2067 set {
2068 IconfigSet $data
2069 }
2070 enable {
2071 IconfigEnable $data
2072 }
2073 disable {
2074 IconfigDisable $data
2075 }
2076 modules {
2077 IconfigModules $data
2078 }
2079 info {
2080 IconfigInfo $data
2081 }
2082 help {
2083 IconfigHelp $data
2084 }
2085 quit {
2086 set exit 1
2087 }
2088 default {
2089 puts "What? You need 'help'"
2090 }
2091 }
2092 }
2093 if {(!$exit) && (![eof stdin])} then {
2094 puts -nonewline $IconfigDefaults(prompt)
2095 flush stdout
2096 } else {
2097 # Save configuration data
2098 arraySave configData $IconfigDefaults(cfgfile) 0 "configuration file "
2099 # Save module database
2100 saveModuleDatabase
2101 puts ""
2102 flush stdout
2103 exit
2104 }
2105 return
2106 }
2107
2108 ##
2109 ## Set configuration settings
2110 ##
2111 ## Args: data
2112 ## Returns: nothing
2113 ##
2114 proc IconfigSet {data} {
2115 variable configData
2116 variable configDefaults
2117
2118 if {![string compare "" $data]} then {
2119 set fmtlen1 [arrayMaxElementDataLength configDefaults 3]
2120 if {$fmtlen1 < 13} then {
2121 set fmtlen1 13 ;# 'Description: '
2122 }
2123 set names [array names configData]
2124 set fmtlen2 [listMaxElementLength $names]
2125 if {$fmtlen2 < 8} then {
2126 set fmtlen2 8 ;# 'Option: '
2127 }
2128 puts ""
2129 puts "Current settings:"
2130 puts ""
2131 # FIXME: this needs improvement
2132 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" Description: Option: Value:]
2133 foreach option [lsort $names] {
2134 if {[info exists configDefaults($option)]} then {
2135 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" [lindex $configDefaults($option) 3] $option $configData($option)]
2136 } else {
2137 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" "" $option $configData($option)]
2138 }
2139 }
2140 puts ""
2141 } else {
2142 set option [lindex [split $data] 0]
2143 if {![info exists configData($option)]} then {
2144 puts "Invalid option: $option"
2145 } else {
2146 set value [join [lrange [split $data] 1 end]]
2147 if {![string compare "" $value]} then {
2148 puts "Currently: $configData($option)"
2149 } else {
2150 set configData($option) $value
2151 puts "Set $option to: $value"
2152 }
2153 }
2154 }
2155 return
2156 }
2157
2158 ##
2159 ## Enable a module
2160 ##
2161 ## Args: data
2162 ## Returns: nothing
2163 ##
2164 proc IconfigEnable {data} {
2165 set module [lindex [split $data] 0]
2166 if {![string compare "" $module]} then {
2167 puts "Usage: enable <module>"
2168 } elseif {[moduleExists $module]} then {
2169 if {![getModuleDatabaseData $module load]} then {
2170 setModuleDatabaseData $module load 1
2171 puts "Enabled module: $module"
2172 } else {
2173 puts "Module `$module' is already enabled."
2174 }
2175 } else {
2176 puts "Invalid module: $module"
2177 }
2178 return
2179 }
2180
2181 ##
2182 ## Disable a module
2183 ##
2184 ## Args: data
2185 ## Returns: nothing
2186 ##
2187 proc IconfigDisable {data} {
2188 set module [lindex [split $data] 0]
2189 if {![string compare "" $module]} then {
2190 puts "Usage: disable <module>"
2191 } elseif {[moduleExists $module]} then {
2192 if {[getModuleDatabaseData $module load] == 1} then {
2193 setModuleDatabaseData $module load 0
2194 puts "Disabled module: $module"
2195 } else {
2196 puts "Module `$module' is already disabled."
2197 }
2198 } else {
2199 puts "Invalid module: $module"
2200 }
2201 return
2202 }
2203
2204 ##
2205 ## List modules
2206 ##
2207 ## Args: data
2208 ## returns: nothing
2209 ##
2210 # FIXME: format the list of modules better (proc from texttools?)
2211 proc IconfigModules {data} {
2212 if {[llength [set modules [listModules]]]} then {
2213 set what [lindex [split $data] 0]
2214 if {![string compare "" $what]} then {
2215 set what "all"
2216 }
2217 switch -exact -- $what {
2218 * -
2219 all {
2220 puts "Available modules:"
2221 foreach line [splitList $modules 65 " " " "] {
2222 puts " $line"
2223 }
2224 }
2225 enabled {
2226 set list ""
2227 foreach module $modules {
2228 if {[getModuleDatabaseData $module load]} {
2229 lappend list $module
2230 }
2231 }
2232 if {[llength $list]} then {
2233 puts "Enabled modules:"
2234 foreach line [splitList $list 65 " " " "] {
2235 puts " $line"
2236 }
2237 } else {
2238 puts "No modules enabled"
2239 }
2240 }
2241 disabled {
2242 set list ""
2243 foreach module $modules {
2244 if {![getModuleDatabaseData $module load]} {
2245 lappend list $module
2246 }
2247 }
2248 if {[llength $list]} then {
2249 puts "Disabled modules:"
2250 foreach line [splitList $list 65 " " " "] {
2251 puts " $line"
2252 }
2253 } else {
2254 puts "No modules disabled"
2255 }
2256 }
2257 default {
2258 puts "Error: 'option' must be one of: all, enabled, disabled"
2259 }
2260 }
2261 } else {
2262 puts "Error: No modules available."
2263 }
2264 return
2265 }
2266
2267 ##
2268 ## Show info for the given module
2269 ##
2270 ## Args: data {*|all|enabled|disabled}
2271 ## returns: nothing
2272 ##
2273 # FIXME: add multiple module support as in config.tcl and or integrate?
2274 proc IconfigInfo {data} {
2275 set module [lindex [split $data] 0]
2276 if {![string compare "" $module]} then {
2277 puts "Usage: info <module>"
2278 } elseif {[moduleExists $module]} then {
2279 puts "Info for module: $module"
2280 puts ""
2281 puts "Filename: [getModuleDatabaseData $module file]"
2282 puts "MD5: [getModuleDatabaseData $module md5sum]"
2283 puts "Version: [getModuleDatabaseData $module version]"
2284 if {[getModuleDatabaseData $module load]} then {
2285 puts "Enabled: yes"
2286 } else {
2287 puts "Enabled: no"
2288 }
2289 if {[string compare "" [set config [getModuleDatabaseData $module config]]]} then {
2290 puts "Config file: $config"
2291 }
2292 if {[string compare "" [set help [getModuleDatabaseData $module help]]]} then {
2293 puts "Help file: $help"
2294 }
2295 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
2296 puts "Provided commands:"
2297 foreach line [splitList $provides 65 " " " "] {
2298 puts " $line"
2299 }
2300 }
2301 if {[string compare "" [set requires [getModuleDatabaseData $module requires]]]} then {
2302 puts "Required commands:"
2303 foreach line [splitList $requires 65 " " " "] {
2304 puts " $line"
2305 }
2306 }
2307 puts "Description:"
2308 foreach line [splitList [getModuleDatabaseData $module description] 65 " " " "] {
2309 puts " $line"
2310 }
2311 } else {
2312 puts "Invalid module: $module"
2313 }
2314 return
2315 }
2316
2317 ##
2318 ## Show configuration help
2319 ##
2320 ## Args: data
2321 ## Returns: nothing
2322 ##
2323 proc IconfigHelp {data} {
2324 if {![string compare "" $data]} then {
2325 set data help
2326 }
2327 switch -exact -- $data {
2328 set {
2329 puts "### set \[option\] \[value\]"
2330 puts " Sets an option to what you specify."
2331 puts " Shows current setting for an option if no new value is given."
2332 puts " Shows current settings for all options if no option is given."
2333 }
2334 enable {
2335 puts "### enable <module>"
2336 puts " Enables the given module."
2337 }
2338 disable {
2339 puts "### disable <module>"
2340 puts " Disables the given module."
2341 }
2342 info {
2343 puts "### info <module>"
2344 puts " Show info for the given module."
2345 }
2346 modules {
2347 puts "### modules \[what\]"
2348 puts " Available options: all, enabled, disabled"
2349 puts " all: Shows all available modules"
2350 puts " enabled: Shows enabled modules"
2351 puts " disabled: Shows disabled modules"
2352 }
2353 help {
2354 puts "### Avaliable commands:"
2355 puts " set \[option\] \[value\]"
2356 puts " enable <module>"
2357 puts " disable <module>"
2358 puts " info <module>"
2359 puts " modules \[what\]"
2360 puts " help \[command\]"
2361 puts " quit"
2362 puts "You can get help on individual commands: 'help <command>'"
2363 }
2364 quit {
2365 puts "### quit"
2366 puts " Quits interactive configuration."
2367 }
2368 default {
2369 puts "No help available on that."
2370 }
2371 }
2372 return
2373 }
2374
2375 ##
2376 ## Inline startup and init code
2377 ##
2378
2379 wpLog o * "wolfpack.tcl v[package require $NamespaceCurrent] loading..."
2380
2381 # Init md5Sum command
2382 if {![md5Init]} then {
2383 wpLog o * "Error: can't find a usable md5 command!"
2384 return 0
2385 }
2386
2387 # Export commands
2388 eval namespace export [join $ExportList]
2389
2390 # Set missing variables to default values
2391 if {![info exists configDataChanged]} then {
2392 set configDataChanged 0
2393 }
2394 if {![info exists moduleDatabaseDataChanged]} then {
2395 set moduleDatabaseDataChanged 0
2396 }
2397 if {![info exists moduleLoadedList]} then {
2398 set moduleLoadedList ""
2399 }
2400
2401 # Load configuration data
2402 arrayLoad configData $IconfigDefaults(cfgfile) 0 "configuration file "
2403
2404 # Unset unknown configuration variables
2405 foreach name [array names configData] {
2406 if {![info exists configDefaults($name)]} then {
2407 unset configData($name)
2408 set configDataChanged 1
2409 }
2410 }
2411
2412 # Set missing configuration variables to defaults
2413 foreach {name data} [array get configDefaults] {
2414 if {![info exists configData($name)]} then {
2415 set configData($name) [lindex $data 1]
2416 set configDataChanged 1
2417 }
2418 }
2419
2420 # Set oldConfigData configuration variables to match
2421 foreach {name data} [array get configData] {
2422 if {![info exists oldConfigData($name)]} then {
2423 set oldConfigData($name) $data
2424 }
2425 }
2426
2427 # Trace configData changes
2428 trace variable configData w ${NamespaceCurrent}::TraceConfigData
2429
2430 # Save configuration data if changed
2431 if {$configDataChanged} then {
2432 arraySave configData $IconfigDefaults(cfgfile) 0 "configuration file "
2433 }
2434
2435 # Eval command line arguments if loading with tclsh
2436 if {[info exists argv0]} then {
2437 EvalArgs $argc $argv $argv0
2438 }
2439
2440 # Check verbose/quiet options
2441 if {$optionData(quiet)} then {
2442 set Verbose $optionData(quiet)
2443 } elseif {$configData(verbose)} then {
2444 set Verbose $configData(verbose)
2445 } else {
2446 set Verbose $optionData(verbose)
2447 }
2448
2449 # Check rebuild/norebuild options
2450 if {(!$optionData(norebuild)) && ($optionData(rebuild))} then {
2451 set RebuildDatabase 1
2452 } else {
2453 set RebuildDatabase 0
2454 }
2455
2456 # Sanity check: old eggdrop versions used [time] for a timestamp command
2457 if {(($optionData(time)) || ($configData(time))) && \
2458 ([catch {time}])} then {
2459 set TimeOk 1
2460 } else {
2461 set TimeOk 0
2462 }
2463
2464 # Load module database
2465 if {$Verbose >= 0} then {
2466 wpLog o * "Loading module database..."
2467 }
2468
2469 if {$TimeOk} then {
2470 set LoadTime [time {set LoadResult [loadModuleDatabase $Verbose]}]
2471 } else {
2472 set LoadResult [loadModuleDatabase $Verbose]
2473 }
2474
2475 if {$LoadResult != -1} then {
2476 if {$Verbose >= 0} then {
2477 if {[info exists LoadTime]} then {
2478 wpLog o * "Done. ([format "%.3f" [expr [lindex $LoadTime 0] / 1000000.0]] seconds elapsed)"
2479 } else {
2480 wpLog o * "Done."
2481 }
2482 }
2483 set CreateDatabase 0
2484 } else {
2485 if {$Verbose >= 0} then {
2486 wpLog o * "Warning: module database does not exist."
2487 }
2488 set CreateDatabase 1
2489 }
2490
2491 set NeedsRebuild 0
2492
2493 # Compare module database if we are not going to rebuild or create it
2494 if {(!$RebuildDatabase) && (!$CreateDatabase)} then {
2495 if {$Verbose >= 0} then {
2496 wpLog o * "Comparing module database..."
2497 }
2498 if {![file exists $configData(moddbfile)]} then {
2499 set NeedsRebuild 1
2500 } else {
2501 if {$TimeOk} then {
2502 set CompareTime [time {set CompareResult [compareModuleDatabase $Verbose]}]
2503 } else {
2504 set CompareResult [compareModuleDatabase $Verbose]
2505 }
2506 if {!$CompareResult} then {
2507 set NeedsRebuild 1
2508 }
2509 }
2510
2511 if {$Verbose >= 0} then {
2512 if {[info exists CompareTime]} then {
2513 wpLog o * "Done. ([format "%.3f" [expr [lindex $CompareTime 0] / 1000000.0]] seconds elapsed)"
2514 } else {
2515 wpLog o * "Done."
2516 }
2517 if {$NeedsRebuild} then {
2518 wpLog o * "Database is outdated."
2519 } else {
2520 wpLog o * "Database is current."
2521 }
2522 }
2523 }
2524
2525 # Create database if does not exist
2526 # Rebuild database if requested
2527 # Rebuild database if it's outdated and config permits
2528 if {($CreateDatabase) || ($RebuildDatabase) || \
2529 (($NeedsRebuild) && ($configData(rebuild)))} then {
2530
2531 if {$Verbose >= 0} then {
2532 if {$CreateDatabase} then {
2533 wpLog o * "Creating module database..."
2534 } else {
2535 wpLog o * "Rebuilding module database..."
2536 }
2537 }
2538
2539 # Rebuild module database
2540 if {$TimeOk} then {
2541 set RebuildTime [time {rebuildModuleDatabase $Verbose}]
2542 } else {
2543 rebuildModuleDatabase $Verbose
2544 }
2545
2546 if {$Verbose >= 0} then {
2547 if {[info exists RebuildTime]} then {
2548 wpLog o * "Done. ([format "%.3f" [expr [lindex $RebuildTime 0] / 1000000.0]] seconds elapsed)"
2549 } else {
2550 wpLog o * "Done."
2551 }
2552 }
2553
2554 # Save module database
2555 if {$Verbose >= 0} then {
2556 wpLog o * "Saving module database..."
2557 }
2558
2559 if {$TimeOk} then {
2560 set SaveTime [time {set SaveResult [saveModuleDatabase $Verbose]}]
2561 } else {
2562 set SaveResult [saveModuleDatabase $Verbose]
2563 }
2564
2565 if {$Verbose >= 0} then {
2566 if {$SaveResult} then {
2567 if {[info exists SaveTime]} then {
2568 wpLog o * "Done. ([format "%.3f" [expr [lindex $SaveTime 0] / 1000000.0]] seconds elapsed)"
2569 } else {
2570 wpLog o * "Done."
2571 }
2572 } else {
2573 wpLog o * "Error"
2574 }
2575 }
2576
2577 } elseif {($NeedsRebuild) && ($Verbose >= 0)} then {
2578 wpLog o * "Warning: not rebuilding outdated module database..."
2579 }
2580
2581 # Enter interactive configuration if loading with tclsh
2582 if {[info exists argv0]} then {
2583 if {$optionData(config)} then {
2584 Iconfig
2585 }
2586 }
2587
2588 # Build command table
2589 if {(![info exists argv0]) || ($optionData(debug))} then {
2590 if {$Verbose >= 0} then {
2591 wpLog o * "Building command table..."
2592 }
2593 if {$TimeOk} then {
2594 set CommandTime [time {buildCommandTable $Verbose}]
2595 } else {
2596 buildCommandTable $Verbose
2597 }
2598 if {$Verbose >= 0} then {
2599 if {[info exists CommandTime]} then {
2600 wpLog o * "Done. ([format "%.3f" [expr [lindex $CommandTime 0] / 1000000.0]] seconds elapsed)"
2601 } else {
2602 wpLog o * "Done."
2603 }
2604 }
2605
2606 set loadList ""
2607
2608 # Load debug module first if not in eggdrop mode
2609 if {([info exists argv0]) && ([moduleExists debug])} then {
2610 lappend loadList debug
2611 }
2612
2613 # Load other modules next, moduleLoad will preload additional modules
2614 foreach name [lsort [array names moduleDatabaseData]] {
2615 if {[getModuleDatabaseData $name load] == 1} then {
2616 lappend loadList $name
2617 }
2618 }
2619
2620 wpLog o * "Loading modules..."
2621
2622 # Load modules
2623 if {$TimeOk} then {
2624 set LoadTime [time {
2625 foreach module $loadList {
2626 if {[catch {moduleLoad $module $Verbose} result]} then {
2627 wpLog o * "Error: unable to load module `$module': $result"
2628 }
2629 }
2630 }]
2631 } else {
2632 foreach module $loadList {
2633 if {[catch {moduleLoad $module $Verbose} result]} then {
2634 wpLog o * "Error: unable to load module `$module': $result"
2635 }
2636 }
2637 }
2638
2639 if {[info exists LoadTime]} then {
2640 wpLog o * "Done. ([format "%.3f" [expr [lindex $LoadTime 0] / 1000000.0]] seconds elapsed)"
2641 } else {
2642 wpLog o * "Done."
2643 }
2644
2645 set ModuleLoadCount [llength [split $moduleLoadedList]]
2646 if {$ModuleLoadCount} then {
2647 set ModuleTotalCount [llength [array names moduleDatabaseData]]
2648 wpLog o * "Modules loaded ($ModuleLoadCount/$ModuleTotalCount): $moduleLoadedList"
2649 } else {
2650 wpLog o * "No modules loaded."
2651 }
2652
2653 # Unload modules if started in debug mode
2654 if {$optionData(debug)} then {
2655
2656 # FIXME: code module dependency stuff first
2657 # wpLog o * "Unloading modules..."
2658
2659 # Unload all modules except debug
2660 # foreach module $moduleLoadedList {
2661 # if {[string compare $module debug]} then {
2662 # if {[catch {moduleUnload $module $Verbose} result]} then {
2663 # wpLog o * "Error: unable to unload module `$module': $result"
2664 # }
2665 # }
2666 # }
2667
2668 # Unload debug module last to make it display stats
2669 if {[moduleLoaded debug]} then {
2670 if {[catch {moduleUnload debug} result]} then {
2671 wpLog o * "Error: unable to unload module `debug': $result"
2672 }
2673 }
2674 # wpLog o * "Done."
2675 }
2676 }
2677
2678 } ;# namespace ::wp
2679
2680 return

webmaster@eggheads.org
ViewVC Help
Powered by ViewVC 1.1.23