/[cvs]/wolfpack/wolfpack.tcl
ViewVC logotype

Contents of /wolfpack/wolfpack.tcl

Parent Directory Parent Directory | Revision Log Revision Log | View Revision Graph Revision Graph


Revision 1.17 - (show annotations) (download) (as text)
Tue Jan 14 09:20:10 2003 UTC (16 years, 9 months ago) by tothwolf
Branch: MAIN
Changes since 1.16: +6 -3 lines
File MIME type: application/x-tcl
*** empty log message ***

1 #! /bin/sh
2 # \
3 # Nice little hack to find latest version of tclsh in PATH \
4 # \
5 # NOTE: backslash and semicolon placements are important! \
6 # \
7 # Search for tclsh[0-9].[0-9] in each valid dir in PATH \
8 for dir in $(echo $PATH | sed 's/:/ /g'); \
9 do \
10 if test -d $dir; \
11 then \
12 files=$(/bin/ls $dir | egrep '^tclsh[0-9]\.[0-9]$'); \
13 if test "$files" != ""; \
14 then \
15 versions="${versions:+$versions }$(echo $files | sed 's/tclsh//g')"; \
16 fi; \
17 fi; \
18 done; \
19 # Loop over each version to find the latest version of tclsh \
20 for ver in $versions; \
21 do \
22 tmpver=$(echo $ver | sed 's/\.//g'); \
23 if test "$lasttmpver" != ""; \
24 then \
25 if test "$tmpver" -gt "$lasttmpver"; \
26 then \
27 lastver=$ver; \
28 lasttmpver=$tmpver; \
29 fi; \
30 else \
31 lastver=$ver; \
32 lasttmpver=$tmpver; \
33 fi; \
34 done; \
35 # Use the latest tclsh version found, otherwise fall back to 'tclsh' \
36 exec tclsh$lastver "$0" "$@"
37 ###############################################################################
38 ##
39 ## Wolfpack - A modular Tcl system for Eggdrop 1.3.0+ with Tcl 8.0+
40 ## Copyright (C) 1998-2003 Tothwolf <tothwolf@concentric.net>
41 ##
42 ## This program is free software; you can redistribute it and/or modify
43 ## it under the terms of the GNU General Public License as published by
44 ## the Free Software Foundation; either version 2 of the License, or
45 ## (at your option) any later version.
46 ##
47 ## This program is distributed in the hope that it will be useful,
48 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
49 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
50 ## GNU General Public License for more details.
51 ##
52 ## You should have received a copy of the GNU General Public License
53 ## along with this program; if not, write to the Free Software
54 ## Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
55 ##
56 ###############################################################################
57 ##
58 ## You should not need to edit anything in any of these files.
59 ##
60 ## './wolfpack.tcl -c' may be used to configure initial settings.
61 ## './wolfpack.tcl --help' will list all avaliable options.
62 ##
63 ## Use '.wpconf' in dcc chat with the bot to configure everything else.
64 ##
65 ###############################################################################
66 ##
67 ## $Id: wolfpack.tcl,v 1.16 2003/01/14 09:05:08 tothwolf Exp $
68 ##
69
70 # make sure Tcl version is compatible with this code (we use namespaces)
71 if {[catch {package require Tcl 8.0}]} then {
72 if {[info exists argv0]} then {
73 puts "Wolfpack: Error: wolfpack requires Tcl 8.0 or later to load."
74 } else {
75 putloglev o * "Wolfpack: Error: wolfpack requires Tcl 8.0 or later to load."
76 }
77 return 0
78 }
79
80 namespace eval :: {
81
82 # Eggdrop doesn't currently set argv0, so we use that to detect load type.
83 global argv0
84
85 if {![info exists argv0]} then {
86 # HACK: quick fix for buggy tcl variables in older bots
87 catch {set version}
88 catch {set numversion}
89 # require eggdrop 1.3.0 or later
90 if {(![info exists version]) || (![info exists numversion]) || \
91 ($numversion < 1030000)} then {
92 putloglev o * "Wolfpack: Error: wolfpack requires Eggdrop 1.3.0 or later to load."
93 return 0
94 }
95 } else {
96 # emulate eggdrop's putloglev when loading with tclsh
97 if {![string compare "" [info commands putloglev]]} then {
98 proc putloglev {level channel text} {
99 puts $text
100 }
101 }
102 }
103
104 ##
105 ## Log tcl messages where they can be seen
106 ##
107 ## Args: text
108 ## Returns: nothing
109 ##
110 proc tclLog {text} {
111 # Tcl's tclLog embeds newlines in it's output
112 if {[string first \n $text] == -1} then {
113 putloglev o * "Wolfpack: \[Tcl\]: $text"
114 } else {
115 foreach line [split $text \n] {
116 putloglev o * "Wolfpack: \[Tcl\]: $line"
117 }
118 }
119 return
120 }
121
122 } ;# namespace ::
123
124 namespace eval ::wp {
125
126 # manage package information
127 package forget ::wp
128 package provide ::wp 1.9.9.0
129
130 # set namespace variable
131 set NamespaceCurrent [namespace current]
132
133 ##
134 ## WARNING: If you change these, you may render your module database useless!
135 ##
136
137 # Max number of lines to scan in a module file
138 set moduleDatabaseConfig(scanlines) 30
139
140 # Max depth to list directories in module path
141 set moduleDatabaseConfig(maxdepth) 4
142
143 # Module database version
144 set moduleDatabaseConfig(version) 2.0
145
146 # Module database header
147 set moduleDatabaseConfig(header) "Wolfpack module database "
148
149 # Module database defaults
150 set moduleDatabaseConfig(defaults) "{version 0.1} {description {(no description)}} {load 0}"
151
152 # Versioned module database formats
153 array set moduleDatabaseFormat {
154 2.0 "{version config help description provides requires} {load file md5sum}"
155 }
156
157 # md5 style, command name and result string index
158 array set md5Format {
159 bsd "md5 3"
160 gnu "md5sum 0"
161 }
162
163 # Configuration file
164 set IconfigDefaults(cfgfile) wolfpack.conf
165
166 # Interactive configuration prompt
167 set IconfigDefaults(prompt) "wolfpack> "
168
169 # Configuration defaults, values and descriptions
170 array set configDefaults {
171 modulepath {word modules/ {} {Module path}}
172 configpath {word wpconf/ {} {Config path}}
173 datapath {word wpdata/ {} {Data path}}
174 helppath {word wphelp/ {} {Help path}}
175 moddbfile {word wolfpack.db {} {Module database file}}
176 rebuild {{range {0 1}} 1 {} {Automatically rebuild database}}
177 verbose {{range {0 1}} 0 {} {Verbose operation}}
178 time {{range {0 1}} 0 {} {Time database compare and rebuild}}
179 commandchar {word - {} {Character to prefix public commands with}}
180 }
181
182 # Command line option defaults
183 array set optionData {
184 config 0
185 rebuild 0
186 norebuild 0
187 time 0
188 verbose 0
189 quiet 0
190 debug 0
191 }
192
193 # Exported commands
194 set ExportList {
195 md5Sum
196 md5Init
197 replaceExpr
198 listFiles
199 listSubdirs
200 findFiles
201 createFile
202 createDir
203 backupFile
204 listSave
205 listLoad
206 arraySave
207 arrayLoad
208 arraySetAll
209 arrayFindElementName
210 arrayMaxElementDataLength
211 listMaxElementLength
212 splitList
213 arraySearch
214 commandChar
215 dataFormatDefault
216 dataFormatValue
217 dataFormatReplace
218 dataFormatBuild
219 dataFormatConvert
220 scanModule
221 getModuleDatabaseData
222 setModuleDatabaseData
223 saveModuleDatabase
224 loadModuleDatabase
225 compareModuleDatabase
226 rebuildModuleDatabase
227 listModules
228 moduleExists
229 moduleLoaded
230 moduleBindUnbind
231 moduleLoad
232 moduleUnload
233 moduleConfigSave
234 moduleConfigLoad
235 moduleConfigCheckdefs
236 moduleConfig
237 moduleDataSave
238 moduleDataLoad
239 moduleDataBackup
240 moduleData
241 buildCommandTable
242 whichCommand
243 whichModule
244 whichModuleCommand
245 compareVersion
246 wpLog
247 }
248
249 ##
250 ## Create md5 checksum for a file
251 ##
252 ## Args: filename
253 ## Returns: md5 checksum if successful
254 ## Errors: permission denied,
255 ## no such file,
256 ## not a file,
257 ## can't exec md5 command
258 ##
259 proc md5Sum {file} {
260 variable md5Config
261
262 if {![file exists $file]} then {
263 error "$file: no such file"
264 } else {
265 if {![file isfile $file]} then {
266 error "$file: not a file"
267 } else {
268 if {![file readable $file]} then {
269 error "$file: permission denied"
270 } else {
271 if {[catch {set sum [lindex [exec $md5Config(command) $file] $md5Config(index)]} result]} then {
272 error "$file: $result"
273 } else {
274 return $sum
275 }
276 }
277 }
278 }
279 }
280
281 ##
282 ## Init md5 command
283 ##
284 ## Args: none
285 ## Returns: 1 if a useable md5 command found
286 ## 0 otherwise
287 ##
288 proc md5Init {} {
289 variable md5Config
290 variable md5Format
291
292 foreach type [array names md5Format] {
293 foreach {command index} $md5Format($type) {break}
294 if {([catch {exec $command ""} result]) && \
295 (![regexp -- "^couldn't execute" $result])} then {
296 set md5Config(command) $command
297 set md5Config(index) $index
298 return 1
299 }
300 }
301 return 0
302 }
303
304 ##
305 ## Replace all occurances of an expression in a string with the given text
306 ##
307 ## Args: string, expr, replacement text
308 ## Returns: string
309 ##
310 proc replaceExpr {string expr {replace ""}} {
311 while {[regexp -nocase -- $expr $string]} {
312 regsub -all -- $expr $string $replace string
313 }
314 return $string
315 }
316
317 ##
318 ## List files in a path
319 ##
320 ## Args: path
321 ## Returns: list of files in the given path,
322 ## nothing if no files in the given path
323 ## Errors: permission denied,
324 ## no such directory,
325 ## not a directory
326 ##
327 proc listFiles {path} {
328 if {![file exists $path]} then {
329 error "$path: no such directory"
330 } else {
331 if {![file isdirectory $path]} then {
332 error "$path: not a directory"
333 } else {
334 if {![file readable $path]} then {
335 error "$path: permission denied"
336 } else {
337 set ret ""
338 foreach name [lsort [glob -nocomplain -- [file join $path *]]] {
339 if {[file isfile $name]} then {
340 lappend ret $name
341 }
342 }
343 return $ret
344 }
345 }
346 }
347 }
348
349 ##
350 ## List subdirs in a path
351 ##
352 ## Args: path
353 ## Returns: list of subdirs in the given path,
354 ## nothing if no subdirs in the given path
355 ## Errors: permission denied,
356 ## no such directory,
357 ## not a directory
358 ##
359 proc listSubdirs {path} {
360 if {![file exists $path]} then {
361 error "$path: no such directory"
362 } else {
363 if {![file isdirectory $path]} then {
364 error "$path: not a directory"
365 } else {
366 if {![file readable $path]} then {
367 error "$path: permission denied"
368 } else {
369 set ret ""
370 foreach name [lsort [glob -nocomplain -- [file join $path *]]] {
371 if {[file isdirectory $name]} then {
372 lappend ret $name
373 }
374 }
375 return $ret
376 }
377 }
378 }
379 }
380
381 ##
382 ## List files with a set ext in a path and its subdirs up to a set depth
383 ##
384 ## Args: path, max search depth, file extension
385 ## Returns: list of files with a set ext in the given path and its subdirs,
386 ## nothing if no matching files are found
387 ##
388 proc findFiles {path depth {ext ""}} {
389 set ret ""
390 set foundDirs "$path "
391 set searchDirs $path
392 for {
393 set currentDepth 0
394 } {($currentDepth <= $depth) || (!$depth)} {
395 incr currentDepth
396 } {
397 set subDirs ""
398 foreach dir $searchDirs {
399 if {[catch {set dirList [listSubdirs $dir]} result]} then {
400 wpLog o * "Error: unable to get file listing: $result"
401 } elseif {[string compare "" $dirList]} then {
402 append subDirs $dirList " "
403 }
404 }
405 if {![string compare "" $subDirs]} then {
406 break
407 }
408 append foundDirs $subDirs " "
409 set searchDirs $subDirs
410 }
411 foreach dir $foundDirs {
412 if {[catch {set files [listFiles $dir]} result]} then {
413 wpLog o * "Error: unable to get file listing: $result"
414 } else {
415 if {[string compare "" $ext]} then {
416 foreach file $files {
417 if {![string compare $ext \
418 [string tolower [file extension $file]]]} then {
419 lappend ret $file
420 }
421 }
422 } else {
423 set ret $files
424 }
425 }
426 }
427 return $ret
428 }
429
430 ##
431 ## Check if a file exists, and create it if not
432 ##
433 ## Args: filename, verbose {-1,0,1}, description, force new file
434 ## Returns: 1 if the file was created successfully
435 ## 0 if the operation failed
436 ## -1 if the file already exists
437 ##
438 proc createFile {file {verbose 0} {desc "file "} {force 0}} {
439 if {($force) || (![file exists $file])} then {
440 if {[catch {set fd [open $file w]} result]} then {
441 if {$verbose >= 0} then {
442 wpLog o * "Error: unable to create ${desc}`[file tail $file]': $result"
443 }
444 } else {
445 if {(!$force) && ($verbose >= 1)} then {
446 wpLog o * "Warning: ${desc}`[file tail $file]' does not exist -- creating"
447 }
448 close $fd
449 return 1
450 }
451 } elseif {[file isfile $file]} then {
452 return -1
453 } elseif {$verbose >= 0} then {
454 wpLog o * "Error: not a file: $file"
455 }
456 return 0
457 }
458
459 ##
460 ## Check if a directory exists, and create it if not
461 ##
462 ## Args: directory, verbose {-1,0,1}, description
463 ## Returns: 1 if the directory was created successfully
464 ## 0 if the operation failed
465 ## -1 if the directory already exists
466 ##
467 proc createDir {dir {verbose 0} {desc "directory "}} {
468 if {![file exists $dir]} then {
469 if {[catch {file mkdir $dir} result]} then {
470 if {$verbose >= 0} then {
471 wpLog o * "Error: unable to create ${desc}`[file tail $dir]': $result"
472 }
473 } else {
474 if {$verbose >= 1} then {
475 wpLog o * "Warning: ${desc}`[file tail $dir]' does not exist -- creating"
476 }
477 return 1
478 }
479 } elseif {[file isdirectory $dir]} then {
480 return -1
481 } elseif {$verbose >= 0} then {
482 wpLog o * "Error: not a directory: $dir"
483 }
484 return 0
485 }
486
487 ##
488 ## Create a backup of the given file with an optional suffix
489 ##
490 ## Args: filename, suffix, verbose {-1,0,1}
491 ## Returns: 1 if successful
492 ## -1 if file is 0 in size
493 ## 0 otherwise
494 ##
495 proc backupFile {file {verbose 0} {suffix ~bak}} {
496 variable NamespaceCurrent
497
498 if {[string compare "" $suffix]} then {
499 if {[file size $file]} then {
500 if {[catch {
501 file copy -force $file $file${suffix}
502 } result]} then {
503 if {$verbose >= 0} then {
504 wpLog o * $NamespaceCurrent "Error: unable to create backup file for `[file tail $file]': $result"
505 }
506 } else {
507 return 1
508 }
509 } else {
510 return -1
511 }
512 }
513 return 0
514 }
515
516 ##
517 ## Save data from a list into a file
518 ##
519 ## Args: list, filename, verbose {-1,0,1}, description, access flag
520 ## Returns: 1 is successful,
521 ## 0 otherwise
522 ##
523 proc listSave {listName file {verbose 0} {desc "file "} {access w}} {
524 upvar 1 $listName list
525
526 if {[createFile $file $verbose $desc]} then {
527 if {[catch {set fd [open $file $access]} result]} then {
528 if {$verbose >= 0} then {
529 wpLog o * "Error: unable to open ${desc}`$file' for writing: $result"
530 }
531 } else {
532 if {[info exists list]} then {
533 foreach data $list {
534 puts $fd [list $data]
535 }
536 }
537 close $fd
538 return 1
539 }
540 }
541 return 0
542 }
543
544 ##
545 ## Load data into a list from a file
546 ##
547 ## Args: list, filename, verbose {-1,0,1}, description, ignore regsub
548 ## Returns: 1 if successful,
549 ## 0 otherwise
550 ##
551 proc listLoad {listName file {verbose 0} {desc "file "} {ignore "^#"}} {
552 upvar 1 $listName list
553
554 if {[createFile $file $verbose $desc]} then {
555 if {[catch {set fd [open $file r]} result]} then {
556 if {$verbose >= 0} then {
557 wpLog o * "Error: unable to open ${desc}`$file' for reading: $result"
558 }
559 } else {
560 if {[info exists list]} then {
561 unset list
562 }
563 while {![eof $fd]} {
564 set line [replaceExpr [gets $fd] "^ "]
565 if {([string compare "" $line]) && \
566 (![regexp -- $ignore $line])} then {
567 append list $line " "
568 }
569 }
570 close $fd
571 return 1
572 }
573 }
574 return 0
575 }
576
577 ##
578 ## Save data from an array info a file
579 ##
580 ## Args: array, filename, verbose {-1,0,1}, description, access flag
581 ## Returns: 1 is successful,
582 ## 0 otherwise
583 ##
584 proc arraySave {arrayName file {verbose 0} {desc "file "} {access w}} {
585 upvar 1 $arrayName array
586
587 if {[createFile $file $verbose $desc]} then {
588 if {[catch {set fd [open $file $access]} result]} then {
589 if {$verbose >= 0} then {
590 wpLog o * "Error: unable to open ${desc}`$file' for writing: $result"
591 }
592 } else {
593 if {[array exists array]} then {
594 foreach name [lsort [array names array]] {
595 puts $fd "[list $name] [list $array($name)]"
596 }
597 close $fd
598 return 1
599 } else {
600 close $fd
601 }
602 }
603 }
604 return 0
605 }
606
607 ##
608 ## Load data into an array from a file
609 ##
610 ## Args: array, filename, verbose {-1,0,1}, description, ignore regsub
611 ## Returns: 1 if successful,
612 ## 0 otherwise
613 ##
614 proc arrayLoad {arrayName file {verbose 0} {desc "file "} {ignore "^#"}} {
615 upvar 1 $arrayName array
616
617 if {[createFile $file $verbose $desc]} then {
618 if {[catch {set fd [open $file r]} result]} then {
619 if {$verbose >= 0} then {
620 wpLog o * "Error: unable to open ${desc}`$file' for reading: $result"
621 }
622 } else {
623 if {[info exists array]} then {
624 unset array
625 }
626 while {![eof $fd]} {
627 set line [replaceExpr [gets $fd] "^ "]
628 if {([string compare "" $line]) && \
629 (![regexp -- $ignore $line])} then {
630 set array([lindex $line 0]) [lindex $line 1]
631 }
632 }
633 close $fd
634 return 1
635 }
636 }
637 return 0
638 }
639
640 ##
641 ## Set all elements in the given array the the given value
642 ##
643 ## Args: array name, value
644 ## Returns: 1 if the array exists
645 ## 0 otherwise
646 ##
647 proc arraySetAll {arrayName {value ""}} {
648 upvar 1 $arrayName array
649
650 if {[array exists array]} then {
651 foreach name [array names array] {
652 set array($name) $value
653 }
654 return 1
655 }
656 return 0
657 }
658
659 ##
660 ## Find the given element in an array
661 ##
662 ## Args: array name, element name
663 ## Returns: case sensitive element name if found,
664 ## nothing otherwise
665 ##
666 proc arrayFindElementName {array element} {
667 set list [lsort [array names $array]]
668 set index [lsearch -exact [string tolower $list] [string tolower $name]]
669 if {$index != -1} then {
670 return [lindex $list $index]
671 }
672 return
673 }
674
675 ##
676 ## Return length of longest data in an array at index
677 ##
678 ## Args: array name
679 ## Returns: length of longest name in an array
680 ##
681 proc arrayMaxElementDataLength {arrayName index} {
682 upvar 1 $arrayName array
683
684 set maxlength 0
685 foreach {name data} [array get array] {
686 set length [string length [lindex $data $index]]
687 if {$length > $maxlength} then {
688 set maxlength $length
689 }
690 }
691 return $maxlength
692 }
693
694 ##
695 ## Return length of the longest element in a list
696 ##
697 ## Args: list
698 ## Returns: length of longest element in the given list
699 ##
700 proc listMaxElementLength {list} {
701 set maxlength 0
702 foreach data $list {
703 set length [string length $data]
704 if {$length > $maxlength} then {
705 set maxlength $length
706 }
707 }
708 return $maxlength
709 }
710
711 ##
712 ## Split up a list into multiple elements
713 ##
714 ## Args: text, max list length, split char, trim chars
715 ## Returns: split list
716 ##
717 # FIXME: improve this
718 proc splitList {text {splitLength 75} {splitChar " "} {trimChars " "}} {
719 # Sanity check splitLength and splitChar
720 if {($splitLength >= 1) && ([string compare "" $splitChar])} then {
721 set elementSplitLength [expr $splitLength - 1]
722 set stringLength [string length $text] ;# Total length of string
723 set subStringLength 0 ;# Text left over
724 set elementLength 0 ;# Element length counter
725 set elementStartIndex 0 ;# Start of split element
726 set elementEndIndex 0 ;# End of split element
727 for {
728 set stringIndex 0
729 } {$stringIndex < $stringLength} {
730 incr stringIndex
731 } {
732 # If element length greater than/equal to split length,
733 # Or element length equal to split length - 1,
734 # And character at current string index is splitChar
735 if {(($elementLength >= $splitLength) ||
736 ($elementLength == $elementSplitLength)) &&
737 (![string compare $splitChar \
738 [string index $text $stringIndex]])} then {
739 # Split substring element from text
740 set string [string range $text $elementStartIndex $elementEndIndex]
741 # Append substring element list to list
742 lappend list [string trim $string $trimChars]
743 # Reset element length counter
744 set elementLength 0
745 # Start split of next element at the end + 1 of the current one
746 set elementStartIndex [expr $elementEndIndex + 1]
747 # Reset end of next element to the start of the next element
748 set elementEndIndex $elementStartIndex
749 # Track remaining text length
750 set subStringLength [expr $subStringLength + [string length $string]]
751 } else {
752 # Increment element length
753 incr elementLength
754 # Increment end of next element
755 incr elementEndIndex
756 }
757 }
758 # Append any left over text as a new element
759 if {$stringLength > $subStringLength} then {
760 lappend list [string trim [string range $text $subStringLength end] $trimChars]
761 }
762 # Whew...that was alot of work!
763 if {[info exists list]} then {
764 return $list
765 }
766 }
767 return
768 }
769
770 ##
771 ## Search an array for a given word or regexp
772 ##
773 ## Args: array name, word/regexp
774 ## Returns: list of indexes that match the given word/regexp
775 ##
776 proc arraySearch {array word} {
777 set word [string tolower $word]
778 set ret ""
779 foreach {name data} [array get $array] {
780 set string [string tolower $data]
781 if {[lsearch -regexp $string $word] != -1} then {
782 for {
783 set index 0
784 set indexes ""
785 } {
786 if {[regexp -- .*$word $string]} then {
787 lappend indexes $index
788 }
789 } {
790 incr index
791 }
792 lappend ret [list [concat $name $indexes]]
793 }
794 }
795 return $ret
796 }
797
798 ##
799 ## Return current command character
800 ##
801 ## Args: type {pub,msg,dcc,fil}
802 ## Returns: command character for the type given
803 ##
804 proc commandChar {type} {
805 global botnick
806 variable configData
807
808 switch -exact -- $type {
809 pub {
810 return $configData(commandchar)
811 }
812 msg {
813 return "/msg $botnick "
814 }
815 dcc {
816 return
817 }
818 fil {
819 return
820 }
821 default {
822 error "Unknown command character type: $type"
823 }
824 }
825 return
826 }
827
828 ##
829 ## Find option default for the given option name in a data list
830 ##
831 ## Args: data list, option name
832 ## Returns: option default if found,
833 ## nothing otherwise
834 ##
835 proc dataFormatDefault {list option} {
836 foreach i $list {
837 if {![string compare $option [lindex $i 0]]} then {
838 return [lindex $i 1]
839 }
840 }
841 return
842 }
843
844 ##
845 ## Find option value for the given option name in a data list
846 ##
847 ## Args: data format, data list, option name
848 ## Returns: option value if found,
849 ## nothing otherwise
850 ##
851 proc dataFormatValue {format data option} {
852 if {[set index [lsearch -exact $format $option]] != -1} then {
853 return [lindex $data $index]
854 }
855 return
856 }
857
858 ##
859 ## Replace option data in the given data list with a new value
860 ##
861 ## Args: data format, data list, option name, new value
862 ## Returns: data list
863 ##
864 proc dataFormatReplace {format data option value} {
865 if {[set index [lsearch -exact $format $option]] != -1} then {
866 return [lreplace $data $index $index $value]
867 }
868 return $data
869 }
870
871 ##
872 ## Create a data format list for a given data format and options
873 ##
874 ## Args: data format list, defaults, options {{option1 value} ...}
875 ## Returns: data format list with options and values in proper order
876 ##
877 proc dataFormatBuild {format defaults args} {
878 set ret ""
879 foreach arg $args {
880 set [lindex $arg 0] [lindex $arg 1]
881 }
882 foreach opt $format {
883 if {[info exists $opt]} then {
884 lappend ret [set $opt]
885 } else {
886 lappend ret [dataFormatDefault $defaults $opt]
887 }
888 }
889 return $ret
890 }
891
892 ##
893 ## Convert a data list from one format to another
894 ##
895 ## Args: from format, to format, data list
896 ## Returns: data list
897 ##
898 proc dataFormatConvert {fromFormat toFormat data} {
899 set ret ""
900 set index 0
901 foreach opt $fromFormat {
902 set $opt [lindex $data $index]
903 incr index
904 }
905 foreach opt $toFormat {
906 if {[info exists $opt]} then {
907 lappend ret [set $opt]
908 } else {
909 lappend ret [dataFormatDefault $defaults $opt]
910 }
911 }
912 return $ret
913 }
914
915 ##
916 ## Scan the given file for module options
917 ##
918 ## Args: file, args {only scan for these options}
919 ## Returns: list of module options if the given file is a module,
920 ## nothing otherwise
921 ## Errors: unable to open file for reading
922 ##
923 proc scanModule {file args} {
924 variable moduleDatabaseConfig
925 variable moduleDatabaseFormat
926
927 if {[catch {set fd [open $file r]} result]} then {
928 error $result
929 } else {
930 set ret ""
931 if {![string compare "" $args]} then {
932 set baseOptions [lindex $moduleDatabaseFormat([set moduleDatabaseConfig(version)]) 0]
933 set extraOptions [lindex $moduleDatabaseFormat([set moduleDatabaseConfig(version)]) 1]
934 set scanOptions "name $baseOptions"
935 set formatOptions "name $baseOptions $extraOptions"
936 } else {
937 set scanOptions $args
938 set formatOptions $args
939 }
940 for {
941 set lineCount 0
942 set optionCount 0
943 set continuedLine 0
944 } {(![eof $fd]) && ($lineCount <= $moduleDatabaseConfig(scanlines))} {
945 incr lineCount
946 } {
947 gets $fd line
948 if {[regexp -- "^# .*:.*" $line]} then {
949 set opt [string trimright [lindex $line 1] :]
950 if {[lsearch -glob $scanOptions $opt] != -1} then {
951 set data [string trimright [string trimleft [string range $line [string first : $line] end] " \t:"] " \t\\"]
952 if {![info exists $opt]} then {
953 set $opt $data
954 } else {
955 append $opt " $data"
956 }
957 }
958 if {[regexp -- \\\\$ $line]} then {
959 set continuedLine 1
960 } else {
961 set continuedLine 0
962 }
963 } elseif {($continuedLine) && ([info exists opt])} then {
964 append $opt " [string trimright [string trimleft $line " \t#"] " \t\\"]"
965 if {![regexp -- \\\\$ $line]} then {
966 set continuedLine 0
967 }
968 }
969 }
970 close $fd
971 if {(![string compare "" $args]) && \
972 ((![info exists name]) || \
973 ([catch {set md5sum [md5Sum $file]}]))} then {
974 return
975 }
976 foreach option $formatOptions {
977 if {(![info exists $option]) || \
978 (![string compare "" [set $option]])} then {
979 set $option [dataFormatDefault $moduleDatabaseConfig(defaults) $option]
980 }
981 lappend ret [set $option]
982 }
983 return $ret
984 }
985 }
986
987 ##
988 ## Get data from module db data array
989 ##
990 ## Args: module name, data type
991 ## Returns: data for the given module's data type if it exists,
992 ## nothing otherwise
993 ##
994 proc getModuleDatabaseData {module type} {
995 variable moduleDatabaseConfig
996 variable moduleDatabaseFormat
997 variable moduleDatabaseData
998
999 if {[moduleExists $module]} then {
1000 set index [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] $type]
1001 if {$index != -1} then {
1002 return [lindex $moduleDatabaseData($module) $index]
1003 }
1004 }
1005 return
1006 }
1007
1008 ##
1009 ## Set data in module db data array
1010 ##
1011 ## Args: module name, data type, data
1012 ## Returns: 1 if valid module and data type,
1013 ## 0 otherwise
1014 ##
1015 proc setModuleDatabaseData {module type data} {
1016 variable moduleDatabaseConfig
1017 variable moduleDatabaseFormat
1018 variable moduleDatabaseData
1019 variable moduleDatabaseDataChanged
1020
1021 if {[moduleExists $module]} then {
1022 set index [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] $type]
1023 if {$index != -1} then {
1024 set moduleDatabaseData($module) [lreplace $moduleDatabaseData($module) $index $index [list $data]]
1025 set moduleDatabaseDataChanged 1
1026 return 1
1027 }
1028 }
1029 return 0
1030 }
1031
1032 ##
1033 ## Save module database
1034 ##
1035 ## Args: verbose {-1,0,1}
1036 ## Returns: 1 if successful,
1037 ## 0 otherwise
1038 ##
1039 proc saveModuleDatabase {{verbose 0}} {
1040 variable configData
1041 variable moduleDatabaseConfig
1042 variable moduleDatabaseData
1043 variable moduleDatabaseDataChanged
1044
1045 if {[createFile $configData(moddbfile) $verbose "module database file "]} then {
1046 if {[catch {set fd [open $configData(moddbfile) w]} result]} then {
1047 if {$verbose >= 0} then {
1048 wpLog o * "Error: unable to open module database file `$configData(moddbfile)' for writing: $result"
1049 }
1050 } else {
1051 puts $fd "# $moduleDatabaseConfig(header)$moduleDatabaseConfig(version)"
1052 close $fd
1053 set ret [arraySave moduleDatabaseData $configData(moddbfile) $verbose "module database file " a]
1054 if {$ret} then {
1055 set moduleDatabaseDataChanged 0
1056 }
1057 return $ret
1058 }
1059 }
1060 return 0
1061 }
1062
1063 ##
1064 ## Load module database
1065 ##
1066 ## Args: verbose {-1,0,1}
1067 ## Returns: 1 if successful,
1068 ## 0 otherwise
1069 ##
1070 proc loadModuleDatabase {{verbose 0}} {
1071 variable configData
1072 variable moduleDatabaseConfig
1073 variable moduleDatabaseFormat
1074 variable moduleDatabaseData
1075 variable moduleDatabaseDataChanged
1076
1077 if {![file exists $configData(moddbfile)]} then {
1078 return -1
1079 } else {
1080 if {[catch {set fd [open $configData(moddbfile) r]} result]} then {
1081 if {$verbose >= 0} then {
1082 wpLog o * "Error: unable to open module database file `$configData(moddbfile)' for reading: $result"
1083 }
1084 } else {
1085 set firstline [replaceExpr [gets $fd] "^ "]
1086 if {[regexp -- "^# $moduleDatabaseConfig(header)" $firstline]} then {
1087 regsub -all -- "^# $moduleDatabaseConfig(header)" $firstline "" version
1088 if {![string compare [set version [string trim $version]] $moduleDatabaseConfig(version)]} then {
1089 close $fd
1090 return [arrayLoad moduleDatabaseData $configData(moddbfile) $verbose "module database file "]
1091 } elseif {[info exists moduleDatabaseFormat($version)]} then {
1092 if {[info exists moduleDatabaseData]} then {
1093 unset moduleDatabaseData
1094 }
1095 while {![eof $fd]} {
1096 set line [replaceExpr [gets $fd] "^ "]
1097 if {([string compare "" $line]) && \
1098 (![regexp -- "^#" $line])} then {
1099 set moduleDatabaseData([lindex $line 0]) [dataFormatConvert [join $moduleDatabaseFormat($version)] [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] [lindex $line 1]]
1100 }
1101 }
1102 close $fd
1103 set moduleDatabaseDataChanged 0
1104 return 1
1105 } else {
1106 wpLog o * "Error: unknown module database version: $version"
1107 }
1108 } else {
1109 wpLog o * "Error: unknown module database format: [string trimleft $firstline " \t#"]"
1110 }
1111 }
1112 close $fd
1113 }
1114 return 0
1115 }
1116
1117 ##
1118 ## Compare loaded module database data to module files
1119 ##
1120 ## Args: verbose {-1,0,1}
1121 ## Returns: 1 if data matches,
1122 ## 0 otherwise
1123 ##
1124 proc compareModuleDatabase {{verbose 0}} {
1125 variable configData
1126 variable moduleDatabaseConfig
1127
1128 foreach path $configData(modulepath) {
1129 set files [findFiles $path $moduleDatabaseConfig(maxdepth) .tcl]
1130 if {[string compare "" $files]} then {
1131 set comparedModules ""
1132 set moduleList [listModules]
1133 # Return early if we don't have any modules listed in the db
1134 if {![string compare "" $moduleList]} then {
1135 return 0
1136 }
1137 foreach file $files {
1138 set shortfile [string trimleft [string range $file [string length $path] end] /]
1139 if {$verbose >= 1} then {
1140 wpLog o * "Comparing file `$shortfile'"
1141 }
1142 if {[catch {set name [lindex [scanModule $file name] 0]} result]} then {
1143 if {$verbose >= 0} then {
1144 wpLog o * "Error: unable to open file `$shortfile' for reading: $result"
1145 }
1146 }
1147 # Process this file if it's a module
1148 if {[string compare "" $name]} then {
1149 # Get module filename from db
1150 set filename [getModuleDatabaseData $name file]
1151 # Compare module filename and make sure it wasn't renamed or moved
1152 if {[string compare $file $filename]} then {
1153 return 0
1154 }
1155 # Compare md5 from module db and sure the module hasn't changed
1156 if {([catch {set md5sum [md5Sum $filename]}]) || \
1157 ([string compare [getModuleDatabaseData $name md5sum] $md5sum])} then {
1158 return 0
1159 }
1160 # Append module name to list of compared modules
1161 lappend comparedModules $name
1162 }
1163 }
1164 # Compare list of compared modules with list of modules from the db
1165 if {[string compare [lsort $comparedModules] $moduleList]} then {
1166 return 0
1167 }
1168 }
1169 }
1170 return 1
1171 }
1172
1173 ##
1174 ## Rebuild module database
1175 ##
1176 ## Args: verbose {-1,0,1}
1177 ## Returns: nothing
1178 ##
1179 proc rebuildModuleDatabase {{verbose 0}} {
1180 variable configData
1181 variable moduleDatabaseConfig
1182 variable moduleDatabaseFormat
1183 variable moduleDatabaseData
1184
1185 foreach path $configData(modulepath) {
1186 set files [findFiles $path $moduleDatabaseConfig(maxdepth) .tcl]
1187 set loadIndex [lsearch -exact [join $moduleDatabaseFormat([set moduleDatabaseConfig(version)])] load]
1188 foreach file $files {
1189 set shortfile [string trimleft [string range $file [string length $path] end] /]
1190 if {$verbose >= 1} then {
1191 wpLog o * "Scanning file `$shortfile'"
1192 }
1193 if {[catch {set data [scanModule $file]} result]} then {
1194 if {$verbose >= 0} then {
1195 wpLog o * "Warning: unable to open file `$shortfile' for reading: $result"
1196 }
1197 } else {
1198 set name [lindex $data 0]
1199 if {[string compare "" $name]} then {
1200 if {[moduleExists $name]} then {
1201 set tmp($name) [lreplace [lrange $data 1 end] $loadIndex $loadIndex [lindex $moduleDatabaseData($name) $loadIndex]]
1202 } else {
1203 set tmp($name) [lrange $data 1 end]
1204 }
1205 }
1206 }
1207 }
1208 }
1209 if {[info exists moduleDatabaseData]} then {
1210 unset moduleDatabaseData
1211 }
1212 if {[info exists tmp]} then {
1213 array set moduleDatabaseData [array get tmp]
1214 }
1215 return
1216 }
1217
1218 ##
1219 ## List all modules in the database
1220 ##
1221 ## Args: none
1222 ## Returns: list of modules in module database
1223 ##
1224 proc listModules {{loaded 0}} {
1225 variable moduleDatabaseData
1226 variable moduleLoadedList
1227
1228 if {$loaded} then {
1229 return [lsort $moduleLoadedList]
1230 }
1231 return [lsort [array names moduleDatabaseData]]
1232 }
1233
1234 ##
1235 ## Check if the given module exists
1236 ##
1237 ## Args: module name
1238 ## Returns: 1 if the given module exists
1239 ## 0 otherwise
1240 ##
1241 proc moduleExists {module} {
1242 variable moduleDatabaseData
1243
1244 if {[info exists moduleDatabaseData($module)]} then {
1245 return 1
1246 }
1247 return 0
1248 }
1249
1250 ##
1251 ## Check if a module is loaded
1252 ##
1253 ## Args: module name
1254 ## Returns: 1 if the given module is loaded
1255 ## 0 otherwise
1256 ##
1257 proc moduleLoaded {module} {
1258 variable moduleLoadedList
1259
1260 if {[lsearch -exact $moduleLoadedList $module] != -1} then {
1261 return 1
1262 }
1263 return 0
1264 }
1265
1266 ##
1267 ## Add/remove bindings for a given module
1268 ##
1269 ## Args: mode {bind|unbind}, module,
1270 ## args {{type ...} {option ...} {regsub ... ...}}
1271 ## Returns: nothing
1272 ##
1273 proc moduleBindUnbind {mode module args} {
1274 variable NamespaceCurrent
1275
1276 if {[info exists ${NamespaceCurrent}::${module}::bindDefaults]} then {
1277 set bindtypes ""
1278 set bindoptions ""
1279 foreach option $args {
1280 switch -exact -- [lindex $option 0] {
1281 type {
1282 # dcc msg pub ...
1283 foreach opt [lrange $option 1 end] {
1284 lappend bindtypes $opt
1285 }
1286 }
1287 option {
1288 # commandchar noauto ...
1289 foreach opt [lrange $option 1 end] {
1290 lappend bindoptions $opt
1291 }
1292 }
1293 regsub {
1294 # replace regexp 'replacewhat' with 'replacewith'
1295 foreach opt [lrange $option 1 end] {
1296 foreach {rwhat rwith} $opt {break}
1297 set replace($rwhat) $rwith
1298 }
1299 }
1300 }
1301 }
1302 foreach {proc data} [array get ${NamespaceCurrent}::${module}::bindDefaults] {
1303 foreach bind $data {
1304 foreach {type flags mask options help} $bind {break}
1305 if {([string compare "" $bindtypes]) && \
1306 ([lsearch -exact $bindtypes $type] == -1)} then {
1307 continue
1308 }
1309 if {([string compare "" $bindoptions]) && \
1310 ([lsearch -exact $bindoptions $option] == -1)} then {
1311 continue
1312 }
1313 if {[lsearch -exact $options commandchar] != -1} then {
1314 set mask "[commandChar pub]$mask"
1315 }
1316 if {[array exists replace]} then {
1317 foreach {replacewhat replacewith} [array get replace] {
1318 regsub -all -- $replacewhat $mask $replacewith mask
1319 }
1320 }
1321 # bind/unbind
1322 $mode $type $flags $mask ${NamespaceCurrent}::${module}::$proc
1323 }
1324 }
1325 }
1326 return
1327 }
1328
1329 ##
1330 ## Load a module
1331 ##
1332 ## Args: module name, verbose {-1,0,1}, args {loop detection}
1333 ## Returns: nothing
1334 ## Errors: if unable to load module
1335 ##
1336 proc moduleLoad {module {verbose 0} args} {
1337 variable NamespaceCurrent
1338 variable moduleLoadedList
1339
1340 if {[lsearch -exact [set loop [lindex $args 0]] $module] == -1} then {
1341 if {[moduleExists $module]} then {
1342 set preload ""
1343 set requires [getModuleDatabaseData $module requires]
1344 foreach required $requires {
1345 set preloadModule [whichModuleCommand $required]
1346 if {[string compare "" $preloadModule]} then {
1347 if {([lsearch -exact $preload $preloadModule] == -1) && \
1348 ([string compare wp $preloadModule]) && \
1349 (![moduleLoaded $preloadModule])} then {
1350 lappend preload $preloadModule
1351 }
1352 } else {
1353 error "required command `$required' not found."
1354 }
1355 }
1356 if {[string compare "" $preload]} then {
1357 foreach premod $preload {
1358 if {[catch {moduleLoad $premod $verbose [concat $loop $module]} result]} then {
1359 error $result
1360 }
1361 }
1362 }
1363 if {[catch {source [getModuleDatabaseData $module file]} result]} then {
1364 error $result
1365 } else {
1366 package forget $module
1367 package provide ${NamespaceCurrent}::${module} [getModuleDatabaseData $module version]
1368 moduleConfigLoad $module 1
1369 moduleConfigCheckdefs $module 1
1370 moduleDataLoad $module 1
1371 # Imported commands '# requires: ...'
1372 if {[string compare "" $requires]} then {
1373 set Eval "namespace eval ${NamespaceCurrent}::${module} \{\n namespace forget *\n namespace import"
1374 foreach required $requires {
1375 if {[string compare "" [set command [whichCommand $required]]]} then {
1376 append Eval " $command"
1377 }
1378 }
1379 append Eval "\n\}"
1380 eval $Eval
1381 }
1382 # Exported commands '# provides: ...'
1383 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
1384 set Eval "namespace eval ${NamespaceCurrent}::${module} \{\n namespace export"
1385 foreach provided $provides {
1386 append Eval " $provided"
1387 }
1388 append Eval "\n\}"
1389 eval $Eval
1390 }
1391 if {[string compare "" [info commands ${NamespaceCurrent}::${module}::ModuleInit]]} then {
1392 ${NamespaceCurrent}::${module}::ModuleInit
1393 }
1394 # FIXME: check for bindings? duplicates?
1395 moduleBindUnbind bind $module
1396 if {![getModuleDatabaseData $module load]} then {
1397 setModuleDatabaseData $module load 1
1398 }
1399 if {[lsearch -exact $moduleLoadedList $module] == -1} then {
1400 lappend moduleLoadedList $module
1401 if {$verbose >= 1} then {
1402 wpLog o * "Module loaded: $module"
1403 }
1404 }
1405 }
1406 } else {
1407 error "No such module: $module"
1408 }
1409 } else {
1410 regsub -all -- " " $loop " -> " loop
1411 error "Preload endless loop: $loop -> $module"
1412 }
1413 return
1414 }
1415
1416 ##
1417 ## Unload a module
1418 ##
1419 ## Args: module name, verbose {-1,0,1}
1420 ## Returns: nothing
1421 ## Errors: if unable to completely unload module
1422 ##
1423 proc moduleUnload {module {verbose 0}} {
1424 variable NamespaceCurrent
1425 variable moduleLoadedList
1426
1427 # FIXME: handle dependant modules and modules that can't be unloaded
1428 if {[moduleExists $module]} then {
1429 if {[string compare "" [info commands ${NamespaceCurrent}::${module}::ModuleDestroy]]} then {
1430 ${NamespaceCurrent}::${module}::ModuleDestroy
1431 }
1432 # FIXME: check for bindings?
1433 moduleBindUnbind unbind $module
1434 moduleConfigSave $module 1
1435 moduleDataSave $module 1
1436 if {[catch {namespace delete ${NamespaceCurrent}::${module}} result]} then {
1437 error $result
1438 } else {
1439 package forget ${NamespaceCurrent}::${module}
1440 if {[getModuleDatabaseData $module load] == 1} then {
1441 setModuleDatabaseData $module load 0
1442 }
1443 set index [lsearch -exact $moduleLoadedList $module]
1444 if {$index != -1} then {
1445 set moduleLoadedList [lreplace $moduleLoadedList $index $index]
1446 if {$verbose >= 1} then {
1447 wpLog o * "Module unloaded: $module"
1448 }
1449 }
1450 }
1451 } else {
1452 error "No such module: $module"
1453 }
1454 return
1455 }
1456
1457 ##
1458 ## Save configuration settings for the given module
1459 ##
1460 ## Args: module, force {0,1}, verbose {-1,0,1}
1461 ## Returns: 1 if settings saved
1462 ## 0 otherwise
1463 ##
1464 proc moduleConfigSave {module {force 0} {verbose 0}} {
1465 variable NamespaceCurrent
1466 variable configData
1467
1468 if {([string compare "" \
1469 [set file [getModuleDatabaseData $module config]]]) && \
1470 ([createDir $configData(configpath)])} then {
1471 set cfgfile [file join $configData(configpath) $file]
1472 if {([getModuleDatabaseData $module load]) && \
1473 (($force) || \
1474 (![info exists ${NamespaceCurrent}::${module}::configDataChanged]) || \
1475 ([set ${NamespaceCurrent}::${module}::configDataChanged]))} then {
1476 if {[arraySave ${NamespaceCurrent}::${module}::configData $cfgfile 0 "$module configuration file "]} then {
1477 if {$verbose >= 1} then {
1478 wpLog o * "Writing $module config file..."
1479 }
1480 set ${NamespaceCurrent}::${module}::configDataChanged 0
1481 return 1
1482 } elseif {$verbose >= 0} then {
1483 wpLog o * "Error writing $module config file."
1484 }
1485 }
1486 }
1487 return 0
1488 }
1489
1490 ##
1491 ## Load configuration settings for the given module
1492 ##
1493 ## Args: module, force {0,1}, verbose {-1,0,1}
1494 ## Returns: 1 if settings loaded
1495 ## 0 otherwise
1496 ##
1497 proc moduleConfigLoad {module {force 0} {verbose 0}} {
1498 variable NamespaceCurrent
1499 variable configData
1500
1501 if {([string compare "" \
1502 [set file [getModuleDatabaseData $module config]]]) && \
1503 ([createDir $configData(configpath)])} then {
1504 set cfgfile [file join $configData(configpath) $file]
1505 if {($force) || \
1506 (![info exists ${NamespaceCurrent}::${module}::configDataChanged]) || \
1507 (![set ${NamespaceCurrent}::${module}::configDataChanged])} then {
1508 if {[arrayLoad ${NamespaceCurrent}::${module}::configData $cfgfile 0 "$module configuration file "]} then {
1509 if {$verbose >= 1} then {
1510 wpLog o * "Loading $module config file..."
1511 }
1512 set ${NamespaceCurrent}::${module}::configDataChanged 0
1513 return 1
1514 } elseif {$verbose >= 0} then {
1515 wpLog o * "Error loading $module config file."
1516 }
1517 }
1518 }
1519 return 0
1520 }
1521
1522 ##
1523 ## Check and set default configuration settings for the given module
1524 ##
1525 ## Args: module, force {0,1}, verbose {-1,0,1}
1526 ## Returns: nothing
1527 ##
1528 proc moduleConfigCheckdefs {module {force 0} {verbose 0}} {
1529 variable NamespaceCurrent
1530
1531 if {([array exists ${NamespaceCurrent}::${module}::configDefaults]) && \
1532 ([string compare "" [getModuleDatabaseData $module config]])} then {
1533 set Changed 0
1534 # Unset unknown variables
1535 foreach name [array names ${NamespaceCurrent}::${module}::configData] {
1536 if {![info exists ${NamespaceCurrent}::${module}::configDefaults($name)]} then {
1537 unset ${NamespaceCurrent}::${module}::configData($name)
1538 set Changed 1
1539 }
1540 }
1541 # Set missing variables to defaults
1542 foreach {name data} [array get ${NamespaceCurrent}::${module}::configDefaults] {
1543 if {![info exists ${NamespaceCurrent}::${module}::configData($name)]} then {
1544 set ${NamespaceCurrent}::${module}::configData($name) [lindex $data 1]
1545 set Changed 1
1546 }
1547 }
1548 # FIXME: do this with a trace?
1549 if {$Changed} then {
1550 set ${NamespaceCurrent}::${module}::configDataChanged 1
1551 }
1552 }
1553 return
1554 }
1555
1556 ##
1557 ## Handle config data for a list of modules
1558 ##
1559 ## Args: action {load|save|checkdefs}, module list, force {0,1},
1560 ## verbose {-1,0,1}
1561 ## Returns: nothing
1562 ##
1563 proc moduleConfig {action modules {force 0} {verbose 0}} {
1564 if {![string compare * $modules]} then {
1565 set modules [listModules 1]
1566 }
1567 switch -exact -- $action {
1568 save {
1569 foreach module $modules {
1570 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1571 moduleConfigSave $module $force $verbose
1572 }
1573 }
1574 }
1575 load {
1576 foreach module $modules {
1577 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1578 moduleConfigLoad $module $force $verbose
1579 }
1580 }
1581 }
1582 checkdefs {
1583 foreach module $modules {
1584 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1585 moduleConfigCheckdefs $module $force $verbose
1586 }
1587 }
1588 }
1589 }
1590 return
1591 }
1592
1593 ##
1594 ## Save data for the given module
1595 ##
1596 ## Args: module, force {0,1}, verbose {-1,0,1}
1597 ## Returns: nothing
1598 ##
1599 proc moduleDataSave {module {force 0} {verbose 0}} {
1600 variable NamespaceCurrent
1601 variable configData
1602
1603 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1604 ([createDir $configData(datapath)])} then {
1605 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1606 foreach {type file desc} $data {break}
1607 if {([info exists type]) && ([info exists file]) && \
1608 ([info exists desc])} then {
1609 set Changed ${NamespaceCurrent}::${module}::${name}Changed
1610 if {($force) || ((![info exists $Changed]) || ([set $Changed]))} then {
1611 if {[${type}Save ${NamespaceCurrent}::${module}::$name [file join $configData(datapath) $file]]} then {
1612 if {$verbose >= 1} then {
1613 wpLog o * $NamespaceCurrent "Writing $desc data file..."
1614 }
1615 set $Changed 0
1616 } elseif {$verbose >= 0} then {
1617 wpLog o * $NamespaceCurrent "Error writing $desc data file!"
1618 }
1619 }
1620 }
1621 }
1622 }
1623 return
1624 }
1625
1626 ##
1627 ## Load data for the given module
1628 ##
1629 ## Args: module, force {0,1}, verbose {-1,0,1}
1630 ## Returns: nothing
1631 ##
1632 proc moduleDataLoad {module {force 0} {verbose 0}} {
1633 variable NamespaceCurrent
1634 variable configData
1635
1636 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1637 ([createDir $configData(datapath)])} then {
1638 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1639 foreach {type file desc} $data {break}
1640 if {([info exists type]) && ([info exists file]) && \
1641 ([info exists desc])} then {
1642 set Changed ${NamespaceCurrent}::${module}::${name}Changed
1643 if {($force) || ((![info exists $Changed]) || ([set $Changed]))} then {
1644 if {[${type}Load ${NamespaceCurrent}::${module}::$name [file join $configData(datapath) $file]]} then {
1645 if {$verbose >= 1} then {
1646 wpLog o * $NamespaceCurrent "Reloading $desc data file..."
1647 }
1648 set $Changed 0
1649 } elseif {$verbose >= 0} then {
1650 wpLog o * $NamespaceCurrent "Error reloading $desc data file!"
1651 }
1652 }
1653 }
1654 }
1655 }
1656 return
1657 }
1658
1659 ##
1660 ## Backup data for the given module
1661 ##
1662 ## Args: module, force {0,1}, verbose {-1,0,1}
1663 ## Returns: nothing
1664 ##
1665 proc moduleDataBackup {module {force 0} {verbose 0}} {
1666 variable NamespaceCurrent
1667 variable configData
1668
1669 if {([info exists ${NamespaceCurrent}::${module}::dataOptions]) && \
1670 ([createDir $configData(datapath)])} then {
1671 foreach {name data} [array get ${NamespaceCurrent}::${module}::dataOptions] {
1672 foreach {type file desc} $data {break}
1673 if {([info exists type]) && ([info exists file]) && \
1674 ([info exists desc])} then {
1675 if {[set result [backupFile [file join $configData(datapath) $file] $verbose]]} then {
1676 if {($result >= 1) && ($verbose >= 1)} then {
1677 wpLog o * $NamespaceCurrent "Backing up $desc data file..."
1678 }
1679 } elseif {$verbose >= 0} then {
1680 wpLog o * $NamespaceCurrent "Error backing up $desc data file!"
1681 }
1682 }
1683 }
1684 }
1685 return
1686 }
1687
1688 ##
1689 ## Handle data for a list of modules
1690 ##
1691 ## Args: action {load|save|backup}, module list, force {0,1},
1692 ## verbose {-1,0,1}
1693 ## Returns: nothing
1694 ##
1695 proc moduleData {action modules {force 0} {verbose 0}} {
1696 if {![string compare * $modules]} then {
1697 set modules [listModules 1]
1698 }
1699 switch -exact -- $action {
1700 save {
1701 foreach module $modules {
1702 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1703 moduleDataSave $module $force $verbose
1704 }
1705 }
1706 }
1707 load {
1708 foreach module $modules {
1709 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1710 moduleDataLoad $module $force $verbose
1711 }
1712 }
1713 }
1714 backup {
1715 foreach module $modules {
1716 if {([moduleExists $module]) && ([moduleLoaded $module])} then {
1717 moduleDataBackup $module $force $verbose
1718 }
1719 }
1720 }
1721 }
1722 return
1723 }
1724
1725 ##
1726 ## Builds command matching table from module database
1727 ##
1728 ## Args: none
1729 ## Returns: nothing
1730 ##
1731 proc buildCommandTable {{verbose 0}} {
1732 variable NamespaceCurrent
1733 variable ExportList
1734 variable commandTable
1735
1736 foreach command $ExportList {
1737 if {![info exists tmp($command)]} then {
1738 if {$verbose >= 2} then {
1739 wpLog o * "Adding command: `$command' as `${NamespaceCurrent}::$command'"
1740 }
1741 set tmp($command) ${NamespaceCurrent}::$command
1742 } elseif {$verbose >= 0} then {
1743 wpLog o * "Warning: ignoring duplicate command `$command', conflicts with `$tmp($command)'"
1744 }
1745 }
1746 foreach module [listModules] {
1747 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
1748 foreach command $provides {
1749 if {![info exists tmp($command)]} then {
1750 if {$verbose >= 2} then {
1751 wpLog o * "Adding command: `$command' as `${NamespaceCurrent}::${module}::$command'"
1752 }
1753 set tmp($command) ${NamespaceCurrent}::${module}::$command
1754 } elseif {$verbose >= 0} then {
1755 wpLog o * "Warning: ignoring duplicate command `$command', conflicts with `$tmp($command)'"
1756 }
1757 }
1758 }
1759 }
1760 if {[info exists commandTable]} then {
1761 unset commandTable
1762 }
1763 array set commandTable [array get tmp]
1764 return
1765 }
1766
1767 ##
1768 ## Return full namespace path for the given command
1769 ##
1770 ## Args: command
1771 ## Returns: full namespace path for the given command if it exists
1772 ## nothing otherwise
1773 ##
1774 proc whichCommand {command} {
1775 variable commandTable
1776
1777 if {[info exists commandTable($command)]} then {
1778 return $commandTable($command)
1779 }
1780 return
1781 }
1782
1783 ##
1784 ## Return full namespace path for the given module
1785 ##
1786 ## Args: module
1787 ## Returns: full namespace path for the given module if it's loaded
1788 ## nothing otherwise
1789 ##
1790 proc whichModule {module} {
1791 variable NamespaceCurrent
1792
1793 if {![string compare $module [namespace tail $NamespaceCurrent] $module]} then {
1794 return $NamespaceCurrent
1795 } elseif {[moduleLoaded $module]} then {
1796 return ${NamespaceCurrent}::$module
1797 }
1798 return
1799 }
1800
1801 ##
1802 ## Return module name that provides the given command
1803 ##
1804 ## Args: command
1805 ## Returns: name of module that provides the given command
1806 ## nothing otherwise
1807 ##
1808 proc whichModuleCommand {command} {
1809 variable NamespaceCurrent
1810 variable commandTable
1811
1812 if {[info exists commandTable($command)]} then {
1813 if {![string compare ${NamespaceCurrent}::$command \
1814 $commandTable($command)]} then {
1815 return [namespace tail $NamespaceCurrent]
1816 }
1817 return [namespace tail [namespace qualifiers $commandTable($command)]]
1818 }
1819 return
1820 }
1821
1822 ##
1823 ## Compare the given version to eggdrop's version
1824 ##
1825 ## Args: version
1826 ## Returns: 0 if eggdrop's version is older then the given version
1827 ## 1 if eggdrop's version matches the given version
1828 ## 2 if eggdrop's version is newer then the given version
1829 ##
1830 proc compareVersion {version} {
1831 global numversion
1832
1833 if {[string compare "" $version]} then {
1834 if {([info exists numversion]) || \
1835 (![catch {set numversion}]) || \
1836 ([info exists numversion])} then {
1837 if {[regexp -- \\. $version]} then {
1838 regsub -all -- \\. $version 0 version
1839 set version ${version}00
1840 }
1841 if {![regexp -- \[^0-9\] $version]} then {
1842 if {$numversion > $version} then {
1843 return 2
1844 } elseif {$numversion == $version} then {
1845 return 1
1846 }
1847 }
1848 }
1849 }
1850 return 0
1851 }
1852
1853 ##
1854 ## Log module information
1855 ##
1856 ## Args: level, channel, args ({<namespace>} {<text>} | {<text>})
1857 ## Returns: nothing
1858 ##
1859 proc wpLog {level channel args} {
1860 if {[llength $args] == 2} then {
1861 if {[string compare wp [set namespace [namespace tail [lindex $args 0]]]]} then {
1862 putloglev $level $channel "Wolfpack: \[$namespace\] [lindex $args 1]"
1863 } else {
1864 putloglev $level $channel "Wolfpack: [lindex $args 1]"
1865 }
1866 } else {
1867 putloglev $level $channel "Wolfpack: [join $args]"
1868 }
1869 return
1870 }
1871
1872 ##
1873 ## Trace configuration changes
1874 ##
1875 ## Args: name1, name2, operation
1876 ## Returns: nothing
1877 ##
1878 proc TraceConfigData {name1 name2 op} {
1879 variable configData
1880 variable oldConfigData
1881
1882 if {[string compare $oldConfigData($name2) $configData($name2)]} then {
1883 switch -exact -- $name2 {
1884 commandchar {
1885 foreach module [listModules 1] {
1886 moduleBindUnbind unbind $module "type pub" "option commandchar" "regsub {^ $oldConfigData(commandchar)}"
1887 moduleBindUnbind bind $module "type pub" "option commandchar"
1888 }
1889 }
1890 }
1891 set oldConfigData($name2) $configData($name2)
1892 }
1893 return
1894 }
1895
1896 ##
1897 ## Evaluate command line arguments
1898 ##
1899 ## Args: none
1900 ## Returns: nothing
1901 ##
1902 proc EvalArgs {argc argv argv0} {
1903 variable NamespaceCurrent
1904 variable optionData
1905
1906 # Make sure defaults are sane
1907 arraySetAll optionData 0
1908 for {set index 0} {$index < $argc} {incr index} {
1909 set option [lindex $argv $index]
1910 switch -regexp -- $option {
1911 (^--config$) {
1912 set optionData(config) 1
1913 }
1914 (^--rebuild$) {
1915 set optionData(rebuild) 1
1916 }
1917 (^--norebuild$) {
1918 set optionData(norebuild) 1
1919 }
1920 (^--time$) {
1921 set optionData(time) 1
1922 }
1923 (^--verbose$) {
1924 incr optionData(verbose)
1925 }
1926 (^--quiet$) {
1927 incr optionData(quiet) -1
1928 }
1929 (^--debug$) {
1930 set optionData(debug) 1
1931 }
1932 (^--help$) {
1933 ShowUsage $argv0
1934 exit
1935 }
1936 (^--version$) {
1937 puts "[file tail $argv0] version [package require ${NamespaceCurrent}]"
1938 exit
1939 }
1940 (^-\[^-\]*$) {
1941 set suboptions [split $option ""]
1942 set sublength [llength [split $suboptions]]
1943 for {set subindex 0} {$subindex < $sublength} {incr subindex} {
1944 set suboption [lindex $suboptions $subindex]
1945 switch -exact -- $suboption {
1946 - {
1947 continue
1948 }
1949 c {
1950 set optionData(config) 1
1951 }
1952 r {
1953 set optionData(rebuild) 1
1954 }
1955 n {
1956 set optionData(norebuild) 1
1957 }
1958 t {
1959 set optionData(time) 1
1960 }
1961 v {
1962 incr optionData(verbose)
1963 }
1964 q {
1965 incr optionData(quiet) -1
1966 }
1967 d {
1968 set optionData(debug) 1
1969 }
1970 default {
1971 if {(![info exists invalidopt]) || \
1972 ($subindex == 1) || \
1973 ([lsearch -exact $invalidopt $option] == -1)} then {
1974 lappend invalidopt $option
1975 }
1976 }
1977 }
1978 }
1979 }
1980 default {
1981 lappend invalidopt $option
1982 }
1983 }
1984 }
1985
1986 # complain about invalid command line arguments
1987 if {[info exists invalidopt]} then {
1988 foreach option $invalidopt {
1989 puts stderr "[file tail $argv0]: unrecognized option `$option'"
1990 }
1991 exit 1
1992 }
1993 }
1994
1995 ##
1996 ## Show usage information
1997 ##
1998 ## Args: none
1999 ## Returns: nothing
2000 ##
2001 proc ShowUsage {argv0} {
2002 # FIXME: code missing options
2003 puts "Usage: [file tail $argv0] <options>"
2004 puts " Valid options:"
2005 puts " -c, --config start interactive configuration"
2006 #puts " -u, --update update module database"
2007 puts " -r, --rebuild force rebuild of module database"
2008 puts " -n, --norebuild don't rebuild module database even if it's outdated"
2009 puts " -t, --time time compare and rebuild of module database"
2010 #puts " -i, --include <mod> include `module' when building database"
2011 #puts " -e, --exclude <mod> exclude `module' when building database"
2012 #puts " -m, --module <mod> only update database for `module'"
2013 puts " -v, --verbose use more than once for more verbose operation"
2014 puts " -q, --quiet use more than once for quieter operation"
2015 puts " -d, --debug start in debug mode with tclsh"
2016 puts " --help show this help"
2017 puts " --version show version information"
2018 }
2019
2020 ##
2021 ## Enter interactive configuration
2022 ##
2023 ## Args: none
2024 ## Returns: nothing
2025 ##
2026 proc Iconfig {} {
2027 variable NamespaceCurrent
2028 variable IconfigDefaults
2029
2030 fileevent stdin readable ${NamespaceCurrent}::IconfigReadStdin
2031 puts "Entering wolfpack configuration system..."
2032 puts "Type 'help' for help."
2033 puts -nonewline $IconfigDefaults(prompt)
2034 flush stdout
2035 vwait forever
2036 }
2037
2038 ##
2039 ## Read stdin and process commands
2040 ##
2041 ## Args: none
2042 ## Returns: nothing
2043 ##
2044 # FIXME: readline-like support?
2045 proc IconfigReadStdin {} {
2046 variable IconfigDefaults
2047 variable configData
2048
2049 set exit 0
2050 if {[eof stdin]} {
2051 set exit 1
2052 }
2053 set stdin [string trimright [gets stdin]]
2054 set data [join [lrange [split $stdin] 1 end]]
2055 if {[string compare "" $stdin]} then {
2056 switch -exact -- [lindex [split $stdin] 0] {
2057 set {
2058 IconfigSet $data
2059 }
2060 enable {
2061 IconfigEnable $data
2062 }
2063 disable {
2064 IconfigDisable $data
2065 }
2066 modules {
2067 IconfigModules $data
2068 }
2069 info {
2070 IconfigInfo $data
2071 }
2072 help {
2073 IconfigHelp $data
2074 }
2075 quit {
2076 set exit 1
2077 }
2078 default {
2079 puts "What? You need 'help'"
2080 }
2081 }
2082 }
2083 if {(!$exit) && (![eof stdin])} then {
2084 puts -nonewline $IconfigDefaults(prompt)
2085 flush stdout
2086 } else {
2087 # Save configuration data
2088 arraySave configData $IconfigDefaults(cfgfile) 0 "configuration file "
2089 # Save module database
2090 saveModuleDatabase
2091 puts ""
2092 flush stdout
2093 exit
2094 }
2095 return
2096 }
2097
2098 ##
2099 ## Set configuration settings
2100 ##
2101 ## Args: data
2102 ## Returns: nothing
2103 ##
2104 proc IconfigSet {data} {
2105 variable configData
2106 variable configDefaults
2107
2108 if {![string compare "" $data]} then {
2109 set fmtlen1 [arrayMaxElementDataLength configDefaults 3]
2110 if {$fmtlen1 < 13} then {
2111 set fmtlen1 13 ;# 'Description: '
2112 }
2113 set names [array names configData]
2114 set fmtlen2 [listMaxElementLength $names]
2115 if {$fmtlen2 < 8} then {
2116 set fmtlen2 8 ;# 'Option: '
2117 }
2118 puts ""
2119 puts "Current settings:"
2120 puts ""
2121 # FIXME: this needs improvement
2122 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" Description: Option: Value:]
2123 foreach option [lsort $names] {
2124 if {[info exists configDefaults($option)]} then {
2125 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" [lindex $configDefaults($option) 3] $option $configData($option)]
2126 } else {
2127 puts [format " %-${fmtlen1}s %-${fmtlen2}s %s" "" $option $configData($option)]
2128 }
2129 }
2130 puts ""
2131 } else {
2132 set option [lindex [split $data] 0]
2133 if {![info exists configData($option)]} then {
2134 puts "Invalid option: $option"
2135 } else {
2136 set value [join [lrange [split $data] 1 end]]
2137 if {![string compare "" $value]} then {
2138 puts "Currently: $configData($option)"
2139 } else {
2140 set configData($option) $value
2141 puts "Set $option to: $value"
2142 }
2143 }
2144 }
2145 return
2146 }
2147
2148 ##
2149 ## Enable a module
2150 ##
2151 ## Args: data
2152 ## Returns: nothing
2153 ##
2154 proc IconfigEnable {data} {
2155 set module [lindex [split $data] 0]
2156 if {![string compare "" $module]} then {
2157 puts "Usage: enable <module>"
2158 } elseif {[moduleExists $module]} then {
2159 if {![getModuleDatabaseData $module load]} then {
2160 setModuleDatabaseData $module load 1
2161 puts "Enabled module: $module"
2162 } else {
2163 puts "Module `$module' is already enabled."
2164 }
2165 } else {
2166 puts "Invalid module: $module"
2167 }
2168 return
2169 }
2170
2171 ##
2172 ## Disable a module
2173 ##
2174 ## Args: data
2175 ## Returns: nothing
2176 ##
2177 proc IconfigDisable {data} {
2178 set module [lindex [split $data] 0]
2179 if {![string compare "" $module]} then {
2180 puts "Usage: disable <module>"
2181 } elseif {[moduleExists $module]} then {
2182 if {[getModuleDatabaseData $module load] == 1} then {
2183 setModuleDatabaseData $module load 0
2184 puts "Disabled module: $module"
2185 } else {
2186 puts "Module `$module' is already disabled."
2187 }
2188 } else {
2189 puts "Invalid module: $module"
2190 }
2191 return
2192 }
2193
2194 ##
2195 ## List modules
2196 ##
2197 ## Args: data
2198 ## returns: nothing
2199 ##
2200 # FIXME: format the list of modules better (proc from texttools?)
2201 proc IconfigModules {data} {
2202 if {[llength [set modules [listModules]]]} then {
2203 set what [lindex [split $data] 0]
2204 if {![string compare "" $what]} then {
2205 set what "all"
2206 }
2207 switch -exact -- $what {
2208 * -
2209 all {
2210 puts "Available modules:"
2211 foreach line [splitList $modules 65 " " " "] {
2212 puts " $line"
2213 }
2214 }
2215 enabled {
2216 set list ""
2217 foreach module $modules {
2218 if {[getModuleDatabaseData $module load]} {
2219 lappend list $module
2220 }
2221 }
2222 if {[llength $list]} then {
2223 puts "Enabled modules:"
2224 foreach line [splitList $list 65 " " " "] {
2225 puts " $line"
2226 }
2227 } else {
2228 puts "No modules enabled"
2229 }
2230 }
2231 disabled {
2232 set list ""
2233 foreach module $modules {
2234 if {![getModuleDatabaseData $module load]} {
2235 lappend list $module
2236 }
2237 }
2238 if {[llength $list]} then {
2239 puts "Disabled modules:"
2240 foreach line [splitList $list 65 " " " "] {
2241 puts " $line"
2242 }
2243 } else {
2244 puts "No modules disabled"
2245 }
2246 }
2247 default {
2248 puts "Error: 'option' must be one of: all, enabled, disabled"
2249 }
2250 }
2251 } else {
2252 puts "Error: No modules available."
2253 }
2254 return
2255 }
2256
2257 ##
2258 ## Show info for the given module
2259 ##
2260 ## Args: data {*|all|enabled|disabled}
2261 ## returns: nothing
2262 ##
2263 # FIXME: add multiple module support as in config.tcl and or integrate?
2264 proc IconfigInfo {data} {
2265 set module [lindex [split $data] 0]
2266 if {![string compare "" $module]} then {
2267 puts "Usage: info <module>"
2268 } elseif {[moduleExists $module]} then {
2269 puts "Info for module: $module"
2270 puts ""
2271 puts "Filename: [getModuleDatabaseData $module file]"
2272 puts "MD5: [getModuleDatabaseData $module md5sum]"
2273 puts "Version: [getModuleDatabaseData $module version]"
2274 if {[getModuleDatabaseData $module load]} then {
2275 puts "Enabled: yes"
2276 } else {
2277 puts "Enabled: no"
2278 }
2279 if {[string compare "" [set config [getModuleDatabaseData $module config]]]} then {
2280 puts "Config file: $config"
2281 }
2282 if {[string compare "" [set help [getModuleDatabaseData $module help]]]} then {
2283 puts "Help file: $help"
2284 }
2285 if {[string compare "" [set provides [getModuleDatabaseData $module provides]]]} then {
2286 puts "Provided commands:"
2287 foreach line [splitList $provides 65 " " " "] {
2288 puts " $line"
2289 }
2290 }
2291 if {[string compare "" [set requires [getModuleDatabaseData $module requires]]]} then {
2292 puts "Required commands:"
2293 foreach line [splitList $requires 65 " " " "] {
2294 puts " $line"
2295 }
2296 }
2297 puts "Description:"
2298 foreach line [splitList [getModuleDatabaseData $module description] 65 " " " "] {
2299 puts " $line"
2300 }
2301 } else {
2302 puts "Invalid module: $module"
2303 }
2304 return
2305 }
2306
2307 ##
2308 ## Show configuration help
2309 ##
2310 ## Args: data
2311 ## Returns: nothing
2312 ##
2313 proc IconfigHelp {data} {
2314 if {![string compare "" $data]} then {
2315 set data help
2316 }
2317 switch -exact -- $data {
2318 set {
2319 puts "### set \[option\] \[value\]"
2320 puts " Sets an option to what you specify."
2321 puts " Shows current setting for an option if no new value is given."
2322 puts " Shows current settings for all options if no option is given."
2323 }
2324 enable {
2325 puts "### enable <module>"
2326 puts " Enables the given module."
2327 }
2328 disable {
2329 puts "### disable <module>"
2330 puts " Disables the given module."
2331 }
2332 info {
2333 puts "### info <module>"
2334 puts " Show info for the given module."
2335 }
2336 modules {
2337 puts "### modules \[what\]"
2338 puts " Available options: all, enabled, disabled"
2339 puts " all: Shows all available modules"
2340 puts " enabled: Shows enabled modules"
2341 puts " disabled: Shows disabled modules"
2342 }
2343 help {
2344 puts "### Avaliable commands:"
2345 puts " set \[option\] \[value\]"
2346 puts " enable <module>"
2347 puts " disable <module>"
2348 puts " info <module>"
2349 puts " modules \[what\]"
2350 puts " help \[command\]"
2351 puts " quit"
2352 puts "You can get help on individual commands: 'help <command>'"
2353 }
2354 quit {
2355 puts "### quit"
2356 puts " Quits interactive configuration."
2357 }
2358 default {
2359 puts "No help available on that."
2360 }
2361 }
2362 return
2363 }
2364
2365 ##
2366 ## Inline startup and init code
2367 ##
2368
2369 wpLog o * "wolfpack.tcl v[package require $NamespaceCurrent] loading..."
2370
2371 # Init md5Sum command
2372 if {![md5Init]} then {
2373 wpLog o * "Error: can't find a usable md5 command!"
2374 return 0
2375 }
2376
2377 # Export commands
2378 eval namespace export [join $ExportList]
2379
2380 # Set missing variables to default values
2381 if {![info exists configDataChanged]} then {
2382 set configDataChanged 0
2383 }
2384 if {![info exists moduleDatabaseDataChanged]} then {
2385 set moduleDatabaseDataChanged 0
2386 }
2387 if {![info exists moduleLoadedList]} then {
2388 set moduleLoadedList ""
2389 }
2390
2391 # Load configuration data
2392 arrayLoad configData $IconfigDefaults(cfgfile) 0 "configuration file "
2393
2394 # Unset unknown configuration variables
2395 foreach name [array names configData] {
2396 if {![info exists configDefaults($name)]} then {
2397 unset configData($name)
2398 set configDataChanged 1
2399 }
2400 }
2401
2402 # Set missing configuration variables to defaults
2403 foreach {name data} [array get configDefaults] {
2404 if {![info exists configData($name)]} then {
2405 set configData($name) [lindex $data 1]
2406 set configDataChanged 1
2407 }
2408 }
2409
2410 # Set oldConfigData configuration variables to match
2411 foreach {name data} [array get configData] {
2412 if {![info exists oldConfigData($name)]} then {
2413 set oldConfigData($name) $data
2414 }
2415 }
2416
2417 # Trace configData changes
2418 trace variable configData w ${NamespaceCurrent}::TraceConfigData
2419
2420 # Save configuration data if changed
2421 if {$configDataChanged} then {
2422 arraySave configData $IconfigDefaults(cfgfile) 0 "configuration file "
2423 }
2424
2425 # Eval command line arguments if loading with tclsh
2426 if {[info exists argv0]} then {
2427 EvalArgs $argc $argv $argv0
2428 }
2429
2430 # Check verbose/quiet options
2431 if {$optionData(quiet)} then {
2432 set Verbose $optionData(quiet)
2433 } elseif {$configData(verbose)} then {
2434 set Verbose $configData(verbose)
2435 } else {
2436 set Verbose $optionData(verbose)
2437 }
2438
2439 # Check rebuild/norebuild options
2440 if {(!$optionData(norebuild)) && ($optionData(rebuild))} then {
2441 set RebuildDatabase 1
2442 } else {
2443 set RebuildDatabase 0
2444 }
2445
2446 # Sanity check: old eggdrop versions used [time] for a timestamp command
2447 if {(($optionData(time)) || ($configData(time))) && \
2448 ([catch {time}])} then {
2449 set TimeOk 1
2450 } else {
2451 set TimeOk 0
2452 }
2453
2454 # Load module database
2455 if {$Verbose >= 0} then {
2456 wpLog o * "Loading module database..."
2457 }
2458
2459 if {$TimeOk} then {
2460 set LoadTime [time {set LoadResult [loadModuleDatabase $Verbose]}]
2461 } else {
2462 set LoadResult [loadModuleDatabase $Verbose]
2463 }
2464
2465 if {$LoadResult != -1} then {
2466 if {$Verbose >= 0} then {
2467 if {[info exists LoadTime]} then {
2468 wpLog o * "Done. ([format "%.3f" [expr [lindex $LoadTime 0] / 1000000.0]] seconds elapsed)"
2469 } else {
2470 wpLog o * "Done."
2471 }
2472 }
2473 set CreateDatabase 0
2474 } else {
2475 if {$Verbose >= 0} then {
2476 wpLog o * "Warning: module database does not exist."
2477 }
2478 set CreateDatabase 1
2479 }
2480
2481 set NeedsRebuild 0
2482
2483 # Compare module database if we are not going to rebuild or create it
2484 if {(!$RebuildDatabase) && (!$CreateDatabase)} then {
2485 if {$Verbose >= 0} then {
2486 wpLog o * "Comparing module database..."
2487 }
2488 if {![file exists $configData(moddbfile)]} then {
2489 set NeedsRebuild 1
2490 } else {
2491 if {$TimeOk} then {
2492 set CompareTime [time {set CompareResult [compareModuleDatabase $Verbose]}]
2493 } else {
2494 set CompareResult [compareModuleDatabase $Verbose]
2495 }
2496 if {!$CompareResult} then {
2497 set NeedsRebuild 1
2498 }
2499 }
2500
2501 if {$Verbose >= 0} then {
2502 if {[info exists CompareTime]} then {
2503 wpLog o * "Done. ([format "%.3f" [expr [lindex $CompareTime 0] / 1000000.0]] seconds elapsed)"
2504 } else {
2505 wpLog o * "Done."
2506 }
2507 if {$NeedsRebuild} then {
2508 wpLog o * "Database is outdated."
2509 } else {
2510 wpLog o * "Database is current."
2511 }
2512 }
2513 }
2514
2515 # Create database if does not exist
2516 # Rebuild database if requested
2517 # Rebuild database if it's outdated and config permits
2518 if {($CreateDatabase) || ($RebuildDatabase) || \
2519 (($NeedsRebuild) && ($configData(rebuild)))} then {
2520
2521 if {$Verbose >= 0} then {
2522 if {$CreateDatabase} then {
2523 wpLog o * "Creating module database..."
2524 } else {
2525 wpLog o * "Rebuilding module database..."
2526 }
2527 }
2528
2529 # Rebuild module database
2530 if {$TimeOk} then {
2531 set RebuildTime [time {rebuildModuleDatabase $Verbose}]
2532 } else {
2533 rebuildModuleDatabase $Verbose
2534 }
2535
2536 if {$Verbose >= 0} then {
2537 if {[info exists RebuildTime]} then {
2538 wpLog o * "Done. ([format "%.3f" [expr [lindex $RebuildTime 0] / 1000000.0]] seconds elapsed)"
2539 } else {
2540 wpLog o * "Done."
2541 }
2542 }
2543
2544 # Save module database
2545 if {$Verbose >= 0} then {
2546 wpLog o * "Saving module database..."
2547 }
2548
2549 if {$TimeOk} then {
2550 set SaveTime [time {set SaveResult [saveModuleDatabase $Verbose]}]
2551 } else {
2552 set SaveResult [saveModuleDatabase $Verbose]
2553 }
2554
2555 if {$Verbose >= 0} then {
2556 if {$SaveResult} then {
2557 if {[info exists SaveTime]} then {
2558 wpLog o * "Done. ([format "%.3f" [expr [lindex $SaveTime 0] / 1000000.0]] seconds elapsed)"
2559 } else {
2560 wpLog o * "Done."
2561 }
2562 } else {
2563 wpLog o * "Error"
2564 }
2565 }
2566
2567 } elseif {($NeedsRebuild) && ($Verbose >= 0)} then {
2568 wpLog o * "Warning: not rebuilding outdated module database..."
2569 }
2570
2571 # Enter interactive configuration if loading with tclsh
2572 if {[info exists argv0]} then {
2573 if {$optionData(config)} then {
2574 Iconfig
2575 }
2576 }
2577
2578 # Build command table
2579 if {(![info exists argv0]) || ($optionData(debug))} then {
2580 if {$Verbose >= 0} then {
2581 wpLog o * "Building command table..."
2582 }
2583 if {$TimeOk} then {
2584 set CommandTime [time {buildCommandTable $Verbose}]
2585 } else {
2586 buildCommandTable $Verbose
2587 }
2588 if {$Verbose >= 0} then {
2589 if {[info exists CommandTime]} then {
2590 wpLog o * "Done. ([format "%.3f" [expr [lindex $CommandTime 0] / 1000000.0]] seconds elapsed)"
2591 } else {
2592 wpLog o * "Done."
2593 }
2594 }
2595
2596 set loadList ""
2597
2598 # Load debug module first if not in eggdrop mode
2599 if {([info exists argv0]) && ([moduleExists debug])} then {
2600 lappend loadList debug
2601 }
2602
2603 # Load other modules next, moduleLoad will preload additional modules
2604 foreach name [lsort [array names moduleDatabaseData]] {
2605 if {[getModuleDatabaseData $name load] == 1} then {
2606 lappend loadList $name
2607 }
2608 }
2609
2610 wpLog o * "Loading modules..."
2611
2612 # Load modules
2613 if {$TimeOk} then {
2614 set LoadTime [time {
2615 foreach module $loadList {
2616 if {[catch {moduleLoad $module $Verbose} result]} then {
2617 wpLog o * "Error: unable to load module `$module': $result"
2618 }
2619 }
2620 }]
2621 } else {
2622 foreach module $loadList {
2623 if {[catch {moduleLoad $module $Verbose} result]} then {
2624 wpLog o * "Error: unable to load module `$module': $result"
2625 }
2626 }
2627 }
2628
2629 if {[info exists LoadTime]} then {
2630 wpLog o * "Done. ([format "%.3f" [expr [lindex $LoadTime 0] / 1000000.0]] seconds elapsed)"
2631 } else {
2632 wpLog o * "Done."
2633 }
2634
2635 set ModuleLoadCount [llength [split $moduleLoadedList]]
2636 if {$ModuleLoadCount} then {
2637 set ModuleTotalCount [llength [array names moduleDatabaseData]]
2638 wpLog o * "Modules loaded ($ModuleLoadCount/$ModuleTotalCount): $moduleLoadedList"
2639 } else {
2640 wpLog o * "No modules loaded."
2641 }
2642
2643 # Unload modules if started in debug mode
2644 if {$optionData(debug)} then {
2645
2646 # FIXME: code module dependency stuff first
2647 # wpLog o * "Unloading modules..."
2648
2649 # Unload all modules except debug
2650 # foreach module $moduleLoadedList {
2651 # if {[string compare $module debug]} then {
2652 # if {[catch {moduleUnload $module $Verbose} result]} then {
2653 # wpLog o * "Error: unable to unload module `$module': $result"
2654 # }
2655 # }
2656 # }
2657
2658 # Unload debug module last to make it display stats
2659 if {[moduleLoaded debug]} then {
2660 if {[catch {moduleUnload debug} result]} then {
2661 wpLog o * "Error: unable to unload module `debug': $result"
2662 }
2663 }
2664 # wpLog o * "Done."
2665 }
2666 }
2667
2668 } ;# namespace ::wp
2669
2670 return

webmaster@eggheads.org
ViewVC Help
Powered by ViewVC 1.1.23